shader 卡通着色

步骤
1.贴上纹理贴图 （下面代码中的第三个Pass通道）
2.添加漫反射 （下面代码中的第三个Pass通道）
3.给物体描边 （下面代码中的第二个Pass通道）
4.添加渐变纹理 （下面代码中的第三个Pass通道）
5.边缘发光 （下面代码中的第三个Pass通道）
6.XRay实现 （下面代码中的第一个Pass通道）

XRay中，即第一个Pass通道中，可以实现物体被遮挡时，也能够显示出来相应的轮廓和发光效果。

代码如下：

Shader "MyShader/NewShader"
{
    Properties
    {
        _MainTex ("Texture", 2D) = "white" {}
		_Diffuse("diffuse",Color) = (1,1,1,1)
		_Outline("outline",Range(0,0.2)) = 0.003
		_OutlineColor("outline color",Color)=(0,0,0,0)
		_Steps("steps",Range(1,30))=1
		_ToonEffect("toon effect",Range(0,1))=0.5
		//_RampTex("ramp tex",2D)="white"{}//渐进纹理
		_RimColor("rim color",Color)=(1,1,1,1)
		_RimPower("rim power",Range(0.0001,3))=0.1
		_XRayColor("xray color",Color) = (1,1,1,1)
		_XRayPower("xray power",Range(0.0001,3)) = 0.1
    }
    SubShader
    {
        Tags { "Queue"="Geometry+1000" "RenderType"="Opaque" }
        LOD 100

		Pass//XRay
		{
			Name "XRay"
			Tags{"ForceNoShadowCasting"="True"}//透明物体不产生阴影
			Blend SrcAlpha One//透明物体用到混合
			ZWrite Off
			ZTest Greater
			CGPROGRAM

			#pragma vertex vert
			#pragma fragment frag

			#include "UnityCG.cginc"

			fixed4 _XRayColor;
			float _XRayPower;

			struct v2f
			{
				float4 vertex:SV_POSITION;
				float3 normal:TEXCOORD0;
				float3 viewDir:TEXCOORD1;
			};

			v2f vert(appdata_base v)
			{
				v2f o;
				o.vertex = UnityObjectToClipPos(v.vertex);
				o.normal = v.normal;
				o.viewDir = ObjSpaceViewDir(v.vertex);
				return o;
			}

			fixed4 frag(v2f i):SV_Target
			{
				float3 viewDir = normalize(i.viewDir);
				float3 normal = normalize(i.normal);
				float rim = 1 - dot(normal, viewDir);
				float4 rimColor = _XRayColor * pow(rim, 1 / _XRayPower);
				return rimColor;
			}

			ENDCG
		}


		Pass//描边通道
		{
			Name "Outline"
			Cull Front
			CGPROGRAM

			#pragma vertex vert
			#pragma fragment frag

			#include "UnityCG.cginc"

			float _Outline;
			float4 _OutlineColor;

			struct v2f
			{
				float4 vertex:SV_POSITION;
			};

			v2f vert(appdata_base v)
			{
				v2f o;

				//模型空间法线外拓
				v.vertex.xyz += v.normal*_Outline;
				o.vertex = UnityObjectToClipPos(v.vertex);

				//视角空间法线外拓
				//float4 pos= mul(UNITY_MATRIX_V, mul(unity_ObjectToWorld, v.vertex));//模型顶点坐标转换到视角坐标
				//float3 normal = normalize(mul((float3x3)UNITY_MATRIX_IT_MV, v.normal));//得到视角坐标的法线
				//pos = pos + float4(normal,0) * _Outline;
				//o.vertex= mul(UNITY_MATRIX_P, pos);//从视角空间转换到裁剪空间

				//裁剪空间法线外拓
				//o.vertex = UnityObjectToClipPos(v.vertex);
				//float3 normal = normalize(mul((float3x3)UNITY_MATRIX_IT_MV, v.normal));//得到视角坐标的法线
				//float2 viewNormal = TransformViewToProjection(normal.xy);// 转换 视图空间 到 投影空间
				//o.vertex.xy += viewNormal * _Outline;

				return o;
			}

			fixed4 frag(v2f i) :SV_Target
			{
				return _OutlineColor;
			}

			ENDCG
		}
		

        Pass//边缘外发光和纹理贴图
        {
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag

            #include "UnityCG.cginc"
            #include "Lighting.cginc"


            struct v2f
            {
                float2 uv : TEXCOORD0;
                float4 vertex : SV_POSITION;
				float3 worldNormal : TEXCOORD1;
				float3 worldPos : TEXCOORD2;
            };

            sampler2D _MainTex;
            float4 _MainTex_ST;
			float4 _Diffuse;
			float _Steps;
			float _ToonEffect;
			//sampler2D _RampTex;
			float4 _RimColor;
			float _RimPower;

            v2f vert (appdata_base v)
            {
                v2f o;
                o.vertex = UnityObjectToClipPos(v.vertex);
                o.uv = TRANSFORM_TEX(v.texcoord, _MainTex);
				o.worldNormal = UnityObjectToWorldNormal(v.normal);
				o.worldPos = mul(unity_ObjectToWorld, v.vertex);
                return o;
            }

            fixed4 frag (v2f i) : SV_Target
            {
				fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz;
				fixed3 worldLight = UnityWorldSpaceLightDir(i.worldPos);
				fixed3 view = normalize(UnityWorldSpaceViewDir(i.worldPos));
				//fixed3 view = normalize(_WorldSpaceCameraPos - i.worldPos);

                fixed4 albedo = tex2D(_MainTex, i.uv);
				fixed difLight = dot(worldLight, i.worldNormal)*0.5 + 0.5;

				//渐进纹理颜色值,需要贴一张渐变纹理。与下面三行代码效果类似，下面三行代码的效果不需要渐变贴图
				//fixed4 rampColor = tex2D(_RampTex, fixed2(difLight, difLight));

				difLight = smoothstep(0, 1, difLight);
				float toon = floor(difLight*_Steps) / _Steps;
				difLight = lerp(difLight, toon, _ToonEffect);

				//视角与法线垂直时，即为边缘位置，此时点积为0，用1减去它表示 值越趋于1，就越靠近边缘。
				float rim = 1-saturate(dot(view, i.worldNormal));
				fixed3 rimColor = _RimColor.rgb * pow(rim, 1 / _RimPower);

				fixed3 diffuse = _LightColor0.rgb*_Diffuse.rgb*albedo.rgb*difLight;//*rampColor;
				return fixed4(diffuse + ambient + rimColor, 1);
            }
            ENDCG
        }
    }
	FallBack "Diffuse"
}