Phong光照模型和Unity实现

最新推荐文章于 2024-09-23 19:20:46 发布

Terie

最新推荐文章于 2024-09-23 19:20:46 发布

阅读量682

点赞数

分类专栏：实时渲染 # Unity Shader

本文链接：https://blog.csdn.net/Terie/article/details/108797741

版权

Unity Shader 同时被 2 个专栏收录

5 篇文章 0 订阅

订阅专栏

实时渲染

4 篇文章 5 订阅

订阅专栏

文章目录

概述

Phong光照模型由Lambert光照模型发展而来。Lambert描述了物体表面对漫反射的反应。Phong光照模型在此基础上增加了环境光和镜面反射两项内容。

Phong光照模型和Lambert光照模型一样，依然是个经验模型。这是说，Phong光照模型只是依据粗糙的实验数据得出的一个近似物理世界的物理模型，并没有严格地按照物理定律进行推论和分析。

在绝大多数场合，Phong光照模型能够表现出和真实物理世界相近的光照效果。

数学模型

Phong光照模型描述了物体在人眼中的呈现的样子，由物体表面的漫反射，环境光反射和镜面反射三种现象造成的效果组成。它可以写成一个公式：
$\begin{aligned} I &= I_iK_a +I_iK_d\cdot(L\cdot N) + I_iK_s\cdot(R\cdot V)^n \end{aligned}$

$I$ ：到达观察者的光强
$I_i$ ：物体表面某点的入射光强
$K_a$ ：环境光（ambient）反射系数
$K_d$ ：漫反射（diffuse）反射系数
$K_s$ ：镜面反射（specular）反射系数
$L$ ：指向光源的方向
$N$ ：物体表面某点的法线
$R$ ：反射光的出射方向
$V$ ：指向观察者的方向
$n$ ：镜面反射指数

环境光部分

首先Phong是一个局部光照模型，它只针对直接来自光源的光的影响进行了比较好的描述，尽管这个描述属于经验上的描述。但实际物理世界还有其他来自其他物体反射的光的部分。这是全局光照模型需要考虑的事情，Phong光照模型把这一部分全部扔进了环境光部分，用一个简单的环境光反射系数进行约束。

漫反射系数

漫反射部分 $I_iK_d\cdot(L\cdot N) = I_iK_d\cdot(|L|\cdot |N|\cdot cos\theta)$ 用一个漫反射系数来表示入射光中有多少部分参与了漫反射。同时Phong光照模型认为漫反射的效果与观察者的方位无关，与入射光和物体表面的法线的夹角有关。入射光越是垂直于物体表面入射，漫反射光越是强烈。

镜面反射部分

镜面反射部分 $I_iK_s\cdot(R\cdot V)^n = I_iK_s\cdot(|R|\cdot |V|\cdot cos\theta)^n$ 用一个镜面反射系数来描述入射光中有多少光参与了镜面反射。同时Phong光照模型认为镜面反射的效果与反射光的方向和观察者方向有关。即观察者越是接近反射光的方向，镜面反射的效果越强烈。还需注意的是，这里的镜面反射并不是严格意义上的镜面反射，因为按照严格的镜面反射，反射角等于入射角，只要观察者不在反射光的方向上，反射光的强度就为0。所以这里的镜面反射只是指反射光在分布各个角度上，越是接近镜面反射光的方向则光强越是集中。 $n$ 就是描述这样的集中程度的。

Blinn-Phong光照模型

Phong光照模型的镜面反射部分使用反射光和观察者方向来计算。为此我们还需要根据入射光和法线计算出反射光方向，计算式如下：
$R = 2 * N (d o t (N, L)) - L$
这种计算比较耗时。Blinn-Phong光照模型另辟蹊径，使用观察者方向和入射光方向的角平分方向 $H$ 参与计算，因为计算 $H$ 只需要计算 $L + V$ ，相比计算反射光方向，这个计算量就小得多。它与法线之间的夹角 $\phi = \theta$ ，其中 $\theta$ 就是反射光与观察者方向的夹角。于是 $R\cdot V$ 就可以替换成 $N\cdot H$ 。

Unity Shader实现

这里的实现是Blinn-Phong光照模型的实现，只考虑单个光源的情况，且不考虑环境光照。

Shader "Custom/My First Lighting Shader" {
	Properties {
		_MainTex ("Albedo", 2D) = "white" {} // 漫反射系数
		_SpecularTint ("Specular", Color) = (0.5, 0.5, 0.5) // 镜面反射系数
		_Smoothness ("Smoothness", Range(0, 1)) = 0.1 // 即 n
	}

	SubShader {
		Tags {
				"LightMode" = "ForwardBase"
		}
		Pass {
			CGPROGRAM

			#pragma vertex MyVertexProgram
			#pragma fragment MyFragmentProgram

			#include "UnityStandardBRDF.cginc"
			#include "UnityStandardUtils.cginc"

			sampler2D _MainTex;
			float4 _SpecularTint;
			float4 _MainTex_ST;
			float _Smoothness;

			struct VertexData{
				float4 position : POSITION;
				float3 normal: NORMAL;
				float2 uv : TEXCOORD0; 
			};

			struct Interpolators{
				float4 position: SV_POSITION;
				float2 uv: TEXCOORD0  ;
				float3 normal: TEXCOORD1;
				float3 worldPos: TEXCOORD2 ;
			};

			Interpolators MyVertexProgram(VertexData v){
				Interpolators i;
				i.uv = TRANSFORM_TEX(v.uv, _MainTex); // 按照纹理缩放和平移计算正确的uv坐标
				i.position = UnityObjectToClipPos(v.position); // 将模型坐标从模型坐标系转化到裁剪坐标系
				i.worldPos = mul(unity_ObjectToWorld, v.position); // 获取模型的世界坐标，用来计算观察者方向
				i.normal = UnityObjectToWorldNormal(v.normal); // 法线从模型坐标系转发化到世界坐标系
				return i;
			}

			float4 MyFragmentProgram(Interpolators i): SV_TARGET{
				i.normal = normalize(i.normal);
				float3 lightDir = _WorldSpaceLightPos0.xyz; // 入射光方向
				float3 viewDir = normalize(_WorldSpaceCameraPos - i.worldPos); // 观察者方向
				
				// -------------计算漫反射部分-------------------
				float3 lightColor = _LightColor0.rgb; // 入射光强
				float oneMinusReflectivity;
				float3 albedo = tex2D(_MainTex, i.uv).rgb;
				// 这一步是为了能量守恒，使得漫反射部分和镜面反射部分之和不能超过入射光
				albedo = EnergyConservationBetweenDiffuseAndSpecular(albedo, _SpecularTint.rgb, oneMinusReflectivity); 
				float3 diffuse = albedo *lightColor * DotClamped(lightDir, i.normal); // 得到漫反射部分的结果
				
				// -------------计算镜面反射部分--------------------
				float3 halfVector = normalize(lightDir + viewDir); // 计算中间向量H，而不是直接计算反射光方向
				float3 specular = _SpecularTint.rgb * lightColor * pow(DotClamped(halfVector, i.normal),_Smoothness * 100); // 得到镜面反射部分
				return float4(diffuse + specular, 1); // 将漫反射部分和镜面反射部分相加得到结果
			}

			ENDCG
		}
	}
}

效果

完全粗糙的表面，只发生漫反射。
在这里插入图片描述
有镜面反射部分参与的效果

更强烈的镜面反射

第三张图即是比第二张图的n值更大的镜面反射。所以模型的高光部分比第二张图显得更小更集中。

另外模型变暗是因为能量守恒的约束，在代码中我们对漫反射和镜面反射进行了约束，使得他们之和不会超过入射光。否则，镜面反射和漫反射叠加，会使得物体变得很亮，甚至亮过光源。从第三张图中可以明显看到，镜面反射越强烈，漫反射的部分越弱。当物体几近完全镜面反射的时候，只有在物体表面的反射光方向正对观察者的点才有一点亮斑，其余全部呈现黑色。