unity shader sss/卡通玉石材质

最终效果展示：

玉石材质分析：

漫反射（Diffuse）

       用half Lambert模型实现：

fixed halfLambert = dot(worldNormal,worldLightDir)* 0.5 + 0.5;

效果：

但是光只是这样还不够,我们还需要在half Lambert基础上加上ramp texture增加底色渐变与控制漫反射颜色的参数。

fixed3 Diffuse=_Color.rgb*tex2D(_RampTex,halfLambert.rr).rgb;

所以我们用半兰伯特去采样Ramptex，然后乘以颜色。

效果：

高光（Specular）

//高光计算
fixed spec =pow(saturate( dot(worldNormal,halfDir1)),_Gloss*0.2);
//用于在给定的范围内实现平滑的插值。当 roughness 在 roughness - 0.3 到 roughness - 0.1 之间时，combineSpec 会平滑地变化，以控制高光的混合效果。
fixed combineSpec =smoothstep(roughness-0.3,roughness-0.1,spec);
fixed3 
//第一次lerp将最终的高光效果（第二次lerp）与漫反射颜色 Diffuse 进行插值，插值因子为 roughness
第二次lerp采样到的反射颜色 Reflection 乘以 _SpecularColor 和 Diffuse，形成一种增强的高光颜色。
这个结果再与 _SpecularColor.rgb 进行插值，插值因子为 0.35。
Specular=lerp(Diffuse,lerp(Reflection*_SpecularColor*Diffuse,_SpecularColor.rgb,0.35)*2.2,roughness);

边缘轮廓光（菲涅尔）

fixed Fresnel =pow(1-dot(worldViewDir,worldNormal),_FresnelScale);

玉石内部纹理（视差映射）

fixed3 reflDir =reflect(-i.tangentView,fixed3(0,0,1));//计算入射向量关于法线的反射方向，结果存储在 reflDir 中
float depth=_TexDepth / abs(reflDir.z);//计算深度，控制反射偏移量的大小
float2 uvOffset=reflDir.xy*depth / 1024;//添加深度
i.uv += uvOffset;//将计算出的 UV 偏移量添加到原始 UV 坐标上。

 环境光反射（CubeMap/Ambient）

        CubeMap反射：第一行计算出反射向量，其作用是体现视角的光线如何在表面上反射。然后，CubeMap 根据这个反射向量采样反射颜色，根据材质的光泽度 _Gloss 计算出一个用于CubeMap 采样的 LOD（细节层次）级别。

fixed3 worldRefl =reflect(-worldViewDir,worldNormal);
fixed3 Reflection=texCUBElod(_Cubemap,float4(worldRefl,8*(255-_Gloss)/255))*_ReflCol;

        环境光反射

fixed3 Albedo =tex2D( _MainTex,i.uv).rgb;
fixed3 Ambient = UNITY_LIGHTMODEL_AMBIENT.rgb * Albedo;

代码总结：

Shader "sss玉石" {
	Properties {
        _MainTex("_depthTex",2D)="white"{}
		_RampTex("Ramp Texture",2D)="White"{}
		_Cubemap("Refl Cubemap",Cube)= "_Skybox"{}
		_TexDepth("Texture Depth",float)= 10
		_TexTile("Texture Tiling",float)= 1
		_Color("Color Tint",color)=(1,1,1,1)
		_ReflCol("Ref1l Color",Color)=(1,1,1,1)
		_Gloss("Gloss" ,Range(1,255))=20
		_Metallic("Metallic",Range(0,1))=0
		_SpecularColor("Specular color",Color)=(1,1,1,1)
		_SpecOffset("spec  0ffset",vector)=(0,0,0,1)
		_FresnelScale("Fresnel Scale",Range(2,8))=2
		_FresnelColor("Fresnel Color",Color)=(1,1,1,1)
	}
	SubShader
	{
		Pass 
		{
			Tags {"Lightmode"="ForwardBase" }
            CGPROGRAM

            #pragma vertex vert
            #pragma fragment frag
			#pragma multi_compile_fwdbase
            #include "UnityCG.cginc"
			#include "Lighting.cginc"

			uniform fixed4  _Color;
			uniform float _TexTile;
			uniform sampler2D _RampTex;
			uniform sampler2D _MainTex;
			uniform float _TexDepth;
			uniform float4 _MainTex_ST;
			uniform fixed4 _SpecularColor;
			uniform float4 _SpecOffset1;
			uniform float _FresnelScale;
			uniform fixed4 _FresnelColor;
			uniform samplerCUBE _Cubemap;
			uniform float _Gloss;
			uniform float _Metallic;
			uniform fixed4 _ReflCol;


			struct a2v	
			{
                float4 vertex : POSITION;
                float4 tangent : TANGENT;
                float4 texcoord : TEXCOORD0;
                float3 normal : NORMAL;
            };
			struct v2f
			{
                float4 pos:SV_POSITION;
                float3 worldNormal :TEXCOORD0;
                float2 uv : TEXCOORD1;
                float3 WorldPos : TEXCOORD2;
				float3 tangentView :TEXCOORD3;
				float3 tangentNorm :TEXCOORD4;
            };
            					
			
			
            v2f vert(a2v v)
            {
            	v2f o;
				o.pos = UnityObjectToClipPos(v.vertex);
				o.worldNormal = UnityObjectToWorldNormal(v.normal);
				o.uv=TRANSFORM_TEX(v.texcoord,_MainTex)* _TexTile;
				o.WorldPos =mul(unity_ObjectToWorld, v.vertex).xyz;
				TANGENT_SPACE_ROTATION;
				o.tangentView=mul(rotation,normalize(ObjSpaceViewDir(v.vertex)));
                return o;
            }

						
            fixed4 frag(v2f i):SV_TARGET
            {
			    //向量准备
				float3 WorldPos = i.WorldPos;
				fixed3 worldNormal = normalize(i.worldNormal);
				fixed3 worldLightDir = normalize( UnityWorldSpaceLightDir(WorldPos));
				fixed3 worldViewDir = normalize(UnityWorldSpaceViewDir(WorldPos));
				fixed halfLambert = dot(worldNormal,worldLightDir)* 0.5 + 0.5;
				fixed3 halfDir1 =normalize(worldViewDir + _SpecOffset1.xyz + worldLightDir);
				fixed roughness=_Gloss/255;

				fixed3 reflDir =reflect(-i.tangentView,fixed3(0,0,1));
				float depth=_TexDepth / abs(reflDir.z);
				float2 uvOffset=reflDir.xy*depth / 1024;
				i.uv += uvOffset;

				fixed3 Albedo =tex2D( _MainTex,i.uv).rgb;
				fixed3 Ambient = UNITY_LIGHTMODEL_AMBIENT.xyz * Albedo;
				//漫反射
				fixed3 Diffuse=_Color.rgb*tex2D(_RampTex,halfLambert.rr).rgb;

				fixed3 worldRefl =reflect(-worldViewDir,worldNormal);
				fixed3 Reflection=texCUBElod(_Cubemap,float4(worldRefl,8*(255-_Gloss)/255))*_ReflCol;

				fixed spec =pow(saturate( dot(worldNormal,halfDir1)),_Gloss*0.2);

				fixed combineSpec =smoothstep(roughness-0.3,roughness-0.1,spec);
				fixed3 Specular =lerp(Diffuse,lerp(Reflection*_SpecularColor*Diffuse,_SpecularColor.rgb,0.35)*2.2,roughness);
				//菲涅尔
				fixed Fresnel =pow(max(0.0,1-dot(worldViewDir,worldNormal)),_FresnelScale);

				fixed3 BaseCol=lerp(Diffuse,Specular,combineSpec)+ Ambient;
				fixed3 ReflCol = lerp(BaseCol,Reflection,_Metallic);
				fixed3 finalCol =lerp(ReflCol,_FresnelColor.xyz,Fresnel*(1-_Metallic));
				return fixed4( finalCol,1.0);
				//return 
            }
            ENDCG
        }
	} 
	FallBack "Diffuse"
}