基于Unity2021的URP的RenderFeature进行Outline内容的手写Shader补充

ttod_qzstudio

已于 2022-07-16 17:36:37 修改

阅读量1k

点赞数 1

分类专栏： Unity Shader 文章标签： unity 游戏引擎

于 2022-07-08 16:06:00 首次发布

本文链接：https://blog.csdn.net/ttod/article/details/125680230

版权

Unity 同时被 2 个专栏收录

117 篇文章 4 订阅

订阅专栏

Shader

37 篇文章 3 订阅

订阅专栏

基于Unity2021的URP的RenderFeature进行Outline的另一种方法里面使用的Shader是基于Shader Graph开发的。但是我一直想把这里面给的两个shader替换成手写代码的，经过两天断断续续的编写，算是走通了，希望以后能够对手写URP的shader越来越熟悉。

首先是ViewSpaceNormal这个shader的代码：

Shader "URP/ViewSpaceNormal"
{
	SubShader
	{
		Pass
		{
			HLSLPROGRAM
			#pragma vertex vert
			#pragma fragment frag

			#include "Packages/com.unity.render-pipelines.universal/ShaderLibrary/Core.hlsl"

			struct Attributes
			{
				float3 positionOS : POSITION;
				float3 normal:NORMAL;
			};

			struct Varyings
			{
				float4 positionCS : SV_POSITION;
				float3 normal:COLOR0;
			};

			Varyings vert(Attributes v)
			{
				Varyings o = (Varyings)0;
				o.positionCS = TransformObjectToHClip(v.positionOS);
				o.normal = (TransformWorldToViewDir(TransformObjectToWorldDir(v.normal)) + float3(1,1,1)) * 0.5;
				//o.normal = (TransformObjectToWorldDir(v.normal) + float3(1, 1, 1)) * 0.5;
				return o;
			}

			half4 frag(Varyings i) : SV_TARGET
			{
				return half4(i.normal,1);
			}
			ENDHLSL
		}
	}
		FallBack "Hidden/Shader Graph/FallbackError"
}

其次是ViewSpaceOutline这个shader的代码：

Shader "URP/ViewSpaceOutline"
{
    Properties
    {
        _Color("Color(RGB)",Color) = (1,1,1,1)
        _MainTex("MainTex",2D) = "gary"{}
        _LineWidth("Line Width",Float) = 1
        _AlphaMulti("Alpha Multi",Float) = 1
    }

    SubShader
    {
        Pass
        {
			ZWrite Off

            Blend SrcAlpha OneMinusSrcAlpha

            HLSLPROGRAM
            #pragma vertex vert
            #pragma fragment frag

            #include "Packages/com.unity.render-pipelines.universal/ShaderLibrary/Core.hlsl"

            CBUFFER_START(UnityPerMaterial)
            half4 _Color; 
            half _LineWidth;
            half _AlphaMulti;
            CBUFFER_END

            TEXTURE2D(_MainTex);
            float4 _MainTex_ST;

            #define smp SamplerState_Point_Repeat
            SAMPLER(smp);

            struct Attributes
            {
                float3 positionOS : POSITION;
                float2 uv :TEXCOORD0;
            };

            struct Varyings
            {
                float4 positionCS : SV_POSITION;
                float2 uv :TEXCOORD0;
            };

            Varyings vert(Attributes v)
            {
                Varyings o = (Varyings)0;
                o.uv = TRANSFORM_TEX(v.uv,_MainTex);
                o.positionCS = TransformObjectToHClip(v.positionOS);
                return o;
            }

            half4 frag(Varyings i) : SV_TARGET
            {
                half xOffset = 1.0 / _ScreenParams.x * _LineWidth;
                half yOffset = 1.0 / _ScreenParams.y * _LineWidth;

                half2 UVTR = i.uv + half2(xOffset, yOffset);
                half2 UVBL = i.uv - half2(xOffset, yOffset);
                half2 UVTL = i.uv + half2(-xOffset, yOffset);
                half2 UVBR = i.uv + half2(xOffset, -yOffset);

                half4 mainTexTR = SAMPLE_TEXTURE2D(_MainTex, smp, UVTR);
                half4 mainTexBL = SAMPLE_TEXTURE2D(_MainTex, smp, UVBL);
                half4 mainTexTL = SAMPLE_TEXTURE2D(_MainTex, smp, UVTL);
                half4 mainTexBR = SAMPLE_TEXTURE2D(_MainTex, smp, UVBR);

                half EdgeIntensity = dot((mainTexTR.xyz - mainTexBL.xyz), (mainTexTR.xyz - mainTexBL.xyz)) + dot((mainTexTL.xyz - mainTexBR.xyz), (mainTexTL.xyz - mainTexBR.xyz));
                half alpha = EdgeIntensity * _AlphaMulti;

                return half4(_Color.xyz, alpha);
            }
            ENDHLSL
        }
    }
        FallBack "Hidden/Shader Graph/FallbackError"
}

注意：第二个Shader里面的ZWrite Off是必须的，否则透明物体渲染不出来。

其实代码里面还有些地方自己也不是太理解，只是根据模板套出来的东西，希望以后越写越明白。