本文详细介绍了Phong光照模型的原理及在Unity Shader中的实现过程，包括环境光、漫反射、高光反射和自发光四个分量的计算。通过顶点和片元着色器的编写，展示了如何在Unity中模拟真实世界的光照效果。同时提到了Blinn-Phong模型作为Phong模型的改进。内容适合Unity开发者和图形学爱好者学习。
phong光照模型
phong光照模型是一个经验模型，并没有理论依据，只是说“看起来能像那么回事”。
优点当然是计算量很小，因为所用的公式都很简单，而且基本只要知道一些简单的属性就可以计算，比如坐标啊，光源方向啊，法线啊、完全不用模拟单条光线的路径之类的。
缺点就是比较粗糙，而且也没有办法模拟多次反射的效果。
目前在游戏领域不是光线追踪比较火嘛，因为以前的硬件没有那么高的算力来做光线追踪，在光线追踪之前就是这个经验模型及其变体运用的最广了。
phong光照模型把光线分为四个部分处理，分别是环境光，自发光，漫反射和高光反射，最后渲染出来的结果就是这四个部分叠加起来的结果。
接下来我们在unity shader中实现这个光照模型
顶点着色器
首先从应用中获取我们需要的数据，
编写appdata结构体如下
unity shader需要声明对应的语义才会传递正确的数据
NORMAL语义代表需要法线数据
struct appdata
{
float4 vertex : POSITION;
float3 normal : NORMAL;
};
phong光照模型是逐像素光照，所以我们需要在顶点着色器中准备数据，具体计算在片元着色器中进行。
我们打算在世界坐标下进行计算，所以会用到世界坐标下的法线和世界坐标下的坐标
当然还有最重要的，要把vertex转换到裁剪坐标下，这可以看成是每个着色器都需要编写的固定代码。
编写顶点着色器如下
其中UnityObjectToClipPos是把坐标从模型空间转换到裁剪空间下的宏
UnityObjectToWorldNormal是把法线从模型空间转换到世界空间下的宏
顶点的世界坐标则用矩阵左乘坐标计算，unity_ObjectToWorld是从模型空间到世界空间的变换矩阵
v2f vert(appdata v)
{
v2f o;
o.vertex = UnityObjectToClipPos(v.vertex);
o.worldNormal = UnityObjectToWorldNormal(v.normal);
o.worldPos = mul(unity_ObjectToWorld, v.vertex);
return o;
}
传递给顶点着色器的结构体
struct v2f
{
float4 vertex : SV_POSITION;
float3 worldNormal:TEXCOORD0;
float3 worldPos:TEXCOORD1;
};
环境光分量
环境光简单来说就是用于模拟一些次要光源的总和效果。
比如在现实世界中绝对黑暗的情况是很少的，就算你在房间里不开灯，外面各种各样的灯还是会多多少少透进来一点，又或者是各种外部光线的反射折射透进来，从而把房间内的物体稍稍照亮，使你能看清楚物体的轮廓。
环境光分量可以用宏定义获取，这个值是在unity编辑器内的光照窗口设定的
使用UNITY_LIGHTMODEL_AMBIENT获取之后乘上颜色
这是一个四维向量，包括rgb和透明度，但是我们目前还不需要计算透明度，所以使用.xyz获取这个向量的rgb分量
float3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz * _Color;
只有环境光分量的效果如下，可以看到物体所有部分的亮度都是一样的。phong光照模型的环境光是使用一个固定值，效果并不是很好
漫反射分量
漫反射分量简单来说就是模拟现实世界中物体比较粗糙的部分，光线入射之后在所有方向的反射都是一样的，因此没有计算视角方向。
漫反射分量的计算是用表面法线点乘光源方向。这里使用单位向量进行点乘，推导一下其实就是计算两个向量的角度，当两个向量重合时点乘结果为1。
应用这个公式之后，就是朝向光源方向那一面会被照亮，因为这一面的法线方向和光源方向更接近。
这个法线其实是在3d软件里做模型导出后已经自带的数据，模型空间的表面法线可以在appdata结构体里声明就可以获得
这里需要用NORMAL语义表明这是一个法线
struct appdata
{
float4 vertex : POSITION;
float3 normal : NORMAL;
};
然后在顶点着色器中，需要把这个法线转换到世界坐标下，因为我们整个计算在世界坐标下完成。当然在任意空间中都是可以的，只需要把所有值都转换到那个空间下计算就可以了。
使用UnityObjectToWorldNormal宏可以把法线从模型空间转换到世界空间
o.worldNormal = UnityObjectToWorldNormal(v.normal);
然后是光照方向，因为我们是逐片元光照，所以就是从当前片元到光源的方向，我们这里只简单处理了一个光源。
使用UnityWorldSpaceLightDir获取光源在世界空间下到某点向量，在该pass中，这个光源是平行光
因为只是作为方向使用，所以需要使用normalize函数单位化向量
float3 worldLightDir = normalize(UnityWorldSpaceLightDir(i.worldPos));
最后使用dot点乘函数获得漫反射分量，注意这个分量是一个值而不是向量，可以看成是亮度系数，需要乘上一个颜色向量。
最后使用max来过滤掉小于0的值，因为单位向量点乘的值可能落在[-1,1]中，物体光照背面如果小于0，那么就会变得更暗，我们不希望这样，所以使用了max函数。
float3 diffuse = max(0, dot(worldNormal, worldLightDir)) * _Color;
只有漫反射分量的效果如下
可以看到已经是明暗分明了，不过没有镜面反射效果
高光分量
高光分量模拟显示世界中物体一些非常光滑平整的部分，可以将光线朝一个方向反射而出，而如果你直视这个方向的时候，就会觉得非常刺眼。
高光部分的计算是使用视角方向点乘光的反射方向。即你的视角与反射光越接近，高光部分就越亮，这也和事实相符。
先使用reflect函数来获得光线反射方向，第一个参数是入射光线，第二个参数是反射轴。
我们这里希望光线沿法线反射。
注意这里在worldLightDir前添加了负号，这是因为worldLightDir是从当前坐标到光源的向量，而reflect接受的第一个参数是从光源出发的光线，所以需要反一下。
float3 worldLightReflectDir = normalize(reflect(-worldLightDir, worldNormal));
视角方向计算也很简单，就是用摄像机坐标减去当前片元坐标，_WorldSpaceCameraPos 是一个预定义的值，代表当前正在进行渲染的摄像机
float3 worldViewDir = normalize(_WorldSpaceCameraPos - i.worldPos);
然后使用点乘计算高光，同样使用了max防止光照背面会变得更暗。
这里也用到了pow，这是一个指数函数，可以控制高光区域的大小
float3 speclur = pow(max(0, dot(worldLightReflectDir, worldViewDir)),_Speclur) * _Color;
只有高光分量的效果如下
可以看到有一个光斑一样的效果。而只有我们的视角和光照方向大致重合的时候，才能看出效果
(此实例中光照从左边来)
自发光分量
自发光直接使用指定值，因为Phong模型里的自发光并不能真正照亮其他物体
float3 emissive = _EmissiveColor.xyz;
总结
最后在片元着色器中返回颜色，就是四个分量相加的值。
我们之前说了漫反射和高光反射其实是模拟不同粗糙度的表面，这样直接叠加其实也是不合理的，一般还要再加一个遮罩贴图，标明模型上有些部分是光滑的有点部分是粗糙的。或者一个模型由多个部分组成，每个部分材质的光滑度不一样，因此也需要在着色器中添加对应的属性来计算。
完整代码如下，这样我们就大致在unity shader中实现了phong光照模型。不过还不完整，例如只针对ForwardBase定义了一个pass，只能处理一个光源，没有进行纹理贴图等等。不过知道原理后就可以进行各种扩展了。
Shader "Test/PhongComplete"
{
Properties
{
_Color("Color",Color)=(1,1,1,1)
_EmissiveColor("EmissiveColor",Color)=(0,0,0,0)
_Speclur("Speclur",int)=2
}
SubShader
{
Pass
{
Tags
{
"LightMode"="ForwardBase"
}
CGPROGRAM
#pragma vertex vert
#pragma fragment frag
#include "UnityCG.cginc"
float4 _Color;
float4 _EmissiveColor;
float _Speclur;
struct appdata
{
float4 vertex : POSITION;
float3 normal : NORMAL;
};
struct v2f
{
float4 vertex : SV_POSITION;
float3 worldNormal:TEXCOORD0;
float3 worldPos:TEXCOORD1;
};
v2f vert(appdata v)
{
v2f o;
o.vertex = UnityObjectToClipPos(v.vertex);
o.worldNormal = UnityObjectToWorldNormal(v.normal);
o.worldPos = mul(unity_ObjectToWorld, v.vertex);
return o;
}
fixed4 frag(v2f i) : SV_Target
{
//使用内置宏获取当前片元到光源的方向,里面已经处理了不同光源
float3 worldLightDir = normalize(UnityWorldSpaceLightDir(i.worldPos));
//世界坐标下的法线
float3 worldNormal = normalize(i.worldNormal);
//世界坐标下的视角方向
float3 worldViewDir = normalize(_WorldSpaceCameraPos - i.worldPos);
//光线在当前片元对应的法线下的反射方向
float3 worldLightReflectDir = normalize(reflect(-worldLightDir, worldNormal));
//环境光分量，直接用宏定义获取 此值是在unity编辑器内的光照窗口设定
float3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz * _Color;
//漫反射分量，使用表面法线点乘光源方向
float3 diffuse = max(0, dot(worldNormal, worldLightDir)) * _Color;
//高光分量，使用视角方向点乘光的反射方向
float3 speclur = pow(max(0, dot(worldLightReflectDir, worldViewDir)),_Speclur) * _Color;
//自发光分量，直接使用设定值
float3 emissive = _EmissiveColor.xyz;
return fixed4(ambient + diffuse + speclur+emissive, 1);
}
ENDCG
}
}
}
最终叠加效果如下
phong模型有一个简单的改进叫做blinn-phong模型
blinn-phong的实现
扫一扫
6024
被折叠的 条评论
为什么被折叠?
到【灌水乐园】发言
