Unity ShaderLab学习总结

转载 2015年11月18日 17:48:31

Unity ShaderLab学习总结

Why Bothers?

为什么已经有ShaderForge这种可视化Shader编辑器、为什么Asset Store已经有那么多炫酷的Shader组件可下载,还是有必要学些Shader的编写?

  • 因为上面这些Shader工具/组件最终都是以Shader文件的形式而存在。
  • 需要开发人员/技术美术有能力对Shader进行功能分析、效率评估、选择、优化、甚至是Debug。
  • 对于特殊的需求,可能还是直接编写Shader比较实际、高效。

总之,Shader编写是重要的;但至于紧不紧急,视乎项目需求。

参考资源

  • Youtube:https://www.youtube.com/watch?v=hDJQXzajiPg (包括part1-6)。视频是最佳的学习方式没有之一,所以墙裂建议就算不看下文的所有内容,都要去看一下part1。
  • 书籍:《Unity 3D ShaderLab开发实战详解》
  • Unity各种官方文档

涉及范围

本文只讨论Unity ShaderLab相关的知识和使用方法。但,

使用Shader


如上图,一句话总结:
1. GameObject里有MeshRenderer,
2. MeshRenderer里有Material列表,
3. 每个Material里有且只有一个Shader;
4. Material在编辑器暴露该Shader的可调属性。
所以关键是怎么编写Shader。

Shader基础

编辑器

使用MonoDevelop这反人类的IDE来编写Shader居然是让人满意的。有语法高亮,无语法提示。
如果习惯VisualStudio,可以如下实现.Shader文件的语法高亮。

  • 下载作者donaldwu自己添加的关键词文件usertype.dat。其包括了Unity ShaderLab的部分关键字,和HLSL的所有关键字。关键字以后持续添加中。
  • 将下载的usertype.dat放到Microsoft Visual Studio xx.x\CommonX\IDE\文件夹下;
  • 打开VS,工具>选项>文本编辑器>文件扩展名,扩展名里填“shader”,编辑器选VC++,点击添加;
  • 重启VS,Done。

Shader

Shader "ShaderLab Tutorials/TestShader"
{
    // ...
}


Shader的名字会直接决定shader在material里出现的路径

SubShader

Shader "ShaderLab Tutorials/TestShader" {
    SubShader
    {
        //...
    }
}

一个Shader有多个SubShader。一个SubShader可理解为一个Shader的一个渲染方案。即SubShader是为了针对不同的显卡而编写的。每个Shader至少1个SubShader、理论可以无限多个,但往往两三个就足够。
SubShader和显卡的兼容性判断,和SubShader的标签、Pass的标签和显卡支持的“Unity渲染路径”有关。这些都会在下面逐一提到。

SubShader的Tag

Shader "ShaderLab Tutorials/TestShader" {
    SubShader
    {
        Tags { "Queue"="Geometry+10" "RenderType"="Opaque" }
        //...
    }
}

SubShader内部可以有标签(Tags)的定义。Tag指定了这个SubShader的渲染顺序(时机),以及其他的一些设置。

  • "Queue"标签。定义渲染顺序。预制的值为
    • "Background"。值为1000。比如用于天空盒。
    • "Geometry"。值为2000。大部分物体在这个队列。不透明的物体也在这里。这个队列内部的物体的渲染顺序会有进一步的优化(应该是从近到远,early-z test可以剔除不需经过FS处理的片元)。其他队列的物体都是按空间位置的从远到近进行渲染。
    • "AlphaTest"。值为2450。已进行AlphaTest的物体在这个队列。
    • "Transparent"。值为3000。透明物体。
    • "Overlay"。值为4000。比如镜头光晕。
    • 用户可以定义任意值,比如"Queue"="Geometry+10"
  • "RenderType"标签。Unity可以运行时替换符合特定RenderType的所有Shader。Camera.RenderWithShader或者Camera.SetReplacementShader配合使用。Unity内置的RenderType包括:
    • "Opaque":绝大部分不透明的物体都使用这个;
    • "Transparent":绝大部分透明的物体、包括粒子特效都使用这个;
    • "Background":天空盒都使用这个;
    • "Overlay":GUI、镜头光晕都使用这个;
    • 还有其他可参考Rendering with Replaced Shaders;用户也可以定义任意自己的RenderType字符串。
  • "ForceNoShadowCasting",值为"true"时,表示不接受阴影。
  • "IgnoreProjector",值为"true"时,表示不接受Projector组件的投影。

Pass

Shader "ShaderLab Tutorials/TestShader" {
    SubShader {
        Pass
        {
            //...
        }
    }
}

一个SubShader(渲染方案)是由一个个Pass块来执行的。每个Pass都会消耗对应的一个DrawCall。在满足渲染效果的情况下尽可能地减少Pass的数量。

Pass的Tag

Shader "ShaderLab Tutorials/TestShader" {
    SubShader {
        Pass
        {
            Tags{ "LightMode"="ForwardBase" }
            //...
        }
    }
}

和SubShader有自己专属的Tag类似,Pass也有Pass专属的Tag。
其中最重要Tag是 "LightMode",指定Pass和Unity的哪一种渲染路径(“Rendering Path”)搭配使用。这里需要描述的Tag取值可包括:

  • Always,永远都渲染,但不处理光照
  • ShadowCaster,用于渲染产生阴影的物体
  • ShadowCollector,用于收集物体阴影到屏幕坐标Buff里。

其他渲染路径相关的Tag详见下面章节“Unity渲染路径种类”。
具体所有Tag取值,可参考ShaderLab syntax: Pass Tags

FallBack

Shader "ShaderLab Tutorials/TestShader"{
    SubShader { Pass {} }

    FallBack "Diffuse" // "Diffuse"即Unity预制的固有Shader
    // FallBack Off //将关闭FallBack
}

当本Shader的所有SubShader都不支持当前显卡,就会使用FallBack语句指定的另一个Shader。FallBack最好指定Unity自己预制的Shader实现,因其一般能够在当前所有显卡运行。

Properties

Shader "ShaderLab Tutorials/TestShader"
{
    Properties {
    _Range ("My Range", Range (0.02,0.15)) = 0.07 // sliders
    _Color ("My Color", Color) = (.34, .85, .92, 1) // color
    _2D ("My Texture 2D", 2D) = "" {} // textures
    _Rect("My Rectangle", Rect) = "name" { }
    _Cube ("My Cubemap", Cube) = "name" { }
    _Float ("My Float", Float) = 1
    _Vector ("My Vector", Vector) = (1,2,3,4)
    }

    // Shader
    SubShader{
        Pass{
          //...
          uniform float4 _Color;
          //...
          float4 frag() : COLOR{ return fixed4(_Color); }
          //...
          }
    }

    //fixed pipeline
    SubShader    {
        Pass{
            Color[_Color]
        }
    }
}
  • Shader在Unity编辑器暴露给美术的参数,通过Properties来实现。
  • 所有可能的参数如上所示。主要也就Float、Vector和Texture这3类。
  • 除了通过编辑器编辑Properties,脚本也可以通过Material的接口(比如SetFloatSetTexture编辑)
  • 之后在Shader程序通过[name](固定管线)或直接name(可编程Shader)访问这些属性。

Shader中的数据类型

有3种基本数值类型:floathalffixed
这3种基本数值类型可以再组成vector和matrix,比如half3是由3个half组成、float4x4是由16个float组成。

  • float:32位高精度浮点数。
  • half:16位中精度浮点数。范围是[-6万, +6万],能精确到十进制的小数点后3.3位。
  • fixed:11位低精度浮点数。范围是[-2, 2],精度是1/256。

数据类型影响性能

  • 精度够用就好。
    • 颜色和单位向量,使用fixed
    • 其他情况,尽量使用half(即范围在[-6万, +6万]内、精确到小数点后3.3位);否则才使用float
  • 不要将低精度fixed类型转换为更高的精度,否则会产生性能问题。
  • 低精度fixed不要使用“swizzle”(即形如myFixed4.xyzwmyFixed2.xyxy,中文不知咋译,“搅和
    访问”?),否则会产生性能问题。

    作者donaldwu说:swizzle在编写Shader里是经常用到的,但到底怎样才算swizzle?myFixed4.x算不算?myFixed4.xyzw算不算?myFixed4.xyxy算不算?还是都算?
    这个目前没有找到权威的定义,所以为了不要影响效率,建议fixed尽量不要出现上面任意一种形式。

Shader形态

Shader形态之1:固定管线

固定管线是为了兼容老式显卡。都是顶点光照。之后固定管线可能是被Unity抛弃的功能,所以最好不学它、当它不存在。特征是里面出现了形如下面Material块、没有CGPROGRAMENDCG块。

Shader "ShaderLab Tutorials/TestShader"
{
    Properties {
    _Color ("My Color", Color) = (.34, .85, .92, 1) // color
    }

    // Fixed Pipeline
    SubShader
    {
        Pass
        {
            Material{
            Diffuse [_Color]
            Ambient [_Color]
            }

            Lighting On
        }
    }
}

Shader形态之2:可编程Shader

Shader "ShaderLab Tutorials/TestShader"
{
    Properties {}

    SubShader
    {
        Pass
        {
          // ... the usual pass state setup ...

          CGPROGRAM
          // compilation directives for this snippet, e.g.:
          #pragma vertex vert
          #pragma fragment frag

          // the Cg/HLSL code itself
          float4 vert(float4 v:POSITION) : SV_POSITION{
              return mul(UNITY_MATRIX_MVP, v);
          }
          float4 frag() : COLOR{
              return fixed4(1.0, 0.0, 0.0, 1.0);
          }
          ENDCG
          // ... the rest of pass setup ...
          }
    }
}
  • 功能最强大、最自由的形态。
  • 特征是在Pass里出现CGPROGRAMENDCG
  • 编译指令#pragma。详见官网Cg snippets。其中重要的包括:
编译指令 示例/含义
#pragma vertex name
#pragma fragment name
替换name,来指定Vertex Shader函数、Fragment Shader函数。
#pragma target name 替换name(为2.03.0等)。设置编译目标shader model的版本。
#pragma only_renderers name name ...
#pragma exclude_renderers name name...
#pragma only_renderers gles gles3
#pragma exclude_renderers d3d9 d3d11 opengl
只为指定渲染平台(render platform)编译
  • 引用库。通过形如#include "UnityCG.cginc"引入指定的库。常用的就是UnityCG.cginc了。其他库详见官网Built-in shader include files
  • ShaderLab内置值。Unity给Shader程序提供了便捷的、常用的值,比如下面例子中的UNITY_MATRIX_MVP就代表了这个时刻的MVP矩阵。详见官网ShaderLab built-in values
  • Shader输入输出参数语义(Semantics)。在管线流程中每个阶段之间(比如Vertex Shader阶段和FragmentShader阶段之间)的输入输出参数,通过语义字符串,来指定参数的含义。常用的语义包括:COLORSV_PositionTEXCOORD[n]。完整的参数语义可见HLSL Semantic(由于是HLSL的连接,所以可能不完全在Unity里可以使用)。
  • 特别地,因为Vertex Shader的的输入往往是管线的最开始,Unity为此内置了常用的数据结构:
数据结构 含义
appdata_base vertex shader input with position, normal, one texture coordinate.
appdata_tan vertex shader input with position, normal, tangent, one texture coordinate.
appdata_full vertex shader input with position, normal, tangent, vertex color and two texture coordinates.
appdata_img vertex shader input with position and one texture coordinate.

Shader形态之3:SurfaceShader

Shader "ShaderLab Tutorials/TestShader"
{
    Properties {   }

    // Surface Shader
    SubShader {
      Tags { "RenderType" = "Opaque" }
      CGPROGRAM
      #pragma surface surf Lambert
      struct Input {
          float4 color : COLOR;
      };
      void surf (Input IN, inout SurfaceOutput o) {
          o.Albedo = 1;
      }
      ENDCG
    }
    FallBack "Diffuse"
}
  • SurfaceShader可以认为是一个光照Shader的语法糖、一个光照VS/FS的生成器。减少了开发者写重复代码的需要。
  • 在手游,由于对性能要求比较高,所以不建议使用SurfaceShader。因为SurfaceShader是一个比较“通用”的功能,而通用往往导致性能不高。
  • 特征是在SubShader里出现CGPROGRAMENDCG块。(而不是出现在Pass里。因为SurfaceShader自己会编译成多个Pass。)
  • 编译指令是:
    #pragma surface surfaceFunction lightModel [optionalparams]
    • surfaceFunction:surfaceShader函数,形如void surf (Input IN, inout SurfaceOutput o)
    • lightModel:使用的光照模式。包括Lambert(漫反射)和BlinnPhong(镜面反射)。
      • 也可以自己定义光照函数。比如编译指令为#pragma surface surf MyCalc
  • 你定义输入数据结构(比如上面的Input)、编写自己的Surface函数处理输入、最终输出修改过后的SurfaceOutput。SurfaceOutput的定义为
    struct SurfaceOutput {
      half3 Albedo; // 纹理颜色值(r, g, b)
      half3 Normal; // 法向量(x, y, z)
      half3 Emission; // 自发光颜色值(r, g, b)
      half Specular; // 镜面反射度
      half Gloss; // 光泽度
      half Alpha; // 不透明度
    };

Unity渲染路径(Rendering Path)种类

概述

开发者可以在Unity工程的PlayerSettings设置对渲染路径进行3选1:

  • Deferred Lighting,延迟光照路径。3者中最高质量地还原光照阴影。光照性能只与最终像素数目有关,光源数量再多都不会影响性能。
  • Forward Rendering,顺序渲染路径。能发挥出Shader全部特性的渲染路径,当然也就支持像素级光照。最常用、功能最自由,性能与光源数目*受光照物体数目有关,具体性能视乎其具体使用到的Shader的复杂度。
  • Vertex Lit,顶点光照路径。顶点级光照。性能最高、兼容性最强、支持特性最少、品质最差。

渲染路径的内部阶段和Pass的LightMode标签

每个渲染路径的内部会再分为几个阶段。
然后,Shader里的每个Pass,都可以指定为不同的LightMode。而LightMode实际就是说:“我希望这个Pass在这个XXX渲染路径的这个YYY子阶段被执行”。

Deferred Ligting

渲染路径内部子阶段 对应的LightMode 描述
Base Pass "PrepassBase" 渲染物体信息。即把法向量、高光度到一张ARGB32的物体信息纹理上,把深度信息保存在Z-Buff上。
Lighting Pass 无对应可编程Pass 根据Base Pass得出的物体信息,在屏幕坐标系下,使用BlinnPhong光照模式,把光照信息渲染到ARGB32的光照信息纹理上(RGB表示diffuse颜色值、A表示高光度)
Final Pass "PrepassFinal" 根据光照信息纹理,物体再渲染一次,将光照信息、纹理信息和自发光信息最终混合。LightMap也在这个Pass进行。

Forward Rendering

渲染路径内部子阶段 对应的LightMode 描述
Base Pass "ForwardBase" 渲染:最亮一个的方向光光源(像素级)和对应的阴影、所有顶点级光源、LightMap、所有LightProbe的SH光源(Sphere Harmonic,球谐函数,效率超高的低频光)、环境光、自发光。
Additional Passes "ForwardAdd" 其他需要像素级渲染的的光源

注意到的是,在Forward Rendering中,光源可能是像素级光源、顶点级光源或SH光源。其判断标准是:

  • 配制成“Not Important”的光源都是顶点级光源和SH光源
  • 最亮的方向光永远都是像素级光源
  • 配置成“Important”的都是像素级光源
  • 上面2种情况加起来的像素级光源数目小于“Quality Settings”里面的“Pixel Light Count”的话,会把第1种情况的光源补为额外的像素级光源。

另外,配置成“Auto”的光源有更复杂的判断标注,截图如下:


具体可参考Forward Rendering Path Details

Vertex Lit

渲染路径内部子阶段 对应的LightMode 描述
Vertex "Vertex" 渲染无LightMap物体
VertexLMRGBM "VertexLMRGBM" 渲染有RGBM编码的LightMap物体
VertexLM "VertexLM" 渲染有双LDR编码的LightMap物体

不同LightMode的Pass的被选择

一个工程的渲染路径是唯一的,但一个工程里的Shader是允许配有不同LightMode的Pass的。
在Unity,策略是“从工程配置的渲染路径模式开始,按Deferred、Forward、VertxLit的顺序,搜索最匹配的LightMode的一个Pass”。
比如,在配置成Deferred路径时,优先选有Deferred相关LightMode的Pass;找不到才会选Forward相关的Pass;还找不到,才会选VertexLit相关的Pass。
再比如,在配置成Forward路径时,优先选Forward相关的Pass;找不到才会选VertexLit相关的Pass。

相关文章推荐

【转载】Unity ShaderLab学习总结

Why Bothers? 为什么已经有ShaderForge这种可视化Shader编辑器、为什么Asset Store已经有那么多炫酷的Shader组件可下载,还是有必要学些Shader的编写? ...
  • usausa2
  • usausa2
  • 2017年07月22日 17:22
  • 108

Unity ShaderLab学习总结

http://www.jianshu.com/p/7b9498e58659 Unity ShaderLab学习总结 Why Bothers? 为什么已经有ShaderForg...

【Unity3D】ShaderLab学习笔记

【Unity3D】ShaderLab学习笔记 1、什么是Shader: Shader(着色器)实际上就是一小段程序,它负责将输入的Mesh(多边形网格,一般使用三角形)以指定的方式和输入的贴图或者...

[Unity3D]Shader学习笔记之ShaderLab基础

简介  Unity Shader为控制渲染过程提供了一层抽象。如果没有它,开发者需要和很多文件设置打交道,才能让画面呈现出想要的效果;而在Unity Shader的帮助下,开发者只需要使用Shader...

Shader编程学习笔记(四)—— Unity Shader的组织形式(ShaderLab)

Unity Shader的形态   Unity官方手册上讲Unity Shader有三种不同的编写方案,这三种编写方案分别是surface shaders、vertex and fragment s...

Unity 3D ShaderLab 开发实战详解

  • 2016年02月26日 20:48
  • 43.29MB
  • 下载

【Unity5.x Shdaers】ShaderLab: Blending 混合

ShaderLab: Blending混合用于制作透明物体。当渲染图形时,在所有shaders执行并且所有textures应用之后,像素被写入屏幕。 它们如何与已经存在的内容组合由Blend命令控制。...

Unity3D的Shaderlab实例

  • 2014年09月28日 23:35
  • 30.91MB
  • 下载
内容举报
返回顶部
收藏助手
不良信息举报
您举报文章:Unity ShaderLab学习总结
举报原因:
原因补充:

(最多只允许输入30个字)