Unity内置Shader解读9——Reflective/Bumped Diffuse

1.Shader在什么情况下使用

Reflective(反射)，反射系列，都是通过cubemap实现的，通常在为一些反射度高的金属/玻璃等做一些环境的反射效果，比如玻璃杯反射出房子内部的样子。

image.png

2.Shader的价值(用的多不多)，Shader的难度

反射其实在旧版本中用的比较多的，一些物体在用了反射后真实感能得到极大的提升。

3.代码详细注释

Shader "Legacy Shaders/Reflective/Bumped Diffuse" {
    Properties {
        _Color ("Main Color", Color) = (1,1,1,1)
        _ReflectColor ("Reflection Color", Color) = (1,1,1,0.5)
        _MainTex ("Base (RGB) RefStrength (A)", 2D) = "white" {}
        _Cube ("Reflection Cubemap", Cube) = "_Skybox" { }
        _BumpMap ("Normalmap", 2D) = "bump" {}
    }

    SubShader {
        Tags { "RenderType"="Opaque" }
        LOD 300

        CGPROGRAM
        #pragma surface surf Lambert

        sampler2D _MainTex;
        sampler2D _BumpMap;
        samplerCUBE _Cube;

        fixed4 _Color;
        fixed4 _ReflectColor;

        struct Input {
            float2 uv_MainTex;
            float2 uv_BumpMap;
            //世界空间的反射向量
            float3 worldRefl;
            //定义了一个3x3的矩阵
            //用于WorldReflectionVector中局部坐标系到世界坐标系的转换
            INTERNAL_DATA
        };

        void surf (Input IN, inout SurfaceOutput o) {
            //采样纹理颜色
            fixed4 tex = tex2D(_MainTex, IN.uv_MainTex);
            //混合设定的颜色
            fixed4 c = tex * _Color;
            //最终获得Albedo光照颜色
            o.Albedo = c.rgb;
            //法线获取
            o.Normal = UnpackNormal(tex2D(_BumpMap, IN.uv_BumpMap));

            //世界反射向量。如果表面着色写入到o.Normal，将包含世界反射向量。为了得到基于每个像素的法线贴图的反射向量, 使用WorldReflectionVector的(IN输入, o.Normal)。
            //WorldReflectionVector内部进行了Reflect(IN.worldRefl,dot(o.Normal,INTERNAL_DATA))：反射函数的计算，要求入射方向和法向量都是单位向量
            //Reflect()可以看这篇https://zhuanlan.zhihu.com/p/139892885
            //实际就是通过光方向和法线方向以一种低成本的方式计算出反射方向
            float3 worldRefl = WorldReflectionVector (IN, o.Normal);
            
            //texCUBE会采样方向向量worldRefl在CubeMap上的交点
            //这篇介绍得很详细https://blog.csdn.net/v_xchen_v/article/details/79474193
            fixed4 reflcol = texCUBE (_Cube, worldRefl);
            //如果纹理本身是透明或半透的就保持一致
            //这里用乘法估测是为了支持某些带透明通道的CubeMap
            reflcol *= tex.a;
            //最终在自发光通道混合反射计算结果和反射混合颜色
            o.Emission = reflcol.rgb * _ReflectColor.rgb;
            //由于之前reflcol已经*= tex.a，最终的Alpha与_ReflectColor.a混合即可
            o.Alpha = reflcol.a * _ReflectColor.a;
        }
        ENDCG
    }

    FallBack "Legacy Shaders/Reflective/VertexLit"
}

4.Shader编写思路，用到的知识点

WorldReflectionVector

通过光方向和法线方向以一种低成本的方式计算出反射方向，可以参考这篇的图：

image.png

texCUBE

texCUBE会采样方向向量worldRefl在CubeMap上的交点，参考这篇的图：

image.png