基于8B10B的GT收发器PHY层设计（3）PHY层设计

已于 2024-04-03 17:23:40 修改
阅读量1.7k 收藏 44
点赞数 27
分类专栏： 高速接口学习 文章标签： fpga开发 学习
于 2024-03-31 14:07:46 首次发布
版权声明：本文为博主原创文章，遵循 CC 4.0 BY-SA 版权协议，转载请附上原文出处链接和本声明。
本文链接：https://blog.csdn.net/m0_56222647/article/details/137177084
版权

文章目录

前言

上一篇内容当中我们已经将gt_module模块设计完成，本篇开始进行PHY收发模块设计

一、设计框图

在这里插入图片描述

二、PHY层基本传输协议

在这里插入图片描述

在这里插入图片描述
我们在设置IP核的时候设置过时钟纠正序列，同步码正是该序列，用来纠正时钟的累积误差，一般至少发送俩组同步码，即俩次BC50，BC就是K28.5。SOF则表示一帧数据的开始，EOF表示结束，空闲时期发送LFSR伪随机序列。
注：这里稍微区分一下逗号码和同步码，逗号码是用来指示当前串并转换的位置是否正确，同步码是用来纠正时钟误差。

三、PHY_TX模块

向上通过AXIS接口与用户连接，向下与gt_module模块连接。

3.1、模块接口

module PHY_Tx(
    input               i_clk           ,
    input               i_rst           ,

    input  [31:0]       i_tx_axis_data  ,
    input  [3 :0]       i_tx_axis_keep  ,    
    input               i_tx_axis_valid ,
    input               i_tx_axis_last  ,
    output              o_tx_axis_ready ,

    input               i_gt_tx_done    ,
    output [31:0]       o_gt_tx_data    ,
    output [3 :0]       o_gt_tx_char    
);

3.2、组帧状态机描述

状态机按照数据格式进行跳转，分别进行填充同步码，起始位、数据、结束位，以及在空闲时期插入同步码。

always @(*)begin
    case (r_cur_state)
        P_ST_INIT   : r_nxt_state = i_gt_tx_done ? P_ST_IDLE : P_ST_INIT;
        P_ST_IDLE   : r_nxt_state = ri_tx_axis_valid_1d ? P_ST_COMMA : 
                                    r_st_cnt == P_INSERT_LEN ? P_ST_INSERT : P_ST_IDLE;
        P_ST_COMMA  : r_nxt_state = P_ST_SOF;
        P_ST_SOF    : r_nxt_state = P_ST_DATA;
        P_ST_DATA   : r_nxt_state = !i_tx_axis_valid && (r_st_cnt == r_tx_data_len - 3) ? P_ST_EOF :P_ST_DATA ;
        P_ST_EOF    : r_nxt_state = ri_tx_axis_keep >= 4'b1110 ? P_ST_EOF2 : P_ST_IDLE;
        P_ST_EOF2   : r_nxt_state = P_ST_IDLE;
        P_ST_INSERT : r_nxt_state = ri_tx_axis_valid_1d ? P_ST_COMMA :
                                    r_st_cnt == 1 ? P_ST_IDLE : P_ST_INSERT;
        default     : r_nxt_state = P_ST_INIT;
    endcase
end

3.3、数据大小端问题

需要格外注意的一点是大小端问题，GT发送和接收是小端模式的，在组帧的时候我们按照习惯的大端模式进行组帧，只需要在输出时记得将数据字节顺序重排一下。

assign o_gt_tx_data = {ro_gt_tx_data[7:0],ro_gt_tx_data[15:8],ro_gt_tx_data[23:16],ro_gt_tx_data[31:24]};
assign o_gt_tx_char = {ro_gt_tx_char[0],ro_gt_tx_char[1],ro_gt_tx_char[2],ro_gt_tx_char[3]};

在这里插入图片描述

3.4、字节对齐

用户输入的数据是4字节对齐的，尾端通过keep信号指示有效字节位，在进行组帧的时候，我们是在SOF位后紧接着填充数据字段，也就是说数据整体向后移了一个byte位，所以需要处理4字节对齐的问题，主要是根据用户数据尾端keep来处理SOF位置。
4字节对齐主要是通过打一拍来解决，SOF位置的处理则需要根据用户数据keep信号的情况进行讨论。

always @(posedge i_clk or posedge i_rst)begin
    if(i_rst)begin
        ro_gt_tx_data <= 'd0;
        ro_gt_tx_char <= 'd0;
    end 
    else if(r_cur_state == P_ST_COMMA)begin
        // ro_gt_tx_data <= 32'h50BC50BC;
        ro_gt_tx_data <= 32'hbc50bc50;
        ro_gt_tx_char <= 4'b1010;
    end
    else if(r_cur_state == P_ST_SOF)begin
        ro_gt_tx_data <= {8'hFB,w_fifo_dout[31:8]};
        ro_gt_tx_char <= 4'b1000;
    end
    else if(r_cur_state == P_ST_DATA)begin
        ro_gt_tx_data <= {r_fifo_dout[7:0],w_fifo_dout[31:8]};
        ro_gt_tx_char <= 4'b0000;
    end
    else if(r_cur_state == P_ST_EOF && ri_tx_axis_keep == 4'b1000)begin
        ro_gt_tx_data <= {r_fifo_dout[7:0],w_fifo_dout[31:24],8'hfd,w_lfsr_data[31:24]};
        ro_gt_tx_char <= 4'b0010;
    end
    else if(r_cur_state == P_ST_EOF && ri_tx_axis_keep == 4'b1100)begin
        ro_gt_tx_data <= {r_fifo_dout[7:0],w_fifo_dout[31:16],8'hfd};
        ro_gt_tx_char <= 4'b0001;
    end
    else if(r_cur_state == P_ST_EOF && ri_tx_axis_keep == 4'b1110)begin
        ro_gt_tx_data <= {r_fifo_dout[7:0],w_fifo_dout[31:8]};
        ro_gt_tx_char <= 4'b0000;
    end
    else if(r_cur_state == P_ST_EOF && ri_tx_axis_keep == 4'b1111)begin
        ro_gt_tx_data <= {r_fifo_dout[7:0],w_fifo_dout[31:8]};
        ro_gt_tx_char <= 4'b0000;
    end
    else if(r_cur_state == P_ST_EOF2 && ri_tx_axis_keep == 4'b1110)begin
        ro_gt_tx_data <= {8'hfd,w_lfsr_data[31:8]};
        ro_gt_tx_char <= 4'b1000;
    end
    else if(r_cur_state == P_ST_EOF2 && ri_tx_axis_keep == 4'b1111)begin
        ro_gt_tx_data <= {r_fifo_dout[7:0],8'hfd,w_lfsr_data[31:16]};
        ro_gt_tx_char <= 4'b0100;
    end
    else if(r_cur_state == P_ST_INSERT)begin
        ro_gt_tx_data <= {16'hbc50,16'hbc50};
        ro_gt_tx_char <= 4'b0101;
    end
    else begin
        ro_gt_tx_data <= w_lfsr_data;
        ro_gt_tx_char <= 4'b0000;
    end
end

四、PHY_RX模块

4.1、模块接口

module PHY_Rx(
    input               i_clk           ,
    input               i_rst           ,

    output [31:0]       o_rx_axis_data  ,
    output [3 :0]       o_rx_axis_keep  ,    
    output              o_rx_axis_valid ,
    output              o_rx_axis_last  ,
    input               i_rx_axis_ready ,

    input               i_rx_ByteAlign  ,
    input  [31:0]       i_gt_rx_data    ,
    input  [3 :0]       i_gt_rx_char    
);

4.2、大小端转换

assign w_gt_rx_data = {i_gt_rx_data[7:0],i_gt_rx_data[15:8],i_gt_rx_data[23:16],i_gt_rx_data[31:24]};
assign w_gt_rx_char = {i_gt_rx_char[0],i_gt_rx_char[1],i_gt_rx_char[2],i_gt_rx_char[3]};

将接收数据先进行大小端转换，然后就可以按照大端习惯进行处理，这个看个人情况吧，我只习惯大端模式

4.3、起始位

重点： 为什么我们需要讨论起始位SOF，这是因为GT接收只进行了字节对齐，也就是转换串行数据为并行数据时，每个8bit数据就是我们发送端发送的8bit数据，但这不意味着恢复出来的32bit数据也是对齐的，SOF可以出现在1拍数据（32bit，4byte）的4个byte当中的任何一个byte位置上。
r_comma_access 表示同步码被识别
r_sof表示起始码被识别
r_sof_local 用于指示起始码字节位置

always @(posedge i_clk or posedge i_rst)begin
    if(i_rst)
        r_comma_access <= 'd0;
    else if((ri_gt_rx_data[15:0] == 16'hbc50) && (ri_gt_rx_char[1:0] == 2'b10) && (w_gt_rx_data[31:24] == 8'hfb) && (w_gt_rx_char[3] == 1'b1))
        r_comma_access <= 'd1;
    else if((ri_gt_rx_data[23:0] == 24'hbc50fb) && (ri_gt_rx_char[2:0] == 3'b101))
        r_comma_access <= 'd1;
    else if((ri_gt_rx_data[31:8] == 24'hbc50fb) && (ri_gt_rx_char[3:0] == 4'b1010))
        r_comma_access <= 'd1;
    else if((ri_gt_rx_data_1d[7:0] == 8'hbc) && (ri_gt_rx_char_1d[0] == 1'b1) && (ri_gt_rx_data[31:16] == 16'h50fb) && (ri_gt_rx_char[3:2] == 2'b01))
        r_comma_access <= 'd1;
    else
        r_comma_access <= r_comma_access;
end

always @(posedge i_clk or posedge i_rst)begin
    if(i_rst)
        r_sof <= 'd0;
    else if(r_comma_access && (ri_gt_rx_data_1d[31:24] == 8'hfb) && (ri_gt_rx_char_1d[3] == 1'b1))
        r_sof <= 'd1;
    else if(r_comma_access && (ri_gt_rx_data_1d[23:16] == 8'hfb) && (ri_gt_rx_char_1d[2] == 1'b1))
        r_sof <= 'd1;
    else if(r_comma_access && (ri_gt_rx_data_1d[15:8] == 8'hfb) && (ri_gt_rx_char_1d[1] == 1'b1))
        r_sof <= 'd1;
    else if(r_comma_access && (ri_gt_rx_data_1d[7:0] == 8'hfb) && (ri_gt_rx_char_1d[0] == 1'b1))
        r_sof <= 'd1;
    else
        r_sof <= 'd0;
end

//1表示最高字节位置(从左到右)
always @(posedge i_clk or posedge i_rst)begin
    if(i_rst)
        r_sof_local <= 'd0;
    else if(r_comma_access && (ri_gt_rx_data_1d[31:24] == 8'hfb) && (ri_gt_rx_char_1d[3] == 1'b1))
        r_sof_local <= 'd1;
    else if(r_comma_access && (ri_gt_rx_data_1d[23:16] == 8'hfb) && (ri_gt_rx_char_1d[2] == 1'b1))
        r_sof_local <= 'd2;
    else if(r_comma_access && (ri_gt_rx_data_1d[15:8] == 8'hfb) && (ri_gt_rx_char_1d[1] == 1'b1))
        r_sof_local <= 'd3;
    else if(r_comma_access && (ri_gt_rx_data_1d[7:0] == 8'hfb) && (ri_gt_rx_char_1d[0] == 1'b1))
        r_sof_local <= 'd4;
    else
        r_sof_local <= r_sof_local;
end

4.4、结束位

结束位的字节位置我们也需要进行记录，以便进行keep信号的处理
r_eof 表示结束位被识别
r_eof_1f ：r_eof的前一拍数据
r_eof_2f ：r_eof的前俩拍数据
r_eof_local ：用于指示结束码字节位置

always @(posedge i_clk or posedge i_rst)begin
    if(i_rst)
        r_eof <= 'd0;
    else if(r_comma_access && (ri_gt_rx_data_1d[31:24] == 8'hfd) && (ri_gt_rx_char_1d[3] == 1'b1))
        r_eof <= 'd1;
    else if(r_comma_access && (ri_gt_rx_data_1d[23:16] == 8'hfd) && (ri_gt_rx_char_1d[2] == 1'b1))
        r_eof <= 'd1;
    else if(r_comma_access && (ri_gt_rx_data_1d[15:8] == 8'hfd) && (ri_gt_rx_char_1d[1] == 1'b1))
        r_eof <= 'd1;
    else if(r_comma_access && (ri_gt_rx_data_1d[7:0] == 8'hfd) && (ri_gt_rx_char_1d[0] == 1'b1))
        r_eof <= 'd1;
    else
        r_eof <= 'd0;
end
always @(posedge i_clk or posedge i_rst)begin
    if(i_rst)
        r_eof_1f <= 'd0;
    else if(r_comma_access && (ri_gt_rx_data[31:24] == 8'hfd) && (ri_gt_rx_char[3] == 1'b1))
        r_eof_1f <= 'd1;
    else if(r_comma_access && (ri_gt_rx_data[23:16] == 8'hfd) && (ri_gt_rx_char[2] == 1'b1))
        r_eof_1f <= 'd1;
    else if(r_comma_access && (ri_gt_rx_data[15:8] == 8'hfd) && (ri_gt_rx_char[1] == 1'b1))
        r_eof_1f <= 'd1;
    else if(r_comma_access && (ri_gt_rx_data[7:0] == 8'hfd) && (ri_gt_rx_char[0] == 1'b1))
        r_eof_1f <= 'd1;
    else
        r_eof_1f <= 'd0;
end
always @(posedge i_clk or posedge i_rst)begin
    if(i_rst)
        r_eof_2f <= 'd0;
    else if(r_comma_access && (w_gt_rx_data[31:24] == 8'hfd) && (w_gt_rx_char[3] == 1'b1))
        r_eof_2f <= 'd1;
    else if(r_comma_access && (w_gt_rx_data[23:16] == 8'hfd) && (w_gt_rx_char[2] == 1'b1))
        r_eof_2f <= 'd1;
    else if(r_comma_access && (w_gt_rx_data[15:8] == 8'hfd) && (w_gt_rx_char[1] == 1'b1))
        r_eof_2f <= 'd1;
    else if(r_comma_access && (w_gt_rx_data[7:0] == 8'hfd) && (w_gt_rx_char[0] == 1'b1))
        r_eof_2f <= 'd1;
    else
        r_eof_2f <= 'd0;
end
//1表示最高字节位置(从左到右)
always @(posedge i_clk or posedge i_rst)begin
    if(i_rst)
        r_eof_local <= 'd0;
    else if(r_comma_access && (w_gt_rx_data[31:24] == 8'hfd) && (w_gt_rx_char[3] == 1'b1))
        r_eof_local <= 'd1;
    else if(r_comma_access && (w_gt_rx_data[23:16] == 8'hfd) && (w_gt_rx_char[2] == 1'b1))
        r_eof_local <= 'd2;
    else if(r_comma_access && (w_gt_rx_data[15:8] == 8'hfd) && (w_gt_rx_char[1] == 1'b1))
        r_eof_local <= 'd3;
    else if(r_comma_access && (w_gt_rx_data[7:0] == 8'hfd) && (w_gt_rx_char[0] == 1'b1))
        r_eof_local <= 'd4;
    else
        r_eof_local <= r_eof_local;
end

4.5、axis数据流恢复

进行数据恢复的时候需要根据起始码位置来处理4字节对齐问题，其中最困难的地方在于keep信号的恢复，它需要同时考虑起始码和结束码的问题 ，这里大家可以根据代码认真思考一下，主要是根据起始码位置和结束码位置，对4‘b1111进行移位来恢复最后一帧数据的keep信号。

always @(posedge i_clk or posedge i_rst)begin
    if(i_rst)
        ro_rx_axis_data <= 'd0;
    else if((r_sof || r_run) && r_sof_local == 'd1)
        ro_rx_axis_data <= {ri_gt_rx_data_2d[23:0],ri_gt_rx_data_1d[31:24]};
    else if((r_sof || r_run) && r_sof_local == 'd2)
        ro_rx_axis_data <= {ri_gt_rx_data_2d[15:0],ri_gt_rx_data_1d[31:16]};
    else if((r_sof || r_run) && r_sof_local == 'd3)
        ro_rx_axis_data <= {ri_gt_rx_data_2d[7:0],ri_gt_rx_data_1d[31:8]};
    else if((r_sof || r_run) && r_sof_local == 'd4)
        ro_rx_axis_data <= ri_gt_rx_data_1d;
    else
        ro_rx_axis_data <= ro_rx_axis_data;
end

always @(posedge i_clk or posedge i_rst)begin
    if(i_rst)
        ro_rx_axis_keep <= 'd0;
    else if(ro_rx_axis_last)
        ro_rx_axis_keep <= 'd0;
    else if(r_eof_1f && (r_sof_local >= (r_eof_local - 1)))
        ro_rx_axis_keep <= (4'hf << (r_sof_local + 1 - r_eof_local));
    else if(r_eof && (r_sof_local < (r_eof_local - 1)))
        ro_rx_axis_keep <= (4'hf << (4-(r_eof_local - 1 - r_sof_local)));
    else if(r_sof || r_run)
        ro_rx_axis_keep <= 4'hf;
    else
        ro_rx_axis_keep <= 'd0;
end
 
always @(posedge i_clk or posedge i_rst)begin
    if(i_rst)
        ro_rx_axis_valid <= 'd0;
    else if(ro_rx_axis_last)
        ro_rx_axis_valid <= 'd0;
    else if(r_sof)
        ro_rx_axis_valid <= 'd1;
    else
        ro_rx_axis_valid <= ro_rx_axis_valid;
end

always @(posedge i_clk or posedge i_rst)begin
    if(i_rst)
        ro_rx_axis_last <= 'd0;
    else if(ro_rx_axis_last)
        ro_rx_axis_last <= 'd0;
    else if(r_eof_2f && (r_sof_local == 4 && r_eof_local == 1))
        ro_rx_axis_last <= 'd1;
    else if(r_eof_1f && (r_sof_local >= (r_eof_local - 1)))
        ro_rx_axis_last <= 'd1;
    else if(r_eof)
        ro_rx_axis_last <= 'd1;
    else
        ro_rx_axis_last <= 'd0;
end

五、LFSR伪随机码

发送端空闲时期需要发送伪随机码来模拟信道的高斯噪声

module LFSR_gen#(
    parameter       P_LFSR_INIT = 16'hA076
)(
    input           i_clk       ,
    input           i_rst       ,

    output [31:0]   o_lfsr_data 
);
reg  [31:0] r_lfsr_data ;
reg  [15:0] r_lfsr      ;
wire [47:0] w_xor_run   ;

assign w_xor_run[47:32] = r_lfsr;
assign o_lfsr_data = r_lfsr_data;
genvar i;
generate
    for(i = 0 ; i < 32 ; i = i + 1)begin
        assign w_xor_run[31 - i] = w_xor_run[47 - i]^w_xor_run[46 - i]^w_xor_run[45 - i]^w_xor_run[32 - i];
    end
endgenerate

always @(posedge i_clk or posedge i_rst)begin
    if(i_rst)
        r_lfsr <= P_LFSR_INIT;
    else
        r_lfsr <= w_xor_run[15:0];
end

always @(posedge i_clk or posedge i_rst)begin
    if(i_rst)
        r_lfsr_data <= 'd0;
    else
        r_lfsr_data <= w_xor_run[31:0];  
end

endmodule

六、链路空闲时期处理

在链路空闲时期需要发送伪随机码，并且定期插入同步码0xBC60。
在接收端XCLK时钟域需要跨到RXUSERCLK时钟域，虽然俩者是同频的，但细微的差别也会导致FIFO的上溢和下溢问题，都会是的接收数据出错，我们该如何修正读快写满或者是读慢写快的问题呢？
解决办法就是弹性（Elastic）buffer，这和8B10B编码也有关系，因为涉及到了K码，我们在传输数据的时候会先发送同步码，同步码当中存在K码，当FIFO快写满的时候，弹性buffer就将FIFO当中的K码删除掉一些，当快读空的时候，就在FIFO里插入一些K码。
在这里插入图片描述

在这里插入图片描述

在这里插入图片描述

顺子学不会FPGA
关注
专栏目录
基于FPGA的以太网设计（4）----详解PHY的使用（以YT8531为例）
孤独的单刀
08-01 2513
基于FPGA的以太网设计（4）----详解PHY的使用（以YT8531为例）
详解Xilinx FPGA高速串行收发器GTX/GTP（9）--TX/RX通道
孤独的单刀
08-12 948
详解Xilinx FPGA高速串行收发器GTX/GTP（9）--TX/RX通道
基于GTX 8B10B编码的自定义PHY发送模块（高速收发器十二）
weixin_50810761的博客
06-02 1727
本文详细介绍了自定义PHY协议发送模块的设计方法，重点在于状态机的实现和FIFO的使用以提高数据发送效率。设计考虑了axi_stream接口与GTX IP小端对齐的差异，并在空闲时发送LFSR码以减少EMI。详细分析了状态机的编码逻辑、FIFO配置和计数器设置，并通过仿真验证了设计的正确性。设计思路清晰，代码实现简洁，为GTX IP的深入应用提供了实用指导。
高速通信GT收发器之8B/10B编码
亚特的博客
06-13 932
为什么要8B/10B编码呢？其实就是为了在高速串行通信中，把8bit的数据编码成10bit的数据发送出去，以达到直流平衡的目的。那什么是直流平衡呢？就是在传输信号时确保直流分量（DC component）在一段时间内保持平衡或为零，也就是为了避免传输的数据出现长连“1”或者长连“0”的情况。为什么要直流平衡呢？其实就是为了时钟恢复（CDR Clock Data Recovery）。那为什么要时钟恢复呢？
高速串行通信常用的编码方式-8b/10b编码/解码
OpenFPGA的博客
09-09 9131
绪论8b/10b编码/解码是高速串行通信，如PCle SATA(串行ATA)，以及Fiber Channel中常用的编解码方式。在发送端，编码电路将串行输入的8比特一组的数据转变成10比特...
GTX收发器
山音水月
07-26 1778
.
基于GTX 8B10B编码的自定义PHY接收模块（高速收发器十三）
weixin_50810761的博客
06-03 1780
本文详细介绍了自定义PHY协议接收模块的设计，重点解决了GTX IP接收通道的字节对齐问题。通过移位寄存器暂存数据，检测帧头帧尾，生成数据掩码和有效指示信号。设计考虑了起始位和停止位的多种分布情况，确保了对任意字节数据的正确处理。仿真验证了十六种接收格式，确认了模块功能的正确性。最终，该模块将与GTX IP和自定义发送模块综合，形成完整的PHY设计，为下一步的实际验证打下基础。
8B10B编码原理详解
m0_56222647的博客
03-28 2615
比如：在表3B/4B中，对于D.x.3（011），其对应的4B码字有两种：1100和0011，若此时RD为负，则取1100作为其对应的4B码字作为输出，同时检验此时的编码是否为完美编码，如果是完美编码，则保持RD的极性不变；本章来阐述下将8bit转换为10bit编码是如何实现的，转换的目的是保证DC平衡，所有用10bit表示8bit的原则也是尽可能的从1024个里面挑选出0和1差不多的，而且是01交替差不多的。低５位编码为６位，依次命名为ａ，ｂ，ｃ，ｄ，ｅ，ｉ，如下图所示。这里，可能有个疑问，
SGMII接口与8b/10b编码在通信设计中的应用
此技术主要应用于交换机、路由器和收发器设计，提供全双工数据传输，并符合Cisco的SGMII规范。该资源描述的是SGMIIeVerificationComponent，这是一个模块化、同步设计的IP组件，用于验证SGMII兼容的PHY或MAC接口。" ...
FPGA Xilinx 7系列高速收发器GTX通信工程代码
10-26
1. GTX收发器配置：在设计过程中，开发者需要通过硬件描述语言（如VHDL或Verilog）来配置GTX收发器的参数，包括时钟管理、数据编码、均衡、眼图分析等。这些设置会直接影响到信号质量和传输距离。 2. 时钟管理：GTX...
德州仪器的USB3.0 PHY
06-06
德州仪器（Texas Instruments，简称TI）推出的USB3.0 PHY（物理层收发器）产品，如TUSB1310A，是一种高速USB接口解决方案，它支持最高5.0 Gbps的数据传输速率，相当于480 MB/s的传输速度。这个速率远远超过了USB 2.0...
(转)xilinx 高速收发器Serdes深入研究-Comma码
yundanfengqing_nuc的专栏
07-08 1476
一、为什么要用Serdes 传统的源同步传输，时钟和数据分离。在速率比较低时（<1000M）,没有问题。 在速率越来越高时，这样会有问题 由于传输线的时延不一致和抖动存在，接收端不能正确的采样数据，对不准眼图中点。 然后就想到了从数据里面恢复出时钟去采样数据，即CDR 这样就不存在延迟不一致的情况，有轻微的抖动也不会影响采样（恢复的时钟会随着数据一起抖动）。 二 、为什么要用8b10b,64b66b? 1 提供足够的跳变来恢复时钟 这样还有问题，收发两端必须共地，但往往很难实现。 ...
7系列GTX中的疑惑
weixin_30600503的博客
06-13 547
1、PCOMMA与MCOMMA指什么？ PCOMMA是指RD-部分的数据，MCOMMA是指RD+部分的数据。 2、risk信号作用？ risk信号来指示有效的K码。 如果不选择用8b10b来编码，是需要对齐的。无论是选择64b/66b还是None。 3、对齐的边界（alignment boundaries）? 个人在这里理解为对齐位置在输出的数据的字节位。如下图 ...
8B10B编解码及FPGA实现
weixin_34309435的博客
04-14 2372
概述          在使用ALTERA的高速串行接口时，GXB模块里硬件实现了8B10B编码，用户只是“傻瓜”式的使用，笔者也一直没有弄清楚。网上搜索了一些学习资料，结合参考文献希望能够对其进行消化。另外，ALTERA现在已经提供8B10B IP，用户可以直接使用，不过有时候为了代码可移植性需要自己写代码实现8B10B编解码，笔者希望在这方面也做些实践。 8B10B编码概念       ...
ZYNQ7045之YOLO部署——FPGA-ZYNQ Soc实战笔记1
m0_69082048的博客
10-30 665
输入时固定的，因为存在全连接层，网络有24层卷积，2个全连接层，包含大量1x1卷积，最终7x7x30表示，7x7个各自，每个格子有30个数据，30个数据包含两个部分1：位置信息（第一个候选框中心点x） 2：预测中心点纵坐标 y 3：候选框W宽度 4：高度H5：第一个候选框置信度6：位置信息（第二个候选框中心点x） 7：预测中心点纵坐标 y 8：候选框W宽度 9：高度H10：第一个候选框置信度11~20：类别信息以及最后的损失函数。
【网络监控加速设备】国产化一站式高性能数据处理平台（海光CPU+复旦微FPGA）
最新发布
Future_alvin的博客
10-30 810
随着网络流量的飞速增长，数据的监控与管理需求日益加剧。针对这一痛点，一款集协议检测、数据监测、报文转发和结果展示于一体的，设备百分之百国产化也体现了完全自主可控。设备不仅具备丰富的网络监控功能，还支持多种配置和自检功能，是高效、安全的数据处理平台的优选。
FPGA实现串口升级及MultiBoot（十一)QuickBoot介绍
OpenFPGA的博客
10-29 977
MultiBoot在流行前官方也推出过QuickBoot作为保证升级的方式，但是不知什么原因，该方式的参考例程已经被官方PASS掉了，下面是官方的说明：https://adaptivesupport.amd.com/s/article/000036833?language=en_US至于原因，后面我们总结时候再分析。介绍使用MultiBoot进行远程更新的架构如下：图1：MultiBoot远程更新...
FPGA时序分析和约束学习笔记（3、Timequest时序路径详解和优化）
qq_37812160的博客
10-30 180
FPGA Timequest时序路径详解和优化
fpga开发环境总结
m0_38012497的博客
10-25 905
FPGA开发环境总结
评论 2
添加红包

请填写红包祝福语或标题

个

红包个数最小为10个

元

红包金额最低5元

当前余额3.43元 前往充值 >
需支付：10.00元
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包

打赏作者

顺子学不会FPGA

你的鼓励将是我创作的最大动力

¥1 ¥2 ¥4 ¥6 ¥10 ¥20
扫码支付：¥1
获取中
扫码支付

您的余额不足，请更换扫码支付或充值

打赏作者

实付元
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明：

1.余额是钱包充值的虚拟货币，按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载，可以购买VIP、付费专栏及课程。

余额充值