练习：ubershader（实例1）

这个案例是喵爷在知乎上的一个例子，我就拿过来分析
最简单的变体shader练习，可以在材质面板上选择性的让贴图是按照贴图中心（0.5，0.5）缩放还是在（0，0）点缩放

Shader "Learn/UVTransfrom"
{
    Properties
    {
        _MainTex ("Texture", 2D) = "white" {}
        [Toggle] _ScaleOnCenter("Scale On Center", Float) = 0//属性面板开关,他会告诉下面关键字_SCALEONCENTER_ON是打开还是关闭
    }
    SubShader
    {
        Tags { "RenderType"="Opaque" }
        LOD 100

        Pass
        {
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            #include "UnityCG.cginc"
            #pragma shader_feature _SCALEONCENTER_ON//feature关键字_SCALEONCENTER_ON

            struct appdata
            {
                float4 vertex   : POSITION;
                float2 uv       : TEXCOORD0;
            };
            struct v2f
            {
                float2 uv       : TEXCOORD0;
                float4 vertex   : SV_POSITION;
            };

            sampler2D   _MainTex;
            float4      _MainTex_ST;

            //自定义一个变换坐标的函数TransformUV
            float2 TransformUV(float2 srcUV ,half4 argST )
            {
                #if _SCALEONCENTER_ON
                    srcUV.xy -= 0.5;
                #endif//先把坐标移动到00点
                srcUV = srcUV * argST.xy + argST.zw;
                #if _SCALEONCENTER_ON
                    srcUV.xy += 0.5;
                #endif//转换完贴图坐标后再移动回原来坐标点
                return srcUV;
            }
            v2f vert (appdata v)
            {
                v2f o;
                o.vertex = UnityObjectToClipPos(v.vertex);
                o.uv = TransformUV(v.uv, _MainTex_ST);
                return o;
            }

            fixed4 frag (v2f i) : SV_Target
            {
                fixed4 col = tex2D(_MainTex, i.uv);
                return col;
            }
            ENDCG
        }
    }
}