UnityShader_实现动画效果（2）

顶点动画

补充一点上一篇遗漏的一个关键点：
当我们的shader中包含了 模型空间的顶点动画时，必须！！加上Tag { DisableBatching = true}！！！因为Unity在合批处理的时候会合并所有相关模型，这会导致这些模型各自的模型空间丢失！！！！！！这一点在这篇中也会遇到！！！

让我们伟大的国旗动起来！
实现原理： 在顶点着色器中，让平面模型的“横轴方向”随时间做正弦函数运动！

Properties {
		_MainTex ("Main Tex", 2D) = "white" {}
		_Color ("Color Tint", Color) = (1, 1, 1, 1)
		_Magnitude ("Distortion Magnitude", Float) = 1
 		_Frequency ("Distortion Frequency", Float) = 1
 		_InvWaveLength ("Distortion Inverse Wave Length", Float) = 10
 		_Speed ("Speed", Float) = 0.5
	}
	SubShader {
		// Need to disable batching because of the vertex animation
		Tags {"DisableBatching"="True"}
		
		Pass {
			Tags { "LightMode"="ForwardBase" }
			
			Cull Off
			
			CGPROGRAM  
			#pragma vertex vert 
			#pragma fragment frag
			
			#include "UnityCG.cginc" 
			
			sampler2D _MainTex;
			float4 _MainTex_ST;
			fixed4 _Color;
			float _Magnitude;
			float _Frequency;
			float _InvWaveLength;
			float _Speed;
			
			struct a2v {
			    float4 vertex : POSITION;
			    float4 texcoord : TEXCOORD0;
			};
			
			struct v2f {
			    float4 pos : SV_POSITION;
			    float2 uv : TEXCOORD0;
			};
			
			v2f vert(a2v v) {
				v2f o;
				
				float4 offset;
				offset.yzw = float3(0.0, 0.0, 0.0);
				offset.x = sin(_Frequency * _Time.y + v.vertex.x * _InvWaveLength + v.vertex.y * _InvWaveLength + v.vertex.z * _InvWaveLength) * _Magnitude;
				o.pos = UnityObjectToClipPos(v.vertex + offset);
				
				o.uv = TRANSFORM_TEX(v.texcoord, _MainTex);
				
				return o;
			}
			
			fixed4 frag(v2f i) : SV_Target {
				fixed4 c = tex2D(_MainTex, i.uv);
				c.rgb *= _Color.rgb;
				
				return c;
			} 
			
			ENDCG
		}

是不是法线上面旗子的影子怪怪的！
是的，影子没有在动！
在shader中我们没有对投影的shader进行编写，他在FallBack中找到了投影Pass，但是这个投影是建立在平面没有动的基础上，为了让影子动起来，我们应该在Shader中写一个影子对应的Pass，处理方法跟之前的文章中相同，此处就不再赘述。

Pass {
			Tags { "LightMode" = "ShadowCaster" }
			
			CGPROGRAM
			
			#pragma vertex vert
			#pragma fragment frag
			
			#pragma multi_compile_shadowcaster
			
			#include "UnityCG.cginc"
			
			float _Magnitude;
			float _Frequency;
			float _InvWaveLength;
			float _Speed;
			
			struct v2f { 
			    V2F_SHADOW_CASTER;
			};
			
			v2f vert(appdata_base v) {
				v2f o;
				
				float4 offset;
				offset.yzw = float3(0.0, 0.0, 0.0);
				offset.x = sin(_Frequency * _Time.y + v.vertex.x * _InvWaveLength + v.vertex.y * _InvWaveLength + v.vertex.z * _InvWaveLength) * _Magnitude;
				v.vertex = v.vertex + offset;

				TRANSFER_SHADOW_CASTER_NORMALOFFSET(o)
				
				return o;
			}
			
			fixed4 frag(v2f i) : SV_Target {
			    SHADOW_CASTER_FRAGMENT(i)
			}
			ENDCG
		}

投影相关可以查看之前的文章
效果如下图

说一下顶点处理的一些问题，之前一直很困惑

在上一篇中也说到 quad 改为 plane会实现不了效果，在这里也是一样的，这里的旗子用的是《UnityShader入门精要》中自带的模型，代码也是出自这里。
我们打开如下图的Selection Wire，可以看到旗子模型的网格下面gif中样式，因此当我们换成其他网格排布的模型（比如Unity自带的plane），就得不到预想的效果！
顶点处理的shader要特别注意从 建模工具导出来的模型三角片元的组成是否正确（或者说能满足所写shader的要求）