UnityShader实例04:遮挡透明材质

遮挡透明材质

在3D游戏中,经常会出现控制的角色被房子或者墙壁之类的挡住,一些游戏会把挡住角色的物体透明化显示(这个应该需要脚本配合shader实现,因此不在本文讨论范围),如藏地传奇;而一些游戏会做一些特殊效果把角色被挡住的部分显示出来,如火炬之光这样(如下图),下面就用shader实现这一效果:



shader实现原理:


分析上图的效果,角色被前面墙体挡住的部分显示的类似xray效果(代码就直接从前面拿了,哈哈),没被挡住的部分显示贴图的正常效果,因此可以知道这个shader需要两个pass来实现。其中一个pass正常显示贴图,另外一个pass实现xray效果。当然不止这么简单,要实现上图的效果还需要Ztest,Zwrite,以及渲染队列等知识。

准备知识:


Rendering Order渲染队列


渲染队列,从字面的意思理解就是渲染的顺序,即对象渲染谁先谁后,如图你画画的时候,如果画画的时候每一笔的顺序一样,如果第一笔画红色,后面一笔画黑色,最终黑色会把红色覆盖掉。Unity里面我们可以通过SubShader Tags中的Queue Tag控制,unity提供了一些内置的渲染队列:

渲染队列渲染队列描述渲染队列值
Background这个队列被最先渲染。它被用于skyboxes等。1000
Geometry这是默认的渲染队列。它被用于绝大多数对象。不透明几何体使用该队列。2000
AlphaTest通道检查的几何体使用该队列。它和Geometry队列不同,对于在所有立体物体绘制后渲染的通道检查的对象,它更有效。2450
Transparent该渲染队列在Geometry和AlphaTest队列后被渲染。任何通道混合的(也就是说,那些不写入深度缓存的Shaders)对象使用该队列,例如玻璃和粒子效果。3000
Overlay该渲染队列是为覆盖物效果服务的。任何最后被渲染的对象使用该队列,例如镜头光晕。4000

在关闭深度测的情况下,可以看出处于background队列的物体会最先被渲染,如果没有深度测试,他将现实画面的最后面,如果前面geometry队列的物体,就会优先显示geometry的物体,我想一般都会有这个问题:如果属于同一个渲染队列该怎么决定谁先谁后呢,所以unity还有其他的方式决定物体能根据实际深度正常显示,如深度测试。可以这么说,渲染队列相当于把物体进行了大致的排序,如果需要精确的话,还需要其他的操作。

Depth Testing深度测试


Depth Testing:深度测试,也叫深度缓冲。用来确定物体的遮挡关系。只有最靠近观察者的物体会被绘制。深度即Z,该值越小表示离观察者越近,该值越大表示离观察者越远。


Shader里默认有如下代码
ZWrite On
ZTest LEqual

意思即使Shader里没有写任何关于Depth Testing的代码,Shader也会执行深度测试。

ZWrite:是否此物体的像素深度会被记录(默认记录),
ZWrite On  深度记录(默认On),此对象的深度会根据实际情况进行记录。
ZWrite Off  不记录此深度,通常用于半透明物体,

ZTest Less | Greater | LEqual | GEqual | Equal | NotEqual | Always

默认是 LEqual。 即当深度小于或者等于 深度最小值时,渲染物体,即渲染最近的物体。


   根据上面的知识我们可以整理个思路,在unity默认情况下物体深度缓存都是打开的,除了半透明物体外,大部分物体都会根据实际情况渲染,显示正确的遮挡关系,即离观察者越近的物体会挡住离观察较远的物体。因此要实现本文的效果,使的被挡住的部分现实出来,我们需要关闭深度缓存(不是关闭ztest),自己控制渲染队列来使被遮挡物体的部分显示到遮挡物的前面来,具体就是在shader中,首先将subshader Tag改成如下形式:
Tags { "Queue" = "Geometry+500" "RenderType"="Opaque" }  

   这样物体将在不透明物体(墙壁)之后渲染,同时定义两个pass,一个输出xray效果,一个输出贴图颜色,将第一个pass设置成Zwitre off,关闭深度缓存,并将Ztest 参数设置成Greater,第二个pass使用默认设置 即Zwrite on , Ztest LEqual。

   那么执行的时候,如果对象没有被墙壁挡住时,先执行的pass输出xray效果,后执行的pass输出了贴图颜色,最终xray被替换成正常贴图颜色。而如果对象被墙壁遮挡时,第一个pass不将它的深度值写入【深度缓存】,此时Ztest参数为Greater ,显然当前pass的深度值("Geometry+500")是大于墙壁深度值的,所以最终显示了当前pass的颜色,第二个pass是默认设置,并写入了【深度缓存】,深度值是小于墙壁深度值的,根据ztest LEqual第二个pass的贴图颜色被剔除,最终的颜色就会根据blend公式,显示第一个pass和墙壁颜色的混合结果:

Blend  SrcAlpha   One

最终颜色=xray效果RGB*xray效果Alpha+墙壁RGB*1


对于这个效果可以总结出个简单的代码模式:

Shader "…………"   
{  
    Properties   
    {   
        ……………………
    }  
      
    SubShader   
    {  
        
        LOD 300  
//更改渲染队列,调整绘制顺序,使物体绘制到其他物体之前
  	Tags { "Queue" = "Geometry+500" "RenderType"="Opaque" }
//第一个pass输出xray部分,两个pass的顺序不能改变
Pass
	{
		Blend SrcAlpha One//设置颜色混合结果
		ZWrite off  //关闭深度缓存,重写对象的绘制顺序
		ztest greater//当深度大于最小值时,渲染对象
		…………………………
	}
//第二个pass正常输出贴图颜色
        pass  
        {  
            	ZTest LEqual//缺省值,可以不写,当深度小于或者等于深度最小值时,渲染对象,即渲染最近的物体。   
            	………………………… 
    	}   
}





VF版本代码01:

Shader "PengLu/OccTransVF"   
{  
    Properties   
    {   
        _MainTex ("Base (RGB)", 2D) = "white" {}  
        _RimColor("RimColor",Color) = (0,1,1,1)
		_RimPower ("Rim Power", Range(0.1,8.0)) = 1.0
    }  
      
    SubShader   
    {  
        
        LOD 300  
  		Tags { "Queue" = "Geometry+500" "RenderType"="Opaque" } 
        Pass
		{
			Blend SrcAlpha One
			ZWrite off
			Lighting off

			ztest greater

			CGPROGRAM
			#pragma vertex vert
			#pragma fragment frag
			#include "UnityCG.cginc"

			float4 _RimColor;
			float _RimPower;
			
			struct appdata_t {
				float4 vertex : POSITION;
				float2 texcoord : TEXCOORD0;
				float4 color:COLOR;
				float4 normal:NORMAL;
			};

			struct v2f {
				float4  pos : SV_POSITION;
				float4	color:COLOR;
			} ;
			v2f vert (appdata_t v)
			{
				v2f o;
				o.pos = mul(UNITY_MATRIX_MVP,v.vertex);
				float3 viewDir = normalize(ObjSpaceViewDir(v.vertex));
                float rim = 1 - saturate(dot(viewDir,v.normal ));
                o.color = _RimColor*pow(rim,_RimPower);
				return o;
			}
			float4 frag (v2f i) : COLOR
			{
				return i.color; 
			}
			ENDCG
		}
        pass  
        {  
            ZWrite on
            ZTest less 

            CGPROGRAM  
            #pragma vertex vert  
            #pragma fragment frag  
            sampler2D _MainTex;  
            float4 _MainTex_ST;
              
            struct appdata {  
                float4 vertex : POSITION;  
                float2 texcoord : TEXCOORD0;  
            };  
            
            struct v2f  {  
                float4 pos : POSITION;  
                float2 uv : TEXCOORD0;  
            };  
            
            v2f vert (appdata v) 
            {  
                v2f o;  
                o.pos = mul(UNITY_MATRIX_MVP,v.vertex);  
                o.uv = v.texcoord;  
                return o;  
            } 
             
            float4 frag (v2f i) : COLOR  
            {  
                float4 texCol = tex2D(_MainTex, i.uv);  
                return texCol;  
            }  
            ENDCG  
        }  
    } 
    FallBack "Diffuse" 
}  


VF版本代码01效果




©️2020 CSDN 皮肤主题: 大白 设计师:CSDN官方博客 返回首页