Unity Shader入门精要笔记（三）

Unity Shader 入门

Shader "Custom/C5_SimShader"
{
    SubShader
    {
        Pass {
            CGPROGRAM
            
            #pragma vertex vert   
            #pragma fragment frag

            float4 vert(float4 v : POSITION) : SV_POSITION {
                return UnityObjectToClipPos (v);
            }
            float4 frag() : SV_Target {
                return fixed4(1.0,1.0,1.0,1.0);
            } 

            ENDCG
        }
    }
    FallBack "Diffuse"
}

POSITION、SV_POSITION：是Cg/HLSL的语义，不可省略。这些语义将告诉系统需要哪些输入值，以及输出的是什么。这里POSITION将告诉Unity，把模型的顶点坐标填充到输入参数v中，SV_POSITION将告诉Unity，顶点着色器的输出是裁剪空间中的顶点坐标。如果没有这些语义来限制输入和输出参数的话，渲染器就完全不知道用户的输入输出是什么，会得到错误的效果。

SV_Target：HLSL的一个系统语义，等同于告诉渲染器，把用户的输出颜色存储到一个渲染目标（render target）中，这里将输出到默认的帧缓存中。片元着色器输出的颜色的每个分量范围在[0,1]

顶点着色器和片元着色器通信

Shader "Custom/C5_SimShader"
{
		Properties {
        _Color("Color Tint", Color) = (1.0,1.0,1.0,1.0)
    }
    SubShader
    {
        Pass {
            CGPROGRAM

            #pragma vertex vert
            #pragma fragment frag
            
            //在Cg代码种，需要定义一个与属性名称和类型都匹配的变量
            fixed4 _Color;

            //把数据从应用阶段传递到顶点着色器中
            struct a2v {
                //用模型空间的顶点坐标填充vertex变量
                float4 vertex : POSITION;
                //用模型空间的法线方向填充normal变量
                float3 normal : NORMAL;
                //用模型空间的第一套纹理填充texcoord变量
                float4 texcoord: TEXCOORD0;
            };
            //定义顶点着色器的输出
            struct v2f {
                //pos里包含了顶点在裁剪空间中的位置信息
                float4 pos : SV_POSITION;
                //用于存储颜色信息
                fixed3 color : COLOR0;
            };

            v2f vert(a2v v) {
                v2f o;
                o.pos = UnityObjectToClipPos (v.vertex); //使用v.vertex 来访问模型空间的顶点坐标
                //v.normal 包含了顶点的法线方向，其分量范围在[-1.0,1.0]
                //下面的代码把分量范围映射到了[0.0, 1.0]
                //存储到o.color中传递给片元着色器
                o.color = v.normal * 0.5 + fixed3(0.5,0.5,0.5);
                return o;
            }

            fixed4 frag(v2f i) : SV_Target {
                //将插值后的i.color显示到屏幕上
                fixed3 c = i.color;
                c *= _Color.rgb;
                return fixed4(c, 1.0);
            } 

            ENDCG
        }
    }
    FallBack "Diffuse"
}

顶点着色器是逐顶点调用的，片元着色器是逐片元调用的。片元着色器中的输入实际上是把顶点着色器的输出进行插值后得到的结果。

Unity支持的语义

从应用阶段传递模型数据给顶点着色器时

语义	描述
POSITION	模型空间中的顶点位置，通常时float4类型
NORMAL	顶点法线，通常时float3类型
TANGENT	顶点切线，通常时float4类型
TEXCOORDn	该顶点的纹理坐标，TEXCOORD0表示第一组纹理坐标
COLOR	顶点颜色，通常时fixed4或float4类型

从顶点着色器传递数据给片元着色器时

语义	描述
SV_POSITION	裁剪空间中的顶点坐标，结构体中必须包含一个用该语义修饰的变量。
COLOR0	通常用于输出第一组顶点颜色，但不是必需的
COLOR1	通常用于输出第二组顶点颜色，但不是必需的
TEXCOORD0~TEXCOORD7	通常用于输出纹理坐标，但不是必需的

​ 除了SV_POSITION是有特别含义外，其他语义对变量的含义没有明确要求，我们可以存储任意值到这些语义描述变量中。通常我们需要把一些自定义的数据从顶点着色器传递到片元着色器，一般选用TEXCOORD0。

片元着色器输出时

语义	描述
SV_Target	输出值将会存储到渲染目标(render target)中。等同于DirectX9中的COLOR语义