UnityShader学习笔记 基础纹理

最新推荐文章于 2022-10-30 16:22:40 发布
最新推荐文章于 2022-10-30 16:22:40 发布
阅读量148 收藏
点赞数
分类专栏： Shader 文章标签： shader unity 图形学
版权声明：本文为博主原创文章，遵循 CC 4.0 BY-SA 版权协议，转载请附上原文出处链接和本声明。
本文链接：https://blog.csdn.net/dmk17771552304/article/details/109110013
版权

单张纹理

Shader "Custom/SingleTexture" 
{
	Properties 
	{
		_Color("Color Tint" , Color) = (1,1,1,1)
		_MainTex("Main Tex",2D) = "white" { }
		_Specular("Specular" , Color) = (1,1,1,1)
		_Gloss("Gloss" , Range(8.0,256)) = 20
	}
	SubShader 
	{
		Pass
		{
			Tags { "LightMode" = "ForwardBase" }

			CGPROGRAM
			#pragma vertex vert
			#pragma fragment frag
			#include "Lighting.cginc"

			fixed4 _Color;
			sampler2D _MainTex;
			fixed4 _MainTex_ST;
			fixed4 _Specular;
			float _Gloss;

			struct a2v
			{
				float4 vertex : POSITION;
				float3 normal : NORMAL;
				float4 texcoord : TEXCOORD0; 
			};
			struct v2f
			{
				float4 pos : SV_POSITION;
				float3 worldNormal : TEXCOORD0;
				float3 worldPos : TEXCOORD1;
				float2 uv : TEXCOORD2;
			};

			v2f vert(a2v v)
			{
				v2f o;

				o.pos = UnityObjectToClipPos( v.vertex);
				o.worldNormal = UnityObjectToWorldNormal(v.normal);
				o.worldPos = mul(unity_ObjectToWorld, v.vertex).xyz;
				//o.uv = v.texcoord.xy * _MainTex_ST.xy + _MainTex_ST.zw;
				o.uv = TRANSFORM_TEX(v.texcoord , _MainTex);
				return o;
			}

			fixed4 frag(v2f i) : SV_Target
			{
				fixed3 worldNormal = normalize(i.worldNormal);
				fixed3 worldLightDir = normalize( UnityWorldSpaceLightDir(i.worldPos));

				fixed3 albedo = tex2D(_MainTex, i.uv).rgb * _Color.rgb;
				fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz * albedo;

				fixed3 diffuse = _LightColor0.rgb * albedo * max(0, dot(worldNormal, worldLightDir));
				
				fixed3 viewDir = normalize(UnityWorldSpaceViewDir(i.worldPos));
				fixed3 halfDir = normalize(worldLightDir + viewDir);
				fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(max(0 , dot(worldNormal , halfDir)), _Gloss);
				
				return fixed4(ambient + diffuse + specular , 1.0);
			}
			ENDCG
		}
	}
	FallBack "Diffuse"
}

与其他属性不同的是,如果为纹理类型的属性声明了一个sampler2D 类型的变量,那么还需要额外声明一个float4类型的变量且名字必须为纹理名_ST

在进行顶点变换时,有两种方式:

//o.uv = v.texcoord.xy * _MainTex_ST.xy + _MainTex_ST.zw;
o.uv = TRANSFORM_TEX(v.texcoord , _MainTex);

两个参数分别为顶点纹理坐标和纹理名

 

纹理属性的相关知识:

 

 

凹凸映射

凹凸映射的两种主要方法:高度映射和法线纹理

高度纹理:

高度图:存储模型表面凹凸程度的图,颜色越浅该位置的表面越向外凸起,颜色越深该位置的表面越向里凹

法线纹理:

法线纹理中存储的是表面的法线方向,但是由于法线方向的分量范围是[-1, 1] ,而像素的分量范围是[0, 1],那么需要做一个映射,

同时，做完纹理采样后，需要做一次反向得映射，得到原先得法线方向

法线纹理中存储的法线的方向的坐标空间有两种:模型空间的法线纹理和切线空间的法线纹理

两种纹理方式得使用得优点：

 

在切线空间下计算:

Shader "Custom/NormalMapTangentSpace" 
{
	Properties 
	{
		_Color("Color Tint" , Color) = (1,1,1,1)
		_MainTex("Main Tex",2D) = "white" { }
		_BumpMap("Normal Map" , 2D) = "bump" {}
		_BumpScale("Bump Scale", Float) = 1.0
		_Specular("Specular" , Color) = (1,1,1,1)
		_Gloss("Gloss" , Range(8.0,256)) = 20
	}
	SubShader 
	{
		Pass
		{
			Tags { "LightMode" = "ForwardBase" }

			CGPROGRAM
			#pragma vertex vert
			#pragma fragment frag
			#include "Lighting.cginc"

			fixed4 _Color;
			sampler2D _MainTex;
			float4 _MainTex_ST;
			
			sampler2D _BumpMap;
			float4 _BumpMap_ST;
			float _BumpScale;

			fixed4 _Specular;
			float _Gloss;

			struct a2v
			{
				float4 vertex : POSITION;
				float3 normal : NORMAL;
				float4 tangent : TANGENT; 
				float4 texcoord : TEXCOORD0;
			};
			struct v2f
			{
				float4 pos : SV_POSITION;
				float4 uv : TEXCOORD0;
				float3 lightDir : TEXCOORD1;
				float3 viewDir : TEXCOORD2;			
			};

			v2f vert(a2v v)
			{
				v2f o;

				o.pos = UnityObjectToClipPos( v.vertex);
				o.uv.xy = v.texcoord.xy * _MainTex_ST.xy + _MainTex_ST.zw;
				o.uv.zw = v.texcoord.xy * _BumpMap_ST.xy + _BumpMap_ST.zw;

				float3 binormal = cross(normalize(v.normal),normalize(v.tangent.xyz))*v.tangent.w;
				float3x3 rotation = float3x3(v.tangent.xyz,binormal,v.normal);

				//TANGENT_SPACE_ROTATION;

				o.lightDir = mul(rotation , ObjSpaceLightDir(v.vertex)).xyz;
				o.viewDir = mul(rotation , ObjSpaceViewDir(v.vertex)).xyz;
				return o;
			}

			fixed4 frag(v2f i) : SV_Target
			{
				fixed3 tangentLightDir = normalize(i.lightDir);
				fixed3 tangentViewDir = normalize( i.viewDir);

				fixed4 packedNormal = tex2D(_BumpMap , i.uv.zw);
				fixed3 tangentNormal;

				tangentNormal = UnpackNormal(packedNormal);
				tangentNormal.xy*=_BumpScale;
				tangentNormal.z = sqrt(1.0-saturate(dot(tangentNormal.xy,tangentNormal.xy)));

				fixed3 albedo = tex2D(_MainTex, i.uv).rgb * _Color.rgb;
				fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz * albedo;

				fixed3 diffuse = _LightColor0.rgb * albedo * max(0, dot(tangentNormal, tangentLightDir));
				
				fixed3 halfDir = normalize(tangentLightDir + tangentViewDir);
				fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(max(0 , dot(tangentNormal , halfDir)), _Gloss);
				
				return fixed4(ambient + diffuse + specular , 1.0);
			}
			ENDCG
		}
	}
	FallBack "Diffuse"
}

 

 

在世界空间下计算:

Shader "Custom/NormalMapWorldSpace" 
{
	Properties 
	{
		_Color("Color Tint" , Color) = (1,1,1,1)
		_MainTex("Main Tex",2D) = "white" { }
		_BumpMap("Normal Map" , 2D) = "bump" {}
		_BumpScale("Bump Scale", Float) = 1.0
		_Specular("Specular" , Color) = (1,1,1,1)
		_Gloss("Gloss" , Range(8.0,256)) = 20
	}
	SubShader 
	{
		Pass
		{
			Tags { "LightMode" = "ForwardBase" }

			CGPROGRAM
			#pragma vertex vert
			#pragma fragment frag
			#include "Lighting.cginc"
			#include "UnityCG.cginc"

			fixed4 _Color;
			sampler2D _MainTex;
			float4 _MainTex_ST;
			
			sampler2D _BumpMap;
			float4 _BumpMap_ST;
			float _BumpScale;

			fixed4 _Specular;
			float _Gloss;

			struct a2v
			{
				float4 vertex : POSITION;
				float3 normal : NORMAL;
				float4 tangent : TANGENT; 
				float4 texcoord : TEXCOORD0;
			};
			struct v2f
			{
				float4 pos : SV_POSITION;
				float4 uv : TEXCOORD0;
				float4 TtoW0 : TEXCOORD1;
				float4 TtoW1 : TEXCOORD2;
				float4 TtoW2 : TEXCOORD3;				
			};

			v2f vert(a2v v)
			{
				v2f o;

				o.pos = UnityObjectToClipPos( v.vertex);
				o.uv.xy = v.texcoord.xy * _MainTex_ST.xy + _MainTex_ST.zw;
				o.uv.zw = v.texcoord.xy * _BumpMap_ST.xy + _BumpMap_ST.zw;

				float3 worldPos = mul(unity_ObjectToWorld , v.vertex).xyz;
				float3 worldNormal = UnityObjectToWorldNormal(v.normal);
				float3 worldTangent = UnityObjectToWorldDir(v.tangent.xyz);
				float3 worldBinormal = cross(worldNormal , worldTangent) * v.tangent.w;
				
				o.TtoW0 = float4(worldTangent.x,worldBinormal.x,worldNormal.x,worldPos.x);
				o.TtoW1 = float4(worldTangent.y,worldBinormal.y,worldNormal.y,worldPos.y);
				o.TtoW2 = float4(worldTangent.z,worldBinormal.z,worldNormal.z,worldPos.z);

				return o;
			}

			fixed4 frag(v2f i) : SV_Target
			{
				float3 worldPos = float3(i.TtoW0.w,i.TtoW1.w,i.TtoW2.w);
				fixed3 lightDir = normalize(UnityWorldSpaceLightDir(worldPos));
				fixed3 viewDir = normalize(UnityWorldSpaceViewDir(worldPos));

				fixed3 bump = UnpackNormal (tex2D(_BumpMap , i.uv.zw));
				bump.xy *= _BumpScale;
				bump.z = sqrt(1.0 - saturate(dot(bump.xy , bump.xy)));
				bump = normalize (half3(dot(i.TtoW0.xyz ,  bump) ,dot(i.TtoW1.xyz , bump) ,dot(i.TtoW2.xyz , bump)));

				fixed3 albedo = tex2D(_MainTex, i.uv).rgb * _Color.rgb;
				fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz * albedo;

				fixed3 diffuse = _LightColor0.rgb * albedo * max(0, dot(bump, lightDir));
				
				fixed3 halfDir = normalize(lightDir + viewDir);
				fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(max(0 , dot(bump , halfDir)), _Gloss);
				
				return fixed4(ambient + diffuse + specular , 1.0);
			}
			ENDCG
		}
	}
	FallBack "Diffuse"
}

 

渐变纹理

Shader "Custom/Ramp" 
{
	Properties 
	{
		_Color ("Color Tint", Color) = (1,1,1,1)
		_RampTex ("RampTex", 2D) = "white" {}
		_Specular ("Specular", Color) = (1,1,1,1)
		_Gloss ("Gloss", Range(8.0,256)) = 20
	}
	SubShader 
	{
		Pass
		{
			Tags { "LightMode" = "ForwardBase" }
			CGPROGRAM

			#pragma vertex vert
			#pragma fragment frag

			#include "Lighting.cginc"

			fixed4 _Color;
			sampler2D _RampTex;
			float4 _RampTex_ST;
			fixed4 _Specular;
			float _Gloss;

			struct a2f
			{
				float4 vertex : POSITION;
				float3 normal : NORMAL;
				float4 texcoord : TEXCOORD0;
			};

			struct v2f
			{
				float4 pos : SV_POSITION;
				float3 worldNormal : TEXCOORD0;
				float3 worldPos : TEXCOORD1;
				float2 uv : TEXCOORD2;
			};

			v2f vert(a2f v)
			{
				v2f o;
				o.pos = UnityObjectToClipPos( v.vertex);
				o.worldNormal = UnityObjectToWorldNormal (v.normal);
				o.worldPos = mul (unity_ObjectToWorld, v.vertex).xyz;
				o.uv = TRANSFORM_TEX(v.texcoord , _RampTex);

				return o;
			}

			fixed4 frag(v2f i) : SV_Target
			{
				fixed3 worldNormal = normalize(i.worldNormal);
				fixed3 worldLightDir = normalize (UnityWorldSpaceLightDir(i.worldPos));

				fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz;

				fixed halfLambert = 0.5 * dot(worldNormal , worldLightDir)+0.5;
				fixed3 diffuseColor = tex2D(_RampTex, fixed2(halfLambert, halfLambert)).rgb * _Color.rgb;
				
				
				fixed3 diffuse = _LightColor0.rgb * diffuseColor;

				fixed3 viewDir = normalize (UnityWorldSpaceViewDir(i.worldPos));
				fixed3 halfDir = normalize (worldLightDir + viewDir);
				fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(max(0 , dot(worldNormal, halfDir)), _Gloss);
				return fixed4(ambient + diffuse + specular , 1.0);
			}

			ENDCG
		}
	}
	FallBack "Diffuse"
}

 

遮罩纹理

Shader "Custom/Mask" 
{
	Properties 
	{
		_Color("Color Tint" , Color) = (1,1,1,1)
		_MainTex("Main Tex",2D) = "white" { }
		_BumpMap("Normal Map" , 2D) = "bump" {}
		_BumpScale("Bump Scale", Float) = 1.0
		_SpecularMask("Specular Mask" , 2D) = "white" {}
		_SpecularScale("Specular Scale" , Float) = 1.0
		_Specular("Specular" , Color) = (1,1,1,1)
		_Gloss("Gloss" , Range(8.0,256)) = 20
	}
	SubShader 
	{
		Pass
		{
			Tags { "LightMode" = "ForwardBase" }

			CGPROGRAM
			#pragma vertex vert
			#pragma fragment frag
			#include "Lighting.cginc"

			fixed4 _Color;
			sampler2D _MainTex;
			float4 _MainTex_ST;
			
			sampler2D _BumpMap;
			float _BumpScale;

			sampler2D _SpecularMask;
			float _SpecularScale;

			fixed4 _Specular;
			float _Gloss;

			struct a2v
			{
				float4 vertex : POSITION;
				float3 normal : NORMAL;
				float4 tangent : TANGENT; 
				float4 texcoord : TEXCOORD0;
			};
			struct v2f
			{
				float4 pos : SV_POSITION;
				float2 uv : TEXCOORD0;
				float3 lightDir : TEXCOORD1;
				float3 viewDir : TEXCOORD2;			
			};

			v2f vert(a2v v)
			{
				v2f o;

				o.pos = UnityObjectToClipPos( v.vertex);
				o.uv.xy = v.texcoord.xy * _MainTex_ST.xy + _MainTex_ST.zw;

				TANGENT_SPACE_ROTATION;

				o.lightDir = mul(rotation , ObjSpaceLightDir(v.vertex)).xyz;
				o.viewDir = mul(rotation , ObjSpaceViewDir(v.vertex)).xyz;
				return o;
			}

			fixed4 frag(v2f i) : SV_Target
			{
				fixed3 tangentLightDir = normalize(i.lightDir);
				fixed3 tangentViewDir = normalize( i.viewDir);

				fixed3 tangentNormal = UnpackNormal(tex2D(_BumpMap,i.uv));
				tangentNormal.xy*=_BumpScale;
				tangentNormal.z = sqrt(1.0-saturate(dot(tangentNormal.xy,tangentNormal.xy)));

				fixed3 albedo = tex2D(_MainTex, i.uv).rgb * _Color.rgb;
				fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz * albedo;

				fixed3 diffuse = _LightColor0.rgb * albedo * max(0, dot(tangentNormal, tangentLightDir));
				
				fixed3 halfDir = normalize(tangentLightDir + tangentViewDir);
				fixed specularMask = tex2D(_SpecularMask , i.uv).r * _SpecularScale;
				
				fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(max(0 , dot(tangentNormal , halfDir)), _Gloss) * specularMask;
				
				return fixed4(ambient + diffuse + specular , 1.0);
			}
			ENDCG
		}
	}
	FallBack "Diffuse"
}

漫漫无期
关注
专栏目录
Unity Shader 入门精要之基础纹理
Marccco的博客
04-09 387
最近在看Unity Shader入门精要这本书,打算进攻下图形学这一块了,加油吧 1.纹理映射坐标也被叫做UV坐标,通常范围都被归一化到[0,1],需要注意的是OpenGL和DirectX在二维空间坐标系是有差异的,但Unity已经帮咱们处理好这个问题了,是用符合OpenGL的传统,也就是原点位于左下角,DX原点是在左上角. 2.在Unity中,声明某个纹理的属性是有贴别的命名规范的,也就是纹...
Unity Shader学习：ShaderToy扩散扭曲
咪咪博客
08-16 1671
Unity Shader学习：ShaderToy扩散扭曲 算法来自:https://www.shadertoy.com/view/4dcGW2 c#部分： using System.Collections; using System.Collections.Generic; using UnityEngine; public class Diffusion : MonoBehavi...
Shader实例:扭曲，漩涡
weixin_30894389的博客
05-13 389
效果： 案例：新仙剑，王者之剑。 在切换场景的时候，就会有这样的全屏扭曲效果。 思路： 1.用GrabPass抓屏到一张纹理中。 2.进行扭曲，绘制到UGUI的Image上。 准备: 去官网下载Unity内置Shader，当前最新版本：builtin_shaders-5.3.1f1 http://unity3d.com/cn/get-unity/download/archive...
Unity_Shader_自动变换顶点颜色
weixin_42137574的博客
10-21 1305
Shader代码如下: // Upgrade NOTE: replaced '_Object2World' with 'unity_ObjectToWorld' // Upgrade NOTE: replaced 'mul(UNITY_MATRIX_MVP,*)' with 'UnityObjectToClipPos(*)' // Upgrade NOTE: replaced 'mul(UNITY_MATRIX_MVP,*)' with 'UnityObjectToClipPos(*)' // U
unityShader之CG标准函数库
天行九歌
12-05 977
CG标准函数库的函数只要分为这几类：数学函数，几何函数，纹理映射函数，偏导数函数； 1：数学函数 数学函数用于执行数学上的常用计算，包括：三角函数，幂函数，向量和矩阵的操作函数。这些函数都被重载，以支持标量和向量作为输入参数。 abs(x)  返回输入参数的绝对值； acos(x) 反余弦函数，输入参数范围[-1,1],返回[0,π]区间的角度值； all(x) 如果输入的参数均不为0，则
unity shader 笔记学习文档
最新发布
12-21
本文档是关于 Unity Shader 的学习笔记，涵盖了 Unity Shader 的基本概念、语法、函数和应用场景。 一、UnpackNormal 函数 UnpackNormal 函数是 UnityCG.cginc 库中的一个函数，用于解压缩法线数据。该函数的用法...
unity shader学习笔记--基础纹理常用的计算
lairpa的博客
03-30 210
##顶点和向量 会经常输出裁剪坐标,世界坐标等信息 顶点裁剪坐标: o.pos = UnityObjectToClipPos (v.vertex) ; 世界顶点坐标: float3 worldPos = mul(unity_ObjectToWorld, v.vertex).xyz; 世界法线向量: fixed3 worldNormal = UnityObjectToWorldNormal(v.normal); o.worldNormal = mul(v.normal, (float3x3)unity_.
【Unity Shader入门精要学习笔记】基础纹理
Mccree的博客专栏
05-14 454
1
unity学习笔记 unity shader unity数据存储方式 DoTween插件常用API
02-18
在这个“unity学习笔记”中，我们将深入探讨Unity中的Shader编程、数据存储方法和DoTween插件的常用API。 Unity Shader是控制游戏图形表现的关键元素，它们允许开发者定制游戏的视觉效果，比如光照、纹理和粒子效果...
UnityShader学习笔记（2）——UnityShader基础
LittleFenrir的博客
01-20 364
UnityShader学习笔记（2）——UnityShader基础Unity Shader 基础（一）Unity Shader 使用流程（二）Unity Shader 的结构1.给Shader命名2.材质和UnityShader的桥梁：属性（Properties）3.重量级成员：子着色器（SubShader）状态设置SubShader的标签 Unity Shader 基础 （一）Unity Shader 使用流程 在Unity中我们需要配合使用材质（Material）和Unity Shader才能达到需要的
一文掌握OpenGL的shader内置函数
徐福记456
10-24 4715
OpenGL ES有大量的GLSL内置函数，包括：三角函数、指数函数、通用函数、浮点函数、几何函数、矩阵函数、矢量关系函数、纹理函数、原子函数、图像函数、插值函数、着色器函数等。
Shader 常用函数总结
sinat_34014668的博客
10-30 6320
Shader 常用函数总结
shader常用运算函数
我的Unity3D
03-02 4305
基本数学运算 max（a，b）返回较大的 min（a，b）返回较小的 mul（a，b）两向量相乘 abs（a）返回a的绝对值 round（x）返回与x最近的整数 sqrt（x）返回x的平方根 rsqrt（x）返回x的平方根倒数 degrees（x）将弧度转化为角度 redians（x）将角度转化为弧度 noise（x）噪声函数 网站：https://graphtoy.com/可将数学公式输入可视化 幂指对函数与偏导数 pow（x，y）x的y次幂 exp（x）返回以e为底的...
Shader消融特效
codingriver的博客
09-26 1011
角色死亡消融，尸体消融，地图烧毁特效 参考 《unity shader 入门精要》 // Upgrade NOTE: replaced 'mul(UNITY_MATRIX_MVP,*)' with 'UnityObjectToClipPos(*)' Shader "Book/15.Dissolve" { Properties { _BurnAmount("Burn A...
Unity Shader 从未入门到已放弃（十）--中级
leileilei的专栏
06-20 273
更复杂的光照（二） 使用Blinn-Phong模型 Shader "My/Bumped Specular" { Properties{ _Color("Color Tint", Color) = (1, 1, 1, 1) _MainTex("Main Tex", 2D) = "white" {} _BumpMap("Normal Map", 2D) = "bump" {} ...
这样学Shader可以少走几年弯路，看完我信了……
奎特尔星球
01-18 1782
推荐理由：你有没有感觉到，看过很多的Shader教程，还是无法上手。看到一个特效，连思路都没有，只能拿别人做好的Shader干点调参数的活。我看了麒麟子的这篇教程才知道，原来连很多概念都没...
Shader常用函数
qq_38004206的博客
01-07 512
写在这里方面自己查看 函数 功能描述 abs(x) 返回输入参数的绝对值 acos(x) 反余切函数，输入参...
Shader常用函数属性
盖子的博客
03-19 3043
Properties属性支持类型 属性类型 默认值的定义语法 例子 Int number _Int(“Int”,Int)=2 Float number _Float(“Float”,Float)=1.5 Range(min,max) number _Range(“Range”,Range(0.0,5.0))=3.0 Color (number,number,number...
HLSL固有函数
12-30 4932
每天30分钟看Shader--(1)HLSL固有函数 【Intrinsic Functions (DirectX HLSL)】 放在blog上看起来方便,这个是MSDN上的，DirectX Documentation里也有Intrinsic Functions (DirectX HLSL)The following table lists the intrinsic functio
Unity Shader学习笔记：UnpackNormal函数和属性命名规范
在学习Unity Shader时，有一些重要的注意事项和方法需要特别关注。 首先，在使用UnityCG.cginc里的函数时，需要特别关注UnpackNormal和expand函数的用法。UnpackNormal函数通常用于解压纹理中压缩的法线信息，以...
评论
添加红包

请填写红包祝福语或标题

个

红包个数最小为10个

元

红包金额最低5元

当前余额3.43元 前往充值 >
需支付：10.00元
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包
实付元
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明：

1.余额是钱包充值的虚拟货币，按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载，可以购买VIP、付费专栏及课程。

余额充值