【007-Shader-旋转特效】

// 旋转特效
Shader "Study/07-RotationShader"
{
    Properties
    {
        _MainTex ("Texture", 2D) = "white" {}

        _RotScale("Rot Scale",Range(0,100)) = 50
    }
    SubShader
    {
        // No culling or depth
        Cull Off ZWrite Off ZTest Always
        Blend SrcAlpha OneMinusSrcAlpha
        Pass
        {
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag

            #include "UnityCG.cginc"

            struct appdata
            {
                float4 vertex : POSITION;
                float2 uv : TEXCOORD0;
            };

            struct v2f
            {
                float2 uv : TEXCOORD0;
                float4 vertex : SV_POSITION;
            };

            v2f vert (appdata v)
            {
                v2f o;
                o.vertex = UnityObjectToClipPos(v.vertex);
                o.uv = v.uv;
                return o;
            }

            sampler2D _MainTex;
            float _RotScale;
            // 中心点
            static float2 center = {0.5,0.5};


            fixed4 frag (v2f i) : SV_Target
            {

                float2 uv =i.uv;
                float2 dt = uv-center;
                float len = sqrt(dot(dt,dt));
                // 弧度值
                float theta = len * UNITY_PI * _RotScale;

                // 旋转矩阵
                float2x2 rot = {
                    cos(theta),sin(theta),
                    -sin(theta),cos(theta),
                };
                dt = mul(rot,dt);
                uv = dt + center;

                fixed4 col = tex2D(_MainTex, uv);
                return col;
            }
            ENDCG
        }
    }
}