unity3d描边shader

刚开始做unity3d游戏的时候被描边的问题困扰过。这个问题需要对多pass和深度测试有所理解。

第一个pass用单色进行渲染，并且将顶点沿法线方向扩展，注意这时候不能写深度，因为第二个pass渲染的时候顶点不扩展，深度测试会无法通过。第二个pass随意画就可以了，注意要写深度。有一点要注意的是渲染顺序的问题，这里的顺序是Transparent，等实体模型画完之后才画。注意双pass还是两次drawcall，而且半透明材质无法实现正确的描边，半透明的描边很难处理，最简单的就是美术直接把边画在贴图上，但是显得很不灵活，但是我不知道而且不认为有什么更好的方法，所以模型尽量少用半透明材质。

这个方法其实和有些人把模型拷贝一份并翻转法线的手法是类似的，但是这种方法还是有优势的，首先资源量减少，并且不需要骨骼，省掉了第二套模型的骨骼变换和meshskin的消耗。

下面是shader代码，代码是从国外网站上摘下来的：

Shader "Outline" {
	Properties {
		_Color ("Main Color", Color) = (.5,.5,.5,1)
		_OutlineColor ("Outline Color", Color) = (0,0,0,1)
		_Outline ("Outline width", Range (0.0, 0.03)) = .005
		_MainTex ("Base (RGB)", 2D) = "white" { }
	}
	CGINCLUDE
		#include "UnityCG.cginc"
		struct appdata {
			float4 vertex : POSITION;
			float3 normal : NORMAL;
		};
		struct v2f {
			float4 pos : POSITION;
			float4 color : COLOR;
		};
		uniform float _Outline;
		uniform float4 _OutlineColor;
		v2f vert(appdata v) {
			v2f o;
			o.pos = mul(UNITY_MATRIX_MVP, v.vertex);
			float3 norm   = mul ((float3x3)UNITY_MATRIX_IT_MV, v.normal);
			float2 offset = TransformViewToProjection(norm.xy);
			o.pos.xy += offset * o.pos.z * _Outline;
			o.color = _OutlineColor;
			return o;
		}
	ENDCG
	SubShader {
		Tags { "Queue" = "Transparent" }
		Pass {
			Tags { "LightMode" = "Always" }
			Cull Off
			ZWrite Off
			//ZTest Always//始终通过深度测试，即可以渲染
			//ColorMask RGB // alpha not used
			Blend SrcAlpha OneMinusSrcAlpha // Normal

			CGPROGRAM
			#pragma vertex vert
			#pragma fragment frag
			half4 frag(v2f i) :COLOR {
				return i.color;
			}
			ENDCG
		}
		Pass {
			Name "BASE"
			ZWrite On
			ZTest LEqual
			Blend SrcAlpha OneMinusSrcAlpha
			Material {
				Diffuse [_Color]
				Ambient [_Color]
			}
			Lighting On
			SetTexture [_MainTex] {
				ConstantColor [_Color]
				Combine texture * constant
			}
			SetTexture [_MainTex] {
				Combine previous * primary DOUBLE
			}
		}
	}
	Fallback "Diffuse"
}

//ZTest Always这行代码打开的话，效果很有意思的。