【Godot4.2】简单调色板生成

已于 2024-03-10 20:22:46 修改
阅读量1k 收藏 10
点赞数 19
分类专栏： Godot4.0 Godot4.x 自定义控件 文章标签： godot gdscript 调色板
于 2024-03-10 20:17:45 首次发布
版权声明：本文为博主原创文章，遵循 CC 4.0 BY-SA 版权协议，转载请附上原文出处链接和本声明。
本文链接：https://blog.csdn.net/graypigen1990/article/details/136607897
版权

概述

Godot内部提供了ColorPicker和ColorPickerButton两个颜色选择控件，也提供了GradientTexture1D和GradientTexture2D,来实现参数化的渐变图片。
但是有时候我们可能需要用Godot自己编写一些绘图程序，可能ColorPicker和ColorPickerButton就显得比较Low了，我们可能想自己实现调色板或者色环之类的。
本篇旨在阐述如何用简单的GDScript代码形式生成调色板，通过TextureRect控件来呈现，并进取色交互。

基础原理

通过构造Image，然后填色或设定每个像素颜色，然后再构造ImageTexture资源，就可以将程序生成的图片赋值给控件的Texture属性。这是本篇的基础。
我们创建一个用户界面场景，添加一个TextureRect控件：
image.png
为TextureRect控件添加如下代码：

extends TextureRect


func _ready():
	# 构造Image
	var img = Image.new()
	img = img.create(100,100,true,Image.FORMAT_RGBA8)  # 限定尺寸和格式
	img.fill(Color.YELLOW_GREEN) # 填充纯色
	# 从Image创建ImageTexture，并赋值给TextureRect
	texture = ImageTexture.create_from_image(img)

上面的代码动态创建一张100×100px带有RGBA信息的图片，然后用Image的fill()方法，填充纯色。
运行场景后，就可以看到一个TextureRect显示了一张被填充为黄绿色的程序生成图片。
image.png
如果你还记得我在【Godot4.2】图片处理函数库 - textureDB一文中贴出的代码，生成纯色填充图片被写成了一个函数color_block。所以通过简单的函数封装，代码就变成了如下形式：

extends TextureRect


func _ready():
	texture = color_block(Vector2(100,100),Color.YELLOW_GREEN)


# 创建纯色块的ImageTexture
func color_block(size:Vector2,color:Color=Color.WHITE) -> ImageTexture:
	var img = Image.new()
	img = img.create(size.x,size.y,false,Image.FORMAT_RGBA8)
	img.fill(color)
	return ImageTexture.create_from_image(img)

fill()方法与遍历图片的每个像素，然后用set_pixel()赋予同一个颜色是等价的。
等价函数：

# 创建纯色块的ImageTexture
func color_block(size:Vector2,color:Color=Color.WHITE) -> ImageTexture:
	var img = Image.new()
	img = img.create(size.x,size.y,false,Image.FORMAT_RGBA8)
	# 遍历每一个像素
	for x in range(size.x):
		for y in range(size.y):
			img.set_pixel(x,y,Color.YELLOW_GREEN) # 设定该像素的颜色值
	return ImageTexture.create_from_image(img)

实现颜色渐变

我们编写一个函数gradient用来生成两种颜色的线性渐变。
同样我们需要像上面一样遍历图片的每一个像素，并设定颜色，而颜色值我们用全局函数leap进行线性插值，插值的比例我们采用x/100.0的水平坐标百分比。

extends TextureRect


func _ready():
	texture = gradient(Vector2(100,100))


# 一维渐变图片
func gradient(size:Vector2,color1:Color=Color.BLACK,color2:Color=Color.WHITE) -> ImageTexture:
	var img = Image.new()
	img = img.create(size.x,size.y,false,Image.FORMAT_RGBA8)
	# 遍历每一个像素
	for x in range(size.x):
		for y in range(size.y):
			img.set_pixel(x,y,lerp(color1,color2,x/100.0)) # 设定该像素的颜色值
	return ImageTexture.create_from_image(img)

默认我们只传入生成的图片尺寸，则会生成一个由黑到白的线性渐变图：
image.png
我们传入自定义的两种颜色，比如黄色和黄绿色：

texture = gradient(Vector2(100,100),Color.YELLOW,Color.YELLOW_GREEN)

则会生成如下的颜色渐变纹理。
image.png
这与Godot内置的gradientTexture1D效果是一致的。
image.png
image.png

基于GradientTexture1D和Gradient资源的版本

# 一维渐变图片
func gradient(size:Vector2,color1:Color=Color.BLACK,color2:Color=Color.WHITE) -> GradientTexture1D:
	var texture  = GradientTexture1D.new()
	# 构建Gradient资源
	var grad = Gradient.new()
	grad.set_color(0.0,color1)  # 在起始处添加颜色1
	grad.set_color(1.0,color2)  # 在末尾处添加颜色2
	texture.gradient = grad
	return texture

基于GradientTexture1D和Gradient资源创建渐变，好处是可以添加更多的颜色。

模仿ColorPicker控件的调色板

实现目标颜色的饱和度和亮度调制

下图是Godot内置的颜色选择控件——ColorPicker。其右侧的窄带选择色相，左侧的调色板则对同一色相进行不同亮度和饱和度的调制。
image.png
这里我们首先实现左侧，对同一色相进行不同亮度和饱和度的调制。

extends TextureRect

# 要调制亮度和饱和度的颜色
@export var color:Color = Color.RED

func _ready():
	# 构造Image
	var img = Image.new()
	img = img.create(100,100,true,Image.FORMAT_RGBA8)
	# 遍历像素进行填色
	for x in range(100):
		for y in range(100):
			var color_x = lerp(Color.WHITE,color,x/100.0)      # 水平饱和度逐渐增加
			var color_y = lerp(color_x,Color.BLACK,y/100.0)    # 垂直亮度逐减
			img.set_pixel(x,y,color_y)
	# 生成并显示图片
	texture = ImageTexture.create_from_image(img)

默认红色调制出的图片如下：
image.png
这里代码使用了导出变量color用于指定要调制的目标颜色，所以我们只需要修改一下，就可以调制任何其他颜色的色板出来。
image.png
image.png

实现目标颜色选择色带

接着我们实现右侧窄带部分，这部分的用于选择基础的目标颜色。
image.png

写法1

我这里用最笨的方法就是观察ColorPicker这个目标颜色部分是由纯红色逐渐到黄色再到绿色…，然后就用RGB三色混合的方式模拟了一遍这个过程：

extends TextureRect

func _ready():
	var img = Image.new()
	img = img.create(10,255*6,true,Image.FORMAT_RGBA8)
	
	for x in range(10.0):
		# 红色逐渐混合绿色 -- 由红变黄
		for val in range(255):
			img.set_pixel(x,val,Color8(255,val,0))
		# 从红绿混合中逐渐减去红色比重 -- 由黄变绿
		for val in range(255):
			img.set_pixel(x,val + 255,Color8(255 - val,255,0))
		# 绿色逐渐混合蓝色
		for val in range(255):
			img.set_pixel(x,val + 255 * 2,Color8(0,255,val))
		# 蓝绿混合中逐渐减去绿色比重
		for val in range(255):
			img.set_pixel(x,val + 255 * 3,Color8(0,255-val,255))
		# 蓝色逐渐混合红色 -- 由蓝变紫
		for val in range(255):
			img.set_pixel(x,val + 255 * 4,Color8(val,0,255))
		# 红蓝混合色中逐渐减去蓝色比重 -- 由紫变红
		for val in range(255):
			img.set_pixel(x,val + 255 * 5,Color8(255,0,255-val))
		
	texture = ImageTexture.create_from_image(img)

生成的效果：
image.png

写法2

上面的代码写的不是太简洁，所以代码可以简化如下：

extends TextureRect

func _ready():
	var img = Image.new()
	img = img.create(10,100 * 6,true,Image.FORMAT_RGBA8)
	
	var colors = [Color(1,0,0),Color(1,1,0),Color(0,1,0),Color(0,1,1),Color(0,0,1),Color(1,0,1),Color(1,0,0)]
	
	for i in range(colors.size()):
		if i+1 < colors.size():
			var color_A = colors[i]
			var color_B = colors[i+1]
			for x in range(10.0):
				# 红色逐渐混合绿色
				for val in range(100.0):
					img.set_pixel(x,val + 100 * i,lerp(color_A,color_B,val/100.0))
		
	texture = ImageTexture.create_from_image(img)
写法3

基于GradientTexture1D和Gradient资源创建的写法：

extends TextureRect


func _ready():
	var colors = [Color(1,0,0),Color(1,1,0),Color(0,1,0),Color(0,1,1),Color(0,0,1),Color(1,0,1),Color(1,0,0)]
	# 构造Image
	var grad_texture = GradientTexture2D.new()
	# 垂直方向进行渐变
	grad_texture.fill_from = Vector2(0,0)
	grad_texture.fill_to = Vector2(0,1)
	# 构造Gradient资源
	var grad = Gradient.new()
	# 删除默认的两个点
	grad.remove_point(1)
	grad.remove_point(0)
	# 添加新的点
	for i in range(colors.size()):
		grad.add_point(float(i)/6.0,colors[i])
	
	# 赋值
	grad_texture.gradient = grad
	# 显示
	texture = grad_texture

自定义控件与颜色选择交互演示

通过上面探讨的基础，我们已经可以实现自己的颜色选择器功能，为了让代码清晰，我封装了ColorsBar和HSBRect两个自定义控件。
代码分别如下：

ColorsBar源码

# ======================================================================
# 名称：ColorsBar
# 类型：自定义控件
# 描述：创建一个色相选择的渐变图，可以选择RGB混合模式下所有可能值的颜色
# 作者：巽星石
# Godot版本：v4.2.1.stable.official [b09f793f5]
# 创建时间：2024年3月9日10:31:42
# 最后修改时间：2024年3月10日19:31:46
# ======================================================================
@tool
class_name ColorsBar extends TextureRect

signal color_changed(color:Color)  # 选择颜色后触发

# ============================= 参数 =============================
var pos:Vector2    # 鼠标位置
var can_move:bool  # 能否移动
# ============================= 虚函数 =============================
# 初始化
func _init():
	create_colors()

# 处理鼠标交互
func _gui_input(event):
	if event is InputEventMouseButton:
		if event.button_index == MOUSE_BUTTON_LEFT:  # 鼠标左键
			can_move = event.is_pressed()            # 按下开启can_move
			if can_move:
				get_color(event)
	
	if event is InputEventMouseMotion:               # 鼠标移动
		if can_move:
			get_color(event)
# 获取颜色
func get_color(event:InputEvent):
	var img:Image = texture.get_image()
	# 记录鼠标局部坐标
	pos.y = clamp(event.position.y,0,size.y-1)
	pos.x = clamp(event.position.x,0,size.x)
	# 触发color_changed信号，返回获取的目标颜色
	emit_signal("color_changed",img.get_pixelv(pos))
	# 请求重绘
	queue_redraw()

func _draw():
	# 绘制白色矩形框
	var rect = Rect2(Vector2(-1,pos.y-1),Vector2(size.x+1,3))
	draw_rect(rect,Color.WHITE,false,1)

# ============================= 核心函数 =============================
# 创建可选颜色
func create_colors():
	var colors = [Color(1,0,0),Color(1,1,0),Color(0,1,0),Color(0,1,1),Color(0,0,1),Color(1,0,1),Color(1,0,0)]
	# 构造Image
	var grad_texture = GradientTexture2D.new()
	# 修改GradientTexture2D的图片尺寸，与TextureRect尺寸保持一致，方便鼠标交互时采样
	grad_texture.width = size.x
	grad_texture.height = size.y
	# 垂直方向进行渐变
	grad_texture.fill_from = Vector2(0,0)
	grad_texture.fill_to = Vector2(0,1)
	# 构造Gradient资源
	var grad = Gradient.new()
	# 删除默认的两个点
	grad.remove_point(1)
	grad.remove_point(0)
	# 添加新的点
	for i in range(colors.size()):
		grad.add_point(float(i)/6.0,colors[i])
	
	# 赋值
	grad_texture.gradient = grad
	# 显示
	texture = grad_texture

HSBRect源码

# ======================================================================
# 名称：HSBRect
# 类型：自定义控件
# 描述：基于给定颜色，进行亮度和饱和度调制，生成一个矩形的颜色渐变区域，
# 可以用鼠标交互进行颜色选择
# 作者：巽星石
# Godot版本：v4.2.1.stable.official [b09f793f5]
# 创建时间：2024年3月9日10:31:42
# 最后修改时间：2024年3月10日19:31:46
# ======================================================================
@tool
class_name HSBRect extends TextureRect

signal color_changed(color:Color)  # 选择颜色后触发

# ============================= 参数 =============================
pos:Vector2 = Vector2(size.x-1,0)    # 鼠标位置
var can_move:bool  # 能否移动

# 要调制亮度和饱和度的颜色
@export var color:Color = Color.RED:
	set(val):
		color = val
		create_hsb()
		# 触发color_changed信号
		var img:Image = texture.get_image()
		emit_signal("color_changed",img.get_pixelv(pos))

# ============================= 虚函数 =============================
# 初始化
func _init():
	create_hsb()

# 处理鼠标交互
func _gui_input(event):
	if event is InputEventMouseButton:
		if event.button_index == MOUSE_BUTTON_LEFT:  # 鼠标左键
			can_move = event.is_pressed()            # 按下开启can_move
			if can_move:
				get_color(event)
	
	if event is InputEventMouseMotion:               # 鼠标移动
		if can_move:
			get_color(event)

func _draw():
	# 绘制白色矩形框
	var rect = Rect2(Vector2(pos.x-1,pos.y-1),Vector2(3,3))
	draw_rect(rect,Color.WHITE,false,1)

# 获取颜色
func get_color(event:InputEvent):
	var img:Image = texture.get_image()
	# 记录鼠标局部坐标
	pos.y = clamp(event.position.y,0,size.y-1)
	pos.x = clamp(event.position.x,0,size.x-1)
	# 触发color_changed信号，返回获取的目标颜色
	emit_signal("color_changed",img.get_pixelv(pos))
	# 请求重绘
	queue_redraw()

# ============================= 核心函数 =============================
# 创建由色相、饱和度和亮度渐变而成的区域
func create_hsb():
	# 构造Image
	var img = Image.new()
	img = img.create(size.x,size.y,true,Image.FORMAT_RGBA8)
	# 遍历像素进行填色
	for x in range(size.x):
		for y in range(size.y):
			var color_x = lerp(Color.WHITE,color,x/size.x)      # 水平饱和度逐渐增加
			var color_y = lerp(color_x,Color.BLACK,y/size.y)    # 垂直亮度逐减
			img.set_pixel(x,y,color_y)
	# 生成并显示图片
	texture = ImageTexture.create_from_image(img)

使用测试

我们创建一个测试场景，分别添加ColorsBar和HSBRect实例，以及一个ColorRect。
image.png
场景根节点代码如下：

extends Control

@onready var colors_bar = $ColorsBar   # 颜色选择条
@onready var hsb_rect = $HSBRect       # 色相-饱和度-亮度混色盘
@onready var color_rect = $ColorRect

# 颜色选择条选择颜色后HSBRect的色相发生相应变化
func _on_colors_bar_color_changed(color):
	hsb_rect.color = color

# HSBRect选择颜色后，在ColorRect显示选择的颜色
func _on_hsb_rect_color_changed(color):
	color_rect.color = color

主要是处理ColorsBar和HSBRect的color_changed信号，让ColorsBar和HSBRect以及ColorRect三者联动起来。
运行后的效果：
在这里插入图片描述

gif图有点失真：
在这里插入图片描述

巽星石
关注
  • 19
    点赞
  • 踩
  • 10
    收藏
    觉得还不错? 一键收藏
  • 打赏
    打赏
  • 0
    评论
专栏目录
ZoneLoadingSystem:Godot动态区域加载系统
04-01
区域加载系统 这是Godot的动态区域加载系统，它负责为您管理区域管理，在玩家探索世界时加载和卸载区域，并使用后台线程来最大程度地减少性能故障。 这允许拥有巨大的无缝世界而无需加载屏幕。 该系统适用于手工制作的区域，例如FPS，冒险游戏或2D游戏。 它不是基于与玩家距离的分块系统。 工作原理：当玩家进入区域触发器时，该区域会附加到树上（该区域应大于该区域），而当玩家退出触发器时，会分离该区域。 区域会预先加载并预先插入一个区域，因此不会出现加载延迟。 该系统可在2D和3D模式下工作（请参见演示），可用于室内和室外环境。 在3D中，需要精心设计区域，以便玩家看不到卸载的区域（需要曲折或起雾）。 每个区域都位于完全围绕该区域的触发区域内。 当玩家进入触发区域时，相应的区域将被加载，实例化（如果尚未）并附加到世界。 当玩家离开该区域时，该区域将从树中删除，但仍保留在内存中，从而允许在
Godot 4 着色器 - Shader调试
drgraph的博客
07-24 1660
我之前用OpenCV进行图像相关处理，觉得已经很不错，结合GDI可以实现流畅的动画效果直到近来用Shader后才发现，着色器更上一层楼，原来这是入了GPU的坑Shader编程限制很多，各种不支持，看在它性能不错功能炫酷的份上，忍了，努力增加一些自己需要的功能最优先的功能是调试需要，Shader的过程信息也不能输出到文本日志中，也不能输出到调试窗口中。查了一下，一般的做法就是在画面中用一些颜色表示。这应该是比较低效的了。琢磨了一下，调试信息还是只能在画面上显示，不过信息最好能以图形、文字等形式展现。
Godot 4 源码分析 - 动态导入图片文件
drgraph的博客
07-30 1328
用Godot 4尝试编一个电子书软件，初步效果已经出来，并且通过管道通信接口可以获取、设置属性、调用函数，貌似能处理各种事宜了。其实不然，外因通过内因起作用，如果没把里面搞明白，功能没有开放出来，则有些需求就不能实现。比如，现在想动态加载新的图书，这就是一个实际需求。如果每一本电子书，都需要导出一次，那这个软件就太不通用了。直接加载另一图片，结果不成功这就得研究一下了。
Godot Engine 学习笔记 Texture
...
10-28 1916
TextureTexture Texture 以下为我对于官方文档的翻译以及使用情况，3.0版本的文档
Godot控件响应鼠标点击事件
nwhasd的博客
09-15 3020
以TextureRect控件为例，其它控件同理： // Confirm dialog // Created by nwhasd // 2021/9/15 // MIT license using Godot; public class Node2D : TextureRect { public override void _Ready() { // 绑定gui输入事件 Connect("gui_input", this, nameof(OnGuiIn
godot 淡入淡出平滑切换场景
斧冰
02-19 4169
godot新建一个空工程 根节点重命名为scene1 然后添加一个TextureRect节点，添加一张背景图1.jpg（网上下载的，你也可以替换成自己喜欢的背景图） 再添加一个Button控件，里面的文字输入“start”，按钮放置在右上角。 保存场景scene1 给场景添加一个gd脚本： 然后给按钮添加一个pressed的点击函数： 将场景scene1.tscn复制一份，改为scene2.tscn，替换scene2的背景图片为1.jpg，这样你就有了2个场景，接下来我们要做的就是在这两个场景之间
Godot在github的资源网址，最近版本4.1.2，只是下载速度有点慢
10-10
https://github.com/godotengine/godot/releases/tag/4.1.2-stable
godot-procedural-generation:Godot游戏引擎的过程生成算法和演示
03-18
Godot程序生成 Godot PCG（程序内容生成）是一个构建一系列算法和演示以了解程序生成的项目。这些算法来自我们的课程 。 :right_arrow:在和上关注我们，以获取免费的游戏创建教程，技巧和新闻！获得我们的之一，...
godot:Graphviz点文件生成器
05-02
godot-轻松生成graphviz图 godot可帮助您在应用程序中生成graphviz图。 概要 _ g := NewGraph ( false , true , "my diagram" , nil ) n0 := g . AddNode ( "n0" , map [ string ] string { "color" : "red" }) n1...
Godot-v4.2-beta1-win64.exe.zip
最新发布
11-08
godot 4.2 windows 版本
调色板程序
11-19
调色程序
MFC Windows 程序设计[二十一]之树形控件
hnjzfwy的博客
02-15 1154
MFC是微软公司提供的一个类库（class libraries），用以减少应用程序开发人员的工作量。其中包含大量Windows句柄封装类和很多Windows的内建控件和组件的封装类。有很多初学MFC的小伙伴们都觉得MFC比较难学，看书吧，看了就忘了，网上的一些教程又是写的含糊不清，故而学习起来很吃力...... 故此，本专栏亲自研究，实践，由易到难，层层深入，将调试过程中所遭所遇进行详细讲解，注意事项进行一一列举，希望能够帮助到各位初学MFC的小伙伴，避免走弯路，费时费力。
Godot Shader特效：流光效果
开发游戏的老王
09-01 2657
效果图 实现原理 使用一个渐变图来引导流光的走向 代码如下 shader_type canvas_item; uniform sampler2D light_vector; uniform float width = 0.08; void fragment(){ vec4 color = texture(TEXTURE,UV); if(color.a != 0.0){ float...
Godot 读取外部图片
qq_38606757的博客
01-10 1853
Godot 读取外部图片 get_buffer() 读取文件 load_png_from_buffer() 转换为 Image类 create_from_image() 转换为 ImageTexture类 func load_external_png(filepath:String): var f = File.new() f.open(filepath,File.READ) var buffer = f.get_buffer(f.get_len()) f.close() var img = Im
Godot3游戏引擎入门之十一：Godot中的粒子系统与射击游戏（上）
SpkingR的博客
12-25 2258
一、前言 第一个收集金币的小游戏结束了，洋洋洒洒写了三篇文章，分别介绍了相关节点、场景以及所有的代码，作为新手能够独立使用 Godot 完成自己的第一个游戏也算是正式入门了！接下来，我们开启第二个完整的小游戏介绍：太空射击小游戏！同样很简单，但是有更多的发挥空间，当然，我只介绍最简单的游戏实现，更多的关卡设计、游戏思路和游戏元素则留给大家去摸索开发吧。 我选择这个游戏的灵感来自于我刚开始学习 ...
调色板的简单实现
【小喵】的博客
03-22 1559
activity_main.xml: <LinearLayout xmlns:android="http://schemas.android.com/apk/res/android" android:layout_width="match_parent" android:layout_height="match_parent" android:orientation="
Godot纹理按钮
游戏开发
09-04 1197
Godot TextureButton 继承了: BaseButton < Control < CanvasItem < Node < Object Texture-based按钮。支持按下，悬停，禁用和聚焦状态。 TextureButton与Button具有相同的功能，除了它使用精灵而不是Godot的Theme资源。 它的创建速度更快，但不像更复杂的控件那样支持本地化。 “正常”状态必须包含纹理；其他纹理是可选的。 来看看属性： Expand：如果为true，则使用Stretch
windows 程序设计 调色板
软件开发
09-04 2166
调色板 这时就需要使用Windows调色盘管理器（在Windows 3.0中提出）了。Windows保留了256种颜色中的20种，而允许应用程序修改其余的236种。（在某些情况下，应用程序最多可以改变256种颜色中的254种－只有黑色和白色除外－但这有一点麻烦）。Windows为系统保留的20种颜色（有时称为20种「静态」颜色）如表16-1所示。 表16-1 256种颜
使用godot 4 生成动态程序化网格
03-27
要使用Godot 4生成动态程序化网格，您可以使用Godot的MeshInstance和Mesh类。 以下是一个简单的例子，演示如何使用Godot 4创建一个程序化生成的立方体网格： ```gdscript extends MeshInstance func _ready(): var mesh = Mesh.new() var vertices = [ Vector3(-1, -1, -1), Vector3(1, -1, -1), Vector3(1, 1, -1), Vector3(-1, 1, -1), Vector3(-1, -1, 1), Vector3(1, -1, 1), Vector3(1, 1, 1), Vector3(-1, 1, 1) ] var faces = [ 0, 1, 2, 0, 2, 3, # front 1, 5, 6, 1, 6, 2, # right 5, 4, 7, 5, 7, 6, # back 4, 0, 3, 4, 3, 7, # left 3, 2, 6, 3, 6, 7, # top 4, 5, 1, 4, 1, 0 # bottom ] mesh.add_surface_from_arrays(Mesh.PRIMITIVE_TRIANGLES, vertices, [], [], [], faces) set_mesh(mesh) ``` 这个脚本创建了一个立方体网格，使用8个顶点和12个面。它使用Mesh类的add_surface_from_arrays方法来创建网格，并使用set_mesh方法将其应用于MeshInstance节点。 要创建更复杂的程序化网格，您可以使用其他Godot 4中可用的Mesh类方法和属性，例如Mesh.add_surface_from_arrays_with_blend_shapes，Mesh.surface_set_material，Mesh.surface_remove，Mesh.surface_find_by_name等。

“相关推荐”对你有帮助么？

  • 非常没帮助
  • 没帮助
  • 一般
  • 有帮助
  • 非常有帮助
提交
评论
添加红包

请填写红包祝福语或标题

个

红包个数最小为10个

元

红包金额最低5元

当前余额3.43元 前往充值 >
需支付：10.00元
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包

打赏作者

巽星石

你的鼓励将是我创作的最大动力

¥1 ¥2 ¥4 ¥6 ¥10 ¥20
扫码支付：¥1
获取中
扫码支付

您的余额不足，请更换扫码支付或充值

打赏作者

实付元
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明：

1.余额是钱包充值的虚拟货币，按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载，可以购买VIP、付费专栏及课程。

余额充值