基于Automation Studio 4.10贝加莱PLC 电机驱动操作—程序控制电机运动

已于 2023-10-13 11:18:58 修改
阅读量1.3k 收藏 4
点赞数 1
分类专栏： plc_贝加莱 文章标签： 编辑器
于 2023-10-12 17:30:12 首次发布
版权声明：本文为博主原创文章，遵循 CC 4.0 BY-SA 版权协议，转载请附上原文出处链接和本声明。
本文链接：https://blog.csdn.net/WJLHW/article/details/133794978
版权

如果没使用不过Automation Studio 4.10软件，想要控制一个电机可能无从下手，那就练习一个小demo，熟悉熟悉使用程序控制贝加莱电机吧。

1.创建电机驱动的plc工程，在上一篇文章中已经说明，连接如下：

基于Automation Studio 4.10贝加莱PLC 电机驱动操作——新建工程

2.程序控制

2.2 例子控制程序

2.2.1 添加例程控制程序sample，新建用户程序文件夹，右击程序工程motion->add boject->package->双击“package empey”

2.2.2 重命名新建文件夹PACKAGE->USERPROGRAM

2.2.3添加轴控例子程序

2.2.4添加轴控例子程序

2.2.5控制程序如下

(********************************************************************
 * COPYRIGHT -- Bernecker + Rainer
 ********************************************************************
 * PROGRAM: Basic
 * File: basicCyclic.st
 * Author: Bernecker + Rainer
 * Created: December 01, 2009
 ********************************************************************
 * Implementation of Program Basic
 ********************************************************************)
PROGRAM _CYCLIC

(***************************************************************
        Control Sequence
***************************************************************)
(* status information is read before the step sequencer to attain a shorter reaction time *)
(************************ MC_READSTATUS *************************)
MC_ReadStatus_0.Enable := NOT(MC_ReadStatus_0.Error);
MC_ReadStatus_0.Axis := Axis1Obj;
MC_ReadStatus_0();
BasicControl.AxisState.Disabled             := MC_ReadStatus_0.Disabled;
BasicControl.AxisState.StandStill           := MC_ReadStatus_0.StandStill;
BasicControl.AxisState.Stopping             := MC_ReadStatus_0.Stopping;
BasicControl.AxisState.Homing               := MC_ReadStatus_0.Homing;
BasicControl.AxisState.DiscreteMotion       := MC_ReadStatus_0.DiscreteMotion;
BasicControl.AxisState.ContinuousMotion     := MC_ReadStatus_0.ContinuousMotion;
BasicControl.AxisState.SynchronizedMotion   := MC_ReadStatus_0.SynchronizedMotion;
BasicControl.AxisState.ErrorStop            := MC_ReadStatus_0.Errorstop;

(********************MC_BR_READDRIVESTATUS***********************)
MC_BR_ReadDriveStatus_0.Enable := NOT(MC_BR_ReadDriveStatus_0.Error);
MC_BR_ReadDriveStatus_0.Axis := Axis1Obj;
MC_BR_ReadDriveStatus_0.AdrDriveStatus := ADR(BasicControl.Status.DriveStatus);
MC_BR_ReadDriveStatus_0();

(******************** MC_READACTUALPOSITION *********************)
MC_ReadActualPosition_0.Enable := (NOT(MC_ReadActualPosition_0.Error));
MC_ReadActualPosition_0.Axis := Axis1Obj;
MC_ReadActualPosition_0();
IF(MC_ReadActualPosition_0.Valid = TRUE)THEN
    BasicControl.Status.ActPosition := MC_ReadActualPosition_0.Position;
END_IF

(******************** MC_READACTUALVELOCITY *********************)
MC_ReadActualVelocity_0.Enable := (NOT(MC_ReadActualVelocity_0.Error));
MC_ReadActualVelocity_0.Axis := Axis1Obj;
MC_ReadActualVelocity_0();
IF(MC_ReadActualVelocity_0.Valid = TRUE)THEN
    BasicControl.Status.ActVelocity := MC_ReadActualVelocity_0.Velocity;
END_IF

(************************ MC_READAXISERROR **********************)
MC_ReadAxisError_0.Enable := NOT(MC_ReadAxisError_0.Error);
MC_ReadAxisError_0.Axis := Axis1Obj;
MC_ReadAxisError_0.DataAddress := ADR(BasicControl.Status.ErrorText);
MC_ReadAxisError_0.DataLength := SIZEOF(BasicControl.Status.ErrorText);
MC_ReadAxisError_0.DataObjectName := 'acp10etxen';
MC_ReadAxisError_0();

(**************** CHECK FOR GENERAL AXIS ERROR ******************)
    IF ((MC_ReadAxisError_0.AxisErrorID <> 0) AND (MC_ReadAxisError_0.Valid = TRUE)) THEN
        AxisStep := STATE_ERROR_AXIS;
(***************** CHECK IF POWER SHOULD BE OFF *******************)
    ELSIF ((BasicControl.Command.Power = FALSE) AND (MC_ReadAxisError_0.Valid = TRUE)) THEN
        IF ((MC_ReadStatus_0.Errorstop = TRUE) AND (MC_ReadStatus_0.Valid = TRUE)) THEN
            AxisStep := STATE_ERROR_RESET;
        ELSE
            AxisStep := STATE_WAIT;
        END_IF
    END_IF

(* central monitoring OF stop command attains a shorter reaction TIME in CASE OF emergency stop *)
(******************CHECK FOR STOP COMMAND************************)
    IF (BasicControl.Command.Stop = TRUE) THEN
        IF ((AxisStep >= STATE_HOME) AND (AxisStep <= STATE_ERROR)) THEN
            (* reset all FB execute inputs we use *)
            MC_Home_0.Execute := 0;
            MC_Stop_0.Execute := 0;
            MC_MoveAbsolute_0.Execute := 0;
            MC_MoveAdditive_0.Execute := 0;
            MC_MoveVelocity_0.Execute := 0;
            MC_ReadAxisError_0.Acknowledge := 0;
            MC_Reset_0.Execute := 0;
            MC_Halt_0.Execute := 0;

            (* reset user commands *)
            BasicControl.Command.Halt := 0;
            BasicControl.Command.Home := 0;
            BasicControl.Command.MoveJogPos := 0;
            BasicControl.Command.MoveJogNeg := 0;
            BasicControl.Command.MoveVelocity := 0;
            BasicControl.Command.MoveAbsolute := 0;
            BasicControl.Command.MoveAdditive := 0;
            AxisStep := STATE_STOP;
        END_IF
    END_IF

CASE AxisStep OF

(******************** WAIT *************************)
    STATE_WAIT:  (* STATE: Wait *)
        IF (BasicControl.Command.Power = TRUE) THEN
            AxisStep := STATE_POWER_ON;
        ELSE
            MC_Power_0.Enable := FALSE;
        END_IF

        (* reset all FB execute inputs we use *)
        MC_Home_0.Execute := FALSE;
        MC_Stop_0.Execute := FALSE;
        MC_MoveAbsolute_0.Execute := FALSE;
        MC_MoveAdditive_0.Execute := FALSE;
        MC_MoveVelocity_0.Execute := FALSE;
        MC_Halt_0.Execute := FALSE;
        MC_ReadAxisError_0.Acknowledge := FALSE;
        MC_Reset_0.Execute := FALSE;

        (* reset user commands *)
        BasicControl.Command.Stop := FALSE;
        BasicControl.Command.Halt := FALSE;
        BasicControl.Command.Home := FALSE;
        BasicControl.Command.MoveJogPos := FALSE;
        BasicControl.Command.MoveJogNeg := FALSE;
        BasicControl.Command.MoveVelocity := FALSE;
        BasicControl.Command.MoveAbsolute := FALSE;
        BasicControl.Command.MoveAdditive := FALSE;

        BasicControl.Status.ErrorID := 0;

(******************** POWER ON **********************)
    STATE_POWER_ON:  (* STATE: Power on *)
        MC_Power_0.Enable := TRUE;
        IF (MC_Power_0.Status = TRUE) THEN
            AxisStep := STATE_READY;
        END_IF
        (* if a power error occured go to error state *)
        IF (MC_Power_0.Error = TRUE) THEN
            BasicControl.Status.ErrorID := MC_Power_0.ErrorID;
            AxisStep := STATE_ERROR;
        END_IF

(******************** READY **********************)
    STATE_READY:  (* STATE: Waiting for commands *)
        IF (BasicControl.Command.Home = TRUE)THEN
            BasicControl.Command.Home := FALSE;
            AxisStep := STATE_HOME;

        ELSIF (BasicControl.Command.Stop = TRUE) THEN
            AxisStep := STATE_STOP;

        ELSIF (BasicControl.Command.MoveJogPos = TRUE) THEN
            AxisStep := STATE_JOG_POSITIVE;

        ELSIF (BasicControl.Command.MoveJogNeg = TRUE) THEN
            AxisStep := STATE_JOG_NEGATIVE;

        ELSIF (BasicControl.Command.MoveAbsolute = TRUE) THEN
            BasicControl.Command.MoveAbsolute := FALSE;
            AxisStep := STATE_MOVE_ABSOLUTE;

        ELSIF (BasicControl.Command.MoveAdditive = TRUE) THEN
            BasicControl.Command.MoveAdditive := FALSE;
            AxisStep := STATE_MOVE_ADDITIVE;

        ELSIF (BasicControl.Command.MoveVelocity = TRUE) THEN
            BasicControl.Command.MoveVelocity := FALSE;
            AxisStep := STATE_MOVE_VELOCITY;
            
        ELSIF (BasicControl.Command.Halt = TRUE) THEN
            BasicControl.Command.Halt := FALSE;
            AxisStep := STATE_HALT;                                    
        END_IF

(******************** HOME **********************)
    STATE_HOME:  (* STATE: start homing process *)
        MC_Home_0.Position := BasicControl.Parameter.HomePosition;
        MC_Home_0.HomingMode := BasicControl.Parameter.HomeMode;
        MC_Home_0.Execute := TRUE;
        IF (MC_Home_0.Done = TRUE) THEN
            MC_Home_0.Execute := FALSE;
            AxisStep := STATE_READY;
        END_IF
        (* if a homing error occured go to error state *)
        IF (MC_Home_0.Error = TRUE) THEN
            MC_Home_0.Execute := FALSE;
            BasicControl.Status.ErrorID := MC_Home_0.ErrorID;
            AxisStep := STATE_ERROR;
        END_IF
        
(***********************HALT_MOVEMENT***************************)
    STATE_HALT:   (* STATE: Halt movement *)
        MC_Halt_0.Deceleration := BasicControl.Parameter.Deceleration;
        MC_Halt_0.Execute := TRUE;
        IF (MC_Halt_0.Done = TRUE) THEN
            MC_Halt_0.Execute := FALSE;
            AxisStep := STATE_READY;        
        END_IF
        (* check if error occured *)
        IF (MC_Halt_0.Error = TRUE) THEN
            BasicControl.Status.ErrorID := MC_Halt_0.ErrorID;
            MC_Halt_0.Execute := FALSE;
            AxisStep := STATE_ERROR;
        END_IF                                         

(*********************** STOP MOVEMENT *************************)
    STATE_STOP:  (* STATE: Stop movement *)
        MC_Stop_0.Deceleration := BasicControl.Parameter.Deceleration;
        MC_Stop_0.Execute := TRUE;
        (* if axis is stopped go to ready state *)
        IF ((MC_Stop_0.Done = TRUE) AND (BasicControl.Command.Stop = FALSE)) THEN
            MC_Stop_0.Execute := FALSE;
            AxisStep := STATE_READY;
        END_IF
        (* check if error occured *)
        IF (MC_Stop_0.Error = TRUE) THEN
            BasicControl.Status.ErrorID := MC_Stop_0.ErrorID;
            MC_Stop_0.Execute := FALSE;
            AxisStep := STATE_ERROR;
        END_IF

(******************** START JOG MOVEMENT POSITVE **********************)
     STATE_JOG_POSITIVE:  (* STATE: Start jog movement in positive direction *)
        MC_MoveVelocity_0.Velocity      := BasicControl.Parameter.JogVelocity;
        MC_MoveVelocity_0.Acceleration  := BasicControl.Parameter.Acceleration;
        MC_MoveVelocity_0.Deceleration  := BasicControl.Parameter.Deceleration;
        MC_MoveVelocity_0.Direction     := mcPOSITIVE_DIR;
        MC_MoveVelocity_0.Execute := TRUE;
        IF (BasicControl.Command.MoveJogPos = FALSE) THEN
            MC_MoveVelocity_0.Execute := FALSE;
            AxisStep := STATE_HALT;
        END_IF
        (* check if error occured *)
        IF (MC_MoveVelocity_0.Error = TRUE) THEN
            BasicControl.Status.ErrorID := MC_MoveVelocity_0.ErrorID;
            MC_MoveVelocity_0.Execute := FALSE;
            AxisStep := STATE_ERROR;
        END_IF

(******************** START JOG MOVEMENT NEGATIVE **********************)
    STATE_JOG_NEGATIVE:  (* STATE: Start jog movement in negative direction *)
        MC_MoveVelocity_0.Velocity      := BasicControl.Parameter.JogVelocity;
        MC_MoveVelocity_0.Acceleration  := BasicControl.Parameter.Acceleration;
        MC_MoveVelocity_0.Deceleration  := BasicControl.Parameter.Deceleration;
        MC_MoveVelocity_0.Direction	    := mcNEGATIVE_DIR;
        MC_MoveVelocity_0.Execute := TRUE;
        IF (BasicControl.Command.MoveJogNeg = FALSE) THEN
            MC_MoveVelocity_0.Execute := FALSE;
            AxisStep := STATE_HALT;
        END_IF
        (* check if error occured *)
        IF (MC_MoveVelocity_0.Error = TRUE) THEN
            BasicControl.Status.ErrorID := MC_MoveVelocity_0.ErrorID;
            MC_MoveVelocity_0.Execute := FALSE;
            AxisStep := STATE_ERROR;
        END_IF

(******************** START ABSOLUTE MOVEMENT **********************)
     STATE_MOVE_ABSOLUTE:  (* STATE: Start absolute movement *)
        MC_MoveAbsolute_0.Position      := BasicControl.Parameter.Position; 
        MC_MoveAbsolute_0.Velocity      := BasicControl.Parameter.Velocity;
        MC_MoveAbsolute_0.Acceleration  := BasicControl.Parameter.Acceleration;
        MC_MoveAbsolute_0.Deceleration  := BasicControl.Parameter.Deceleration;
        MC_MoveAbsolute_0.Direction     := BasicControl.Parameter.Direction;
        MC_MoveAbsolute_0.Execute := TRUE;
        (* check if commanded position is reached *)
        IF (BasicControl.Command.Halt) THEN
            BasicControl.Command.Halt := FALSE;
            MC_MoveAbsolute_0.Execute := FALSE;
            AxisStep := STATE_HALT;
        ELSIF (MC_MoveAbsolute_0.Done = TRUE) THEN
            MC_MoveAbsolute_0.Execute := FALSE;
            AxisStep := STATE_READY;
        END_IF
        (* check if error occured *)
        IF (MC_MoveAbsolute_0.Error = TRUE) THEN
            BasicControl.Status.ErrorID := MC_MoveAbsolute_0.ErrorID;
            MC_MoveAbsolute_0.Execute := FALSE;
            AxisStep := STATE_ERROR;
        END_IF

(******************** START ADDITIVE MOVEMENT **********************)
    STATE_MOVE_ADDITIVE:  (* STATE: Start additive movement *)
        MC_MoveAdditive_0.Distance      := BasicControl.Parameter.Distance;
        MC_MoveAdditive_0.Velocity      := BasicControl.Parameter.Velocity;
        MC_MoveAdditive_0.Acceleration  := BasicControl.Parameter.Acceleration;
        MC_MoveAdditive_0.Deceleration  := BasicControl.Parameter.Deceleration;
        MC_MoveAdditive_0.Execute := TRUE;
        (* check if commanded distance is reached *)
        IF (BasicControl.Command.Halt) THEN
            BasicControl.Command.Halt := FALSE;
            MC_MoveAdditive_0.Execute := FALSE;
            AxisStep := STATE_HALT;
        ELSIF (MC_MoveAdditive_0.Done = TRUE) THEN
            MC_MoveAdditive_0.Execute := FALSE;
            AxisStep := STATE_READY;
        END_IF
        (* check if error occured *)
        IF (MC_MoveAdditive_0.Error = TRUE) THEN
            BasicControl.Status.ErrorID := MC_MoveAdditive_0.ErrorID;
            MC_MoveAdditive_0.Execute := FALSE;
            AxisStep := STATE_ERROR;
        END_IF

(******************** START VELOCITY MOVEMENT **********************)
    STATE_MOVE_VELOCITY:  (* STATE: Start velocity movement *)
        MC_MoveVelocity_0.Velocity      := BasicControl.Parameter.Velocity;
        MC_MoveVelocity_0.Acceleration  := BasicControl.Parameter.Acceleration;
        MC_MoveVelocity_0.Deceleration  := BasicControl.Parameter.Deceleration;
        MC_MoveVelocity_0.Direction     := BasicControl.Parameter.Direction;
        MC_MoveVelocity_0.Execute := TRUE;
        (* check if commanded velocity is reached *)
        IF (BasicControl.Command.Halt) THEN
            BasicControl.Command.Halt := FALSE;
            MC_MoveVelocity_0.Execute := FALSE;
            AxisStep := STATE_HALT;
        ELSIF (MC_MoveVelocity_0.InVelocity = TRUE) THEN
            MC_MoveVelocity_0.Execute := FALSE;
            AxisStep := STATE_READY;
        END_IF
        (* check if error occured *)
        IF (MC_MoveVelocity_0.Error = TRUE) THEN
            BasicControl.Status.ErrorID := MC_MoveVelocity_0.ErrorID;
            MC_MoveVelocity_0.Execute := FALSE;
            AxisStep := STATE_ERROR;
        END_IF

(******************** FB-ERROR OCCURED *************************)
    STATE_ERROR:  (* STATE: Error *)
        (* check if FB indicates an axis error *)
        IF (MC_ReadAxisError_0.AxisErrorCount<>0) THEN
            AxisStep := STATE_ERROR_AXIS;
        ELSE
            IF (BasicControl.Command.ErrorAcknowledge = TRUE) THEN
                BasicControl.Command.ErrorAcknowledge := FALSE;
                BasicControl.Status.ErrorID := 0;
                (* reset axis if it is in axis state ErrorStop *)
                IF ((MC_ReadStatus_0.Errorstop = TRUE) AND (MC_ReadStatus_0.Valid = TRUE)) THEN
                    AxisStep := STATE_ERROR_RESET;
                ELSE
                    AxisStep := STATE_WAIT;
                END_IF
            END_IF
        END_IF

(******************** AXIS-ERROR OCCURED *************************)
    STATE_ERROR_AXIS:  (* STATE: Axis Error *)
        IF (MC_ReadAxisError_0.Valid = TRUE) THEN
            IF (MC_ReadAxisError_0.AxisErrorID <> 0) THEN
                BasicControl.Status.ErrorID := MC_ReadAxisError_0.AxisErrorID;
            END_IF
            MC_ReadAxisError_0.Acknowledge := FALSE;
            IF (BasicControl.Command.ErrorAcknowledge = TRUE) THEN
                BasicControl.Command.ErrorAcknowledge := FALSE;
                (* acknowledge axis error *)
                IF (MC_ReadAxisError_0.AxisErrorID <> 0) THEN
                    MC_ReadAxisError_0.Acknowledge := TRUE;
                END_IF
            END_IF
            IF (MC_ReadAxisError_0.AxisErrorCount = 0) THEN
                (* reset axis if it is in axis state ErrorStop *)
                BasicControl.Status.ErrorID := 0;
                IF ((MC_ReadStatus_0.Errorstop = TRUE) AND (MC_ReadStatus_0.Valid = TRUE)) THEN
                    AxisStep := STATE_ERROR_RESET;
                ELSE
                    AxisStep := STATE_WAIT;
                END_IF
            END_IF
        END_IF

(******************** RESET DONE *************************)
    STATE_ERROR_RESET:  (* STATE: Wait for reset done *)
        MC_Reset_0.Execute := TRUE;
        (* reset MC_Power.Enable if this FB is in Error*)
        IF (MC_Power_0.Error = TRUE) THEN
            MC_Power_0.Enable := FALSE;
        END_IF
        IF(MC_Reset_0.Done = TRUE)THEN
            MC_Reset_0.Execute := FALSE;
            AxisStep := STATE_WAIT;
        ELSIF(MC_Reset_0.Error = TRUE) THEN
            MC_Reset_0.Execute := FALSE;
            AxisStep := STATE_ERROR;                    
        END_IF
(******************** SEQUENCE END *************************)
END_CASE

(***************************************************************
        Function Block Calls
***************************************************************)

(************************** MC_POWER ****************************)
MC_Power_0.Axis := Axis1Obj;  (* pointer to axis *)
MC_Power_0();

(************************** MC_HOME *****************************)
MC_Home_0.Axis := Axis1Obj;
MC_Home_0();

(********************** MC_MOVEABSOLUTE *************************)
MC_MoveAbsolute_0.Axis := Axis1Obj;
MC_MoveAbsolute_0();

(********************** MC_MOVEADDITIVE *************************)
MC_MoveAdditive_0.Axis := Axis1Obj;
MC_MoveAdditive_0();

(********************** MC_MOVEVELOCITY *************************)
MC_MoveVelocity_0.Axis := Axis1Obj;
MC_MoveVelocity_0();

(************************** MC_STOP *****************************)
MC_Stop_0.Axis := Axis1Obj;
MC_Stop_0();

(***************************MC_HALT******************************)
MC_Halt_0.Axis := Axis1Obj;
MC_Halt_0();

(************************** MC_RESET ****************************)
MC_Reset_0.Axis := Axis1Obj;
MC_Reset_0();

END_PROGRAM
初始化程序
PROGRAM _INIT

(* get axis object *)
Axis1Obj := ADR(gAxis01);

AxisStep := STATE_WAIT; (* start step *)

BasicControl.Parameter.Velocity             := 1000;  (*velocity for movement*)
BasicControl.Parameter.Acceleration         := 5000;  (*acceleration for movement*)
BasicControl.Parameter.Deceleration         := 5000;  (*deceleration for movement*)
BasicControl.Parameter.JogVelocity          := 400;   (*velocity for jogging *)
END_PROGRAM

2.2.6 例程控制程序仿真

2.2.7查看自己轴名，匹配到程序中

将程序中的轴名改成自己的轴名

2.2.8下载或者烧卡，这里选择烧卡

2.2.9打开仿真界面，鼠标放在程序窗口，ctrl+w，即可打开仿真界面

2.2.10 在仿真页面（watch）添加要观察的变量

2.2.11 在仿真页面（watch）运行仿真



2.3 自建控制程序

2.3.1 新建自己工程的文件夹，仿照2.2.1和2.2.2

2.3.2 添加自己的控制程序文件

2.3.3 编写自己的控制程序

2.3.4代码如下


PROGRAM _INIT
	(* Insert code here *)
	Axis01Ref	:= ADR(gAxis01);
	
END_PROGRAM

PROGRAM _CYCLIC
	(* Insert code here *)
	
	//使能
	MC_Power_0.Axis:=Axis01Ref;
	MC_Power_0.Enable:=MC_Power_0.Enable;
	MC_Power_0();
	//回零
	MC_Home_0.Axis:=Axis01Ref;
	MC_Home_0.Execute:=MC_Home_0.Execute ;
	MC_Home_0.Position:=0;
	MC_Home_0.HomingMode:=mcHOME_DIRECT ;
	MC_Home_0();
	//读取实际位置
	MC_ReadActualPosition_0.Axis:=Axis01Ref ;
	MC_ReadActualPosition_0.Enable:=1 ;
	MC_ReadActualPosition_0();
	//读取实际速度
	MC_ReadActualVelocity_0.Axis:= Axis01Ref;
	MC_ReadActualVelocity_0.Enable:=1 ;
	MC_ReadActualVelocity_0();
	//停止
	MC_Stop_0.Axis:= Axis01Ref;
	MC_Stop_0.Execute:=MC_Stop_0.Execute ;
	MC_Stop_0.Deceleration:=100 ;
	MC_Stop_0();
	//连续运动
	MC_MoveVelocity_0.Axis:=Axis01Ref ;
	MC_MoveVelocity_0.Execute:=MC_MoveVelocity_0.Execute ;
	MC_MoveVelocity_0.Velocity:=MC_MoveVelocity_0.Velocity ;
	MC_MoveVelocity_0.Acceleration:=1000 ;
	MC_MoveVelocity_0.Deceleration:=1000 ;
	MC_MoveVelocity_0.Direction:=mcPOSITIVE_DIR;
	MC_MoveVelocity_0( );
	
	
END_PROGRAM

PROGRAM _EXIT
	(* Insert code here *)
	 
END_PROGRAM

2.3.5 开始仿真，仿照2.2.7-2.2.8-2.2.9-2.2.10，打开watch

注意：仿真时cpu运行程序不能由冲突

2.3.7 设置变量，验证代码

1. 打开使能

2. 回零

3.设置速度开启运动

4.查看实时速度和位置

完成验证。

JHLLHW
关注
  • 1
    点赞
  • 踩
  • 4
    收藏
    觉得还不错? 一键收藏
  • 0
    评论
专栏目录
Automation Studio的安装、注册、升级
moehre的博客
01-29 8318
Automation Studio的安装、注册、升级
贝加莱plc 温控程序模块
12-08
贝加莱plc 温控标准程序,调用标准库编程, 自整定程序 .
AutomationStudio多功能仿真软件－液，汽，电实验解决方案
01-01
作为一个独特的软件解决方案Automation StudioTM广泛运用子成千上万的学校，以易用的环境提供直观的设计、演示、模拟和电路分析功能。 Automation Studio是十分适合不同的课程应用及教学，不同的科技工程学科都可以使用它。因此各学科可以共同承担成本．带来通大的成本效益。 整所学校都可以得益于Automation Studio 的多功能。多应用，适合多个科技工程课程的优势，Automation StudioTM是一个完整的解决方案，它不 但可以帮助教授最基础的理论，还可以提供高级的工业科技训练。 Automation StudioTM的直观性及简单易用的使用界面，有效的设计工具、现实模拟、互动动画及多功能多应用环境，都展示给学生，给学校的教学 带来极大的方便和益处。
【贝加莱PLC基础教学】5.AutomationStudio编程进阶_PID控制（未完成）
最新发布
A1617215315的博客
11-17 651
目前通过从基础教学1到基础教学4的内容，已经掌握了贝加莱AS软件基础的使用方法。接下来将通过一个仿真和一个实践项目的部分代码来了解如何在As软件中实现控制效果。当然这些只是最基础的控制语句，如果实现更好的控制效果还需要配合诸如PID参数整定和滤波等等环节。
Automation Studio与Matlab/Simulink结合使用
bubbeStar的博客
03-29 836
该文章介绍将Simulink的项目生成C语言代码并嵌入Automation Studio中进行使用
基于Automation Studio 4.10贝加莱PLC 电机驱动操作
WJLHW的博客
10-12 778
Automation Studio 4.10贝加莱PLC 电机驱动操作： 选择相应的硬件 CPU: X20CP1585；驱动器： 8EI2X2MWD10.0700-1；机：8LSA34.R0022D000-0；编码器卡：8EAC0122.003-1；触摸屏：6PPT50.0702-10B
电机控制程序设计经验
finhaz的博客
02-10 5617
  这边总结了一些电机程序编写中的经验，很多经验也来源于别人的博客或者和一些前辈的交流，在此贴出。 设计流程   平台的搭建需要考虑标准化问题。像dsp实验的模块化、各种标准协议采用、仿真验证到算法实现的流程等，都是属于最基本的要求。而多项工作的多人合力完成，关键在于标准化。标准化的接口设计，使得每个人都专注于实现各自模块中的核心功能。   先对算法进行系统级别仿真，工具有matlab等软件，而后...
【贝加莱PLC基础教学】2.5.AutiomationStudio基础编程与仿真
A1617215315的博客
10-14 1716
新手入门AS组态、编程和仿真。
Python的电机控制模拟程序
yuyuyuliang00的博客
09-20 1805
Python的电机控制模拟程序
基于80C51汇编/C语言的步进电机驱动程序
fmy_xfk的博客
09-10 2321
单片机实习：用汇编或C语言在80C51单片机上编写步进电机驱动程序。
经典的电机的速度PID控制程序.rar
05-24
经典的电机的速度PID控制程序 代码
贝加莱中文资料贝加莱功能块例程”，主要包括程序例程等内容，可供学习试用.zip
12-12
贝加莱中文资料贝加莱功能块例程”，主要包括程序例程等内容，可供学习试用
最完整的贝加莱PLC培训教程1.pdf
04-03
最完整的贝加莱PLC培训教程,有需要的可以看看
贝加莱 PVI DLL编程 TM711.pdf
10-18
贝加莱 PVI DLL编程 TM711pdf,贝加莱 PVI DLL编程 TM711
贝加莱编程软件AS2.0.7
03-22
贝加莱编程软件AS2.0.7
贝加莱资料：Automation Studio; 使用入门手册.pdf
09-18
贝加莱资料：Automation Studio; 使用入门手册pdf,贝加莱资料：Automation Studio; 使用入门手册
基于贝加莱PLC的数据采集和存储系统
11-19
基于贝加莱PLC的工程。该程序主要采集电流和电压并对数据进行乒乓存储。
Automation Studio 4的使用入门.pdf
05-19
Automation Studio 4的使用入门实例，从入门到精通，帮助的使用，实例的分析与引导，适合贝加莱PLC新手入门。
51单片机对步进电机的控制
腹有诗词气自华
04-04 5094
以上两段代码都是经过测试的，可以直接复制编译成hex文件，最后导入proteus中模拟仿真。首先打开proteus软件，导入元器件并连线。先写一个用不精确的延时函数来控制转速的程序。接下来就是编写C代码了。L298的逻辑功能表。
贝加莱plc对电机实现pid控制
07-27
贝加莱PLC（Beckhoff PLC）是一种常见的工控系统，可以通过其编程环境TwinCAT来实现电机的PID控制。下面是一个简单的示例代码，演示如何在贝加莱PLC上实现电机的PID控制： ```csharp PROGRAM Main VAR Setpoint: REAL := 0.0; // 设定值 Feedback: REAL := 0.0; // 反馈值 Error: REAL := 0.0; // 误差 Integral: REAL := 0.0; // 积分项 PreError: REAL := 0.0; // 上一次的误差 Output: REAL := 0.0; // 控制输出 Kp: REAL := 1.0; // 比例系数 Ki: REAL := 0.5; // 积分系数 Kd: REAL := 0.2; // 微分系数 END_VAR METHOD PIDControl : REAL VAR P: REAL := 0.0; // 比例项 I: REAL := 0.0; // 积分项 D: REAL := 0.0; // 微分项 BEGIN Error := Setpoint - Feedback; Integral := Integral + Error; P := Kp * Error; I := Ki * Integral; D := Kd * (Error - PreError); Output := P + I + D; PreError := Error; RETURN Output; END_METHOD METHOD MainProgram : BOOL VAR MotorRunning: BOOL := FALSE; // 电机运行状态 MotorStopped: BOOL := TRUE; // 电机停止状态 Start: BOOL := FALSE; // 启动信号 Stop: BOOL := FALSE; // 停止信号 ControlOutput: REAL := 0.0; // 控制输出 END_VAR BEGIN // 主循环 WHILE TRUE DO // 获取反馈值（根据实际情况读取电机的位置或速度反馈） Feedback := GetFeedback(); // 如果启动信号为真且电机当前为停止状态，则启动电机 IF Start AND MotorStopped THEN MotorRunning := TRUE; MotorStopped := FALSE; // 执行启动电机的操作代码 // ... END_IF // 如果停止信号为真且电机当前为运行状态，则停止电机 IF Stop AND MotorRunning THEN MotorRunning := FALSE; MotorStopped := TRUE; // 执行停止电机的操作代码 // ... END_IF // 如果电机运行中，则进行PID控制计算并输出控制信号 IF MotorRunning THEN ControlOutput := PIDControl(); // 将ControlOutput应用到电机控制器（根据实际情况发送控制信号） ApplyControlOutput(ControlOutput); END_IF // 其他逻辑代码... // 延时一段时间，避免过于频繁的循环 WAIT 10ms; END_WHILE; RETURN TRUE; END_METHOD ``` 请注意，上述代码仅为示例，具体的PID控制实现可能会根据具体的电机类型和控制要求进行调整。此外，代码中的GetFeedback()函数和ApplyControlOutput()函数需要根据实际情况进行实现，用于获取电机的反馈值和将控制输出应用到电机控制器中。

“相关推荐”对你有帮助么？

  • 非常没帮助
  • 没帮助
  • 一般
  • 有帮助
  • 非常有帮助
提交
评论
添加红包

请填写红包祝福语或标题

个

红包个数最小为10个

元

红包金额最低5元

当前余额3.43元 前往充值 >
需支付：10.00元
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包
实付元
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明：

1.余额是钱包充值的虚拟货币，按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载，可以购买VIP、付费专栏及课程。

余额充值