unity urp 获取屏幕深度法向颜色纹理以及从深度纹理重构世界空间坐标

之前写过如何从屏幕空间获取uv，但是讲的不完善，https://blog.csdn.net/qq_30100043/article/details/125883016
而且还没有说如何使用深度重新构建世界坐标。所以，这一篇，讲解一下，获取深度 纹理 以及屏幕空间法向。
接下来，说一下，引擎内置的文件，让我们简单的去获取，再也不用想着去哪抄代码了。

这两个对应的是深度贴图和颜色贴图。在urp里面必须开启才行。
引擎内置的纹理获取文件在

里面的代码也很简单
DeclareDepthTexture

#ifndef UNITY_DECLARE_DEPTH_TEXTURE_INCLUDED
#define UNITY_DECLARE_DEPTH_TEXTURE_INCLUDED
#include "Packages/com.unity.render-pipelines.universal/ShaderLibrary/Core.hlsl"

TEXTURE2D_X_FLOAT(_CameraDepthTexture);
SAMPLER(sampler_CameraDepthTexture);

float SampleSceneDepth(float2 uv)
{
    return SAMPLE_TEXTURE2D_X(_CameraDepthTexture, sampler_CameraDepthTexture, UnityStereoTransformScreenSpaceTex(uv)).r;
}

float LoadSceneDepth(uint2 uv)
{
    return LOAD_TEXTURE2D_X(_CameraDepthTexture, uv).r;
}
#endif

定义define防止多次引入，然后引入Core文件，然后声明纹理，后面再增加一下纹理拾取的方法，剩下的两个都一样的套路

DeclareNormalsTexture

#ifndef UNITY_DECLARE_NORMALS_TEXTURE_INCLUDED
#define UNITY_DECLARE_NORMALS_TEXTURE_INCLUDED
#include "Packages/com.unity.render-pipelines.universal/ShaderLibrary/Core.hlsl"

TEXTURE2D_X_FLOAT(_CameraNormalsTexture);
SAMPLER(sampler_CameraNormalsTexture);

float3 SampleSceneNormals(float2 uv)
{
    return UnpackNormalOctRectEncode(SAMPLE_TEXTURE2D_X(_CameraNormalsTexture, sampler_CameraNormalsTexture, UnityStereoTransformScreenSpaceTex(uv)).xy);
}

float3 LoadSceneNormals(uint2 uv)
{
    return UnpackNormalOctRectEncode(LOAD_TEXTURE2D_X(_CameraNormalsTexture, uv).xy);
}
#endif

DeclareOpaqueTexture

#ifndef UNITY_DECLARE_OPAQUE_TEXTURE_INCLUDED
#define UNITY_DECLARE_OPAQUE_TEXTURE_INCLUDED
#include "Packages/com.unity.render-pipelines.universal/ShaderLibrary/Core.hlsl"

TEXTURE2D_X(_CameraOpaqueTexture);
SAMPLER(sampler_CameraOpaqueTexture);

float3 SampleSceneColor(float2 uv)
{
    return SAMPLE_TEXTURE2D_X(_CameraOpaqueTexture, sampler_CameraOpaqueTexture, UnityStereoTransformScreenSpaceTex(uv)).rgb;
}

float3 LoadSceneColor(uint2 uv)
{
    return LOAD_TEXTURE2D_X(_CameraOpaqueTexture, uv).rgb;
}
#endif

我们在使用的时候就很简单的，只需要在shader里面引入相应的hlsl文件就可以实现相应的贴图的获取，记住，屏幕颜色贴图和屏幕深度贴图再urp里面需要手动开启，不管在配置项还是相机上面。

如何使用？
那就简单多了，先引入一下：

#include "Packages/com.unity.render-pipelines.universal/ShaderLibrary/DeclareOpaqueTexture.hlsl"
#include "Packages/com.unity.render-pipelines.universal/ShaderLibrary/DeclareDepthTexture.hlsl"
#include "Packages/com.unity.render-pipelines.universal/ShaderLibrary/DeclareNormalsTexture.hlsl"

计算出屏幕uv：

half2 screenUV = input.positionNDC.xy / input.positionNDC.w;

拿着屏幕uv去获取深度就行了

real depth = SampleSceneDepth(screenUV);

记住，这个深度不是线性的，可以去我上面带链接的那篇去看。

从深度纹理重构世界空间坐标

这一段直接抄官方的就行了，安全，高效
https://docs.unity3d.com/Packages/com.unity.render-pipelines.universal@10.5/manual/writing-shaders-urp-reconstruct-world-position.html

下面我也列出来相应的代码

    //获取屏幕uv
    half2 screenUV = input.positionNDC.xy / input.positionNDC.w;

    //获取深度
    #if UNITY_REVERSED_Z
        real depth = SampleSceneDepth(screenUV);
    #else
        // Adjust Z to match NDC for OpenGL ([-1, 1]) 意思就行 opengl的不一样，不是0-1 而是-1到1
        real depth = lerp(UNITY_NEAR_CLIP_VALUE, 1, SampleSceneDepth(screenUV));
    #endif

    // 使用内置的方法去获取世界空间坐标
    float3 worldPos = ComputeWorldSpacePosition(screenUV, depth, UNITY_MATRIX_I_VP);

应用：
那这个有什么用处呢，比如深度，我可以在水面上面去获取和水底的位置，来得出一个大概的水的深浅的效果，

比如这种

颜色贴图我可以做半透明物体后面扰动的效果等。
法向呢，可以做屏幕空间反射。