UnityShader---光照（衰减和阴影））（内置渲染管线）---10

光照衰减：

// Upgrade NOTE: replaced '_LightMatrix0' with 'unity_WorldToLight'

Shader "Unlit/15"
{
    Properties
    {
        _Diffuse("Diffuse",Color) = (1,1,1,1)
        _Specular("Specular",Color) = (1,1,1,1)
        _Gloss("Gloss",Range(1,256)) = 10
    }
     SubShader
    {
        Pass
        {
            Tags{"LightMode" = "ForwardBase"}

            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            //添加
            #pragma multi_compile_fwdbase

            #include "UnityCG.cginc"
            #include "Lighting.cginc"

            fixed4 _Diffuse;
            fixed4 _Specular;
            float _Gloss;

            struct a2v
            {
                float4 vertex:POSITION;
                float3 normal:NORMAL;
            };

            struct v2f
            {
                float4 pos:SV_POSITION;
                float3 worldNormal:TEXCOORD0;
                float3 worldPos:TEXCOORD1;
            };

            v2f vert(a2v v)
            {
                v2f o;

                o.pos = UnityObjectToClipPos(v.vertex);

                o.worldNormal = UnityObjectToWorldNormal(v.normal);

                o.worldPos = mul(unity_ObjectToWorld,v.vertex);

                return o;
            }

            fixed4 frag(v2f i) :SV_Target
            {

                fixed3 worldNormal = normalize(i.worldNormal);

                fixed3 worldLight = normalize(UnityWorldSpaceLightDir(i.worldPos));

                fixed3 worldView = normalize(UnityWorldSpaceViewDir(i.worldPos));

                fixed3 halfDir = normalize(worldLight + worldView);

                fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.rgb;

                fixed3 diffuse = _LightColor0.rgb * _Diffuse.rgb * saturate(dot(worldNormal,worldLight));

                //Blinn-Phong高光公式:光顔色 * 高光反射顔色 * pow(saturate(dot(法线,半角方向)),高光系数)
                fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(saturate(dot(worldNormal,halfDir)),_Gloss);

                fixed atten = 1;

                return fixed4((ambient + diffuse + specular) * atten,1.0);
            }

            ENDCG
        }

        Pass
        {
            Tags{"LightMode" = "ForwardAdd"}

            //设置混合模式
            Blend One One

            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            //添加
            #pragma multi_compile_fwdadd

            #include "UnityCG.cginc"
            #include "Lighting.cginc"
            #include "AutoLight.cginc"

            fixed4 _Diffuse;
            fixed4 _Specular;
            float _Gloss;

            struct a2v
            {
                float4 vertex:POSITION;
                float3 normal:NORMAL;
            };

            struct v2f
            {
                float4 pos:SV_POSITION;
                float3 worldNormal:TEXCOORD0;
                float3 worldPos:TEXCOORD1;
            };

            v2f vert(a2v v)
            {
                v2f o;

                o.pos = UnityObjectToClipPos(v.vertex);

                o.worldNormal = UnityObjectToWorldNormal(v.normal);

                o.worldPos = mul(unity_ObjectToWorld,v.vertex);

                return o;
            }

            fixed4 frag(v2f i) :SV_Target
            {
                fixed3 worldNormal = normalize(i.worldNormal);

                fixed3 worldLight = normalize(UnityWorldSpaceLightDir(i.worldPos));

                fixed3 worldView = normalize(UnityWorldSpaceViewDir(i.worldPos));

                fixed3 halfDir = normalize(worldLight + worldView);               

                fixed3 diffuse = _LightColor0.rgb * _Diffuse.rgb * saturate(dot(worldNormal,worldLight));

                //Blinn-Phong高光公式:光顔色 * 高光反射顔色 * pow(saturate(dot(法线,半角方向)),高光系数)
                fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(saturate(dot(worldNormal,halfDir)),_Gloss);

#ifdef USING_DIRECTIONAL_LIGHT
                fixed atten = 1;
#else
                float3 lightCoord = mul(unity_WorldToLight, float4(i.worldPos, 1)).xyz;
                fixed atten = tex2D(_LightTexture0,dot(lightCoord,lightCoord).rr).UNITY_ATTEN_CHANNEL;
#endif

                return fixed4((diffuse + specular) * atten,1.0);
            }
            ENDCG
        }
    }
    Fallback "Specular"
}

光照阴影：

// Upgrade NOTE: replaced '_LightMatrix0' with 'unity_WorldToLight'

Shader "Unlit/16"
{
    Properties
    {
        _Diffuse("Diffuse",Color) = (1,1,1,1)
        _Specular("Specular",Color) = (1,1,1,1)
        _Gloss("Gloss",Range(1,256)) = 10
    }
    SubShader
    {
        Pass
        {
            Tags{"LightMode" = "ForwardBase"}

            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            //添加
            #pragma multi_compile_fwdbase

            #include "UnityCG.cginc"
            #include "Lighting.cginc"
            #include "AutoLight.cginc"

            fixed4 _Diffuse;
            fixed4 _Specular;
            float _Gloss;

            struct a2v
            {
                float4 vertex:POSITION;
                float3 normal:NORMAL;
            };

            struct v2f
            {
                float4 pos:SV_POSITION;
                float3 worldNormal:TEXCOORD0;
                float3 worldPos:TEXCOORD1;
                SHADOW_COORDS(2)
            };

            v2f vert(a2v v)
            {
                v2f o;

                o.pos = UnityObjectToClipPos(v.vertex);

                o.worldNormal = UnityObjectToWorldNormal(v.normal);

                o.worldPos = mul(unity_ObjectToWorld,v.vertex);

                TRANSFER_SHADOW(o);

                return o;
            }

            fixed4 frag(v2f i) :SV_Target
            {

                fixed3 worldNormal = normalize(i.worldNormal);

                fixed3 worldLight = normalize(UnityWorldSpaceLightDir(i.worldPos));

                fixed3 worldView = normalize(UnityWorldSpaceViewDir(i.worldPos));

                fixed3 halfDir = normalize(worldLight + worldView);

                fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.rgb;

                fixed3 diffuse = _LightColor0.rgb * _Diffuse.rgb * saturate(dot(worldNormal,worldLight));

                //Blinn-Phong高光公式:光顔色 * 高光反射顔色 * pow(saturate(dot(法线,半角方向)),高光系数)
                fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(saturate(dot(worldNormal,halfDir)),_Gloss);

                //fixed atten = 1;
                //fixed shadow = SHADOW_ATTENUATION(i);

                //统一计算衰减和阴影
                UNITY_LIGHT_ATTENUATION(atten,i,i.worldPos);

                return fixed4((ambient + diffuse + specular) * atten,1.0);
            }

            ENDCG
        }

        Pass
        {
            Tags{"LightMode" = "ForwardAdd"}

            //设置混合模式
            Blend One One

            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            //添加
            //#pragma multi_compile_fwdadd
            #pragma multi_compile_fwdadd_fullshadows

            #include "UnityCG.cginc"
            #include "Lighting.cginc"
            #include "AutoLight.cginc"

            fixed4 _Diffuse;
            fixed4 _Specular;
            float _Gloss;

            struct a2v
            {
                float4 vertex:POSITION;
                float3 normal:NORMAL;
            };

            struct v2f
            {
                float4 pos:SV_POSITION;
                float3 worldNormal:TEXCOORD0;
                float3 worldPos:TEXCOORD1;
                //SHADOW_COORDS(2)
            };

            v2f vert(a2v v)
            {
                v2f o;

                o.pos = UnityObjectToClipPos(v.vertex);

                o.worldNormal = UnityObjectToWorldNormal(v.normal);

                o.worldPos = mul(unity_ObjectToWorld,v.vertex);

                //TRANSFER_SHADOW(o);

                return o;
            }

            fixed4 frag(v2f i) :SV_Target
            {

                fixed3 worldNormal = normalize(i.worldNormal);

                fixed3 worldLight = normalize(UnityWorldSpaceLightDir(i.worldPos));

                fixed3 worldView = normalize(UnityWorldSpaceViewDir(i.worldPos));

                fixed3 halfDir = normalize(worldLight + worldView);               

                fixed3 diffuse = _LightColor0.rgb * _Diffuse.rgb * saturate(dot(worldNormal,worldLight));

                //Blinn-Phong高光公式:光顔色 * 高光反射顔色 * pow(saturate(dot(法线,半角方向)),高光系数)
                fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(saturate(dot(worldNormal,halfDir)),_Gloss);

                //1.计算衰减
//#ifdef USING_DIRECTIONAL_LIGHT
//                fixed atten = 1;
//#else
//                float3 lightCoord = mul(unity_WorldToLight, float4(i.worldPos, 1)).xyz;
//                fixed atten = tex2D(_LightTexture0,dot(lightCoord,lightCoord).rr).UNITY_ATTEN_CHANNEL;
//#endif
                //2.计算衰减和阴影
                UNITY_LIGHT_ATTENUATION(atten,i,i.worldPos);

                return fixed4((diffuse + specular) * atten,1.0);
            }
            ENDCG
        }
    }
    Fallback "Specular"
}