UnityShader 翻书效果

Shader "Achonor/TurnBook"
{
    Properties
    {
        _MainTex ("FrontTex", 2D) = "white" {}
        _BackTex ("BackTex", 2D) = "white" {}
        _Speed ("Turn _Speed", Range(0, 1)) = 0.5
        _XOffset ("Centor X Offset", float) = 5
        _Angle ("Angle", Range(0, 180)) = 180  
        _WaveLength("WaveLength",Range(-1, 1)) = 0
        _WaveHeight("WaveHeight",Range(0, 8)) = 1
    }
    CGINCLUDE
    #include "UnityCG.cginc"

    struct appdata
    {
        float4 vertex : POSITION;
        float2 uv : TEXCOORD0;
    };

    struct v2f
    {
        float4 uv : TEXCOORD0;
        float4 pos : SV_POSITION;
    };
    sampler2D _MainTex;
    sampler2D _BackTex;
    float4 _MainTex_ST;
    float4 _BackTex_ST;
    float _Speed;
    float _XOffset;
    float _Angle;
    float _WaveLength;
    float _WaveHeight;

    v2f vert(appdata v)
    {
        v2f o;
        float sin_v, cos_v;
        sincos(radians(_Angle * ((_Time.y * _Speed) % 1)) , sin_v, cos_v);
        float4x4 rt_matrix = {
            cos_v,  -sin_v, 0, 0,
            sin_v,  cos_v,  0, 0,
            0,      0,      1, 0,
            0,      0,      0, 1,
        };
        v.vertex += float4(_XOffset, 0, 0, 0);
        float distance = sqrt(v.vertex.x * v.vertex.x);
        v.vertex.y = sin(distance * _WaveLength)  * _WaveHeight * sin_v;;
        v.vertex.x = v.vertex.x * (0.9 + abs(cos_v * 0.1));

        v.vertex = mul(rt_matrix, v.vertex);
        v.vertex -= float4(_XOffset, 0, 0, 0);

        o.pos = UnityObjectToClipPos(v.vertex);
        o.uv.xy = TRANSFORM_TEX(v.uv, _MainTex);
        o.uv.zw = TRANSFORM_TEX(v.uv, _BackTex);
        return o;
    }

    fixed4 frag1(v2f i) : SV_Target
    {
        fixed4 col = tex2D(_MainTex, i.uv.xy);
        return col;
    }

    fixed4 frag2(v2f i) : SV_Target
    {
        fixed4 col = tex2D(_BackTex, i.uv.zw);
        return col;
    }
    ENDCG

    SubShader
    {
        Tags { "RenderType"="Opaque" }

        Pass
        {
            Cull Back

            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag1
            ENDCG
        }
        Pass
        {
            Cull Front

            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag2
            ENDCG
        }
    }
}