一、定点动画的一些注意事项
上节说的取消批处理"DisableBatching"="True"
,是因为我们需要操作模型空间的信息,如果进行批处理,那么会合并模型以至于我们丢失模型的模型空间。所以之后如果要在顶点着色器中操作相关模型空间时,需要记得考虑是否需要关闭批处理。
取消批处理会增加Draw Call,带来一定的性能下降,所以我们需要尽可能地避免使用模型空间下的一些绝对位置来进行计算。
广告牌的例子中,为了避免显示使用模型空间的中心来作为锚点,我们可以利用顶点颜色来存储每个顶点到锚点的距离值,这种做法商业游戏中常见。
二、实现顶点动画的阴影效果
我们如果继续使用之前的内置的Diffuse包含的ShadowCaster Pass来渲染,不会得到正常的效果,因为这个Pass没有进行相关的顶点动画,Untiy会按照原来的顶点位置进行计算阴影。
这时,我们就需要自己定义一个ShadowCaster Pass,在这个Pass中我们需要进行同样的顶点变化过程。
和前面一样,如果涉及半透明物体,那么由于Fallback是Transparent/VertexLit,而这其中没有定义ShadowCaster Pass,所以此时不会有阴影。
Shader "Unity Shaders Book/Chapter 11/Vertex Animation With Shadow" {
Properties {
_MainTex ("Main Tex", 2D) = "white" {}
_Color ("Color Tint", Color) = (1, 1, 1, 1)
_Magnitude ("Distortion Magnitude", Float) = 1
_Frequency ("Distortion Frequency", Float) = 1
_InvWaveLength ("Distortion Inverse Wave Length", Float) = 10
_Speed ("Speed", Float) = 0.5
}
SubShader {
// Need to disable batching because of the vertex animation
Tags {"DisableBatching"="True"}
Pass { //这个Pass就是之前河流那个
Tags { "LightMode"="ForwardBase" }
Cull Off
CGPROGRAM
#pragma vertex vert
#pragma fragment frag
#include "UnityCG.cginc"
sampler2D _MainTex;
float4 _MainTex_ST;
fixed4 _Color;
float _Magnitude;
float _Frequency;
float _InvWaveLength;
float _Speed;
struct a2v {
float4 vertex : POSITION;
float4 texcoord : TEXCOORD0;
};
struct v2f {
float4 pos : SV_POSITION;
float2 uv : TEXCOORD0;
};
v2f vert(a2v v) {
v2f o;
float4 offset;
offset.yzw = float3(0.0, 0.0, 0.0);
offset.x = sin(_Frequency * _Time.y + v.vertex.x * _InvWaveLength + v.vertex.y * _InvWaveLength + v.vertex.z * _InvWaveLength) * _Magnitude;
o.pos = UnityObjectToClipPos(v.vertex + offset);
o.uv = TRANSFORM_TEX(v.texcoord, _MainTex);
o.uv += float2(0.0, _Time.y * _Speed);
return o;
}
fixed4 frag(v2f i) : SV_Target {
fixed4 c = tex2D(_MainTex, i.uv);
c.rgb *= _Color.rgb;
return c;
}
ENDCG
}
// Pass to render object as a shadow caster
Pass { //这个Pass是我们新增的用于给顶点动画增加的ShadowCaster Pass
Tags { "LightMode" = "ShadowCaster" }
CGPROGRAM
#pragma vertex vert
#pragma fragment frag
#pragma multi_compile_shadowcaster
#include "UnityCG.cginc"
float _Magnitude;
float _Frequency;
float _InvWaveLength;
float _Speed;
struct v2f {
V2F_SHADOW_CASTER; //ShadowCaster Pass中的三剑客,用来定义阴影投射需要的一些变量
};
v2f vert(appdata_base v) {
v2f o;
float4 offset; //和上面Pass类似,先计算偏移
offset.yzw = float3(0.0, 0.0, 0.0);
offset.x = sin(_Frequency * _Time.y + v.vertex.x * _InvWaveLength + v.vertex.y * _InvWaveLength + v.vertex.z * _InvWaveLength) * _Magnitude;
v.vertex = v.vertex + offset; //直接进行对顶点位置的更新
TRANSFER_SHADOW_CASTER_NORMALOFFSET(o) //ShadowCaster Pass中的三剑客
return o;
}
fixed4 frag(v2f i) : SV_Target {
SHADOW_CASTER_FRAGMENT(i) //ShadowCaster Pass中的三剑客
}
ENDCG
}
}
FallBack "VertexLit"
}
需要注意一些变量设置:
这个阴影三剑客的TRANSFER_SHADOW_CASTER_NORMALOFFSET(o)
会使用:名称为v的输入结构体,v中要包含顶点位置v.vertex
,v.normal
信息,appdata_base
结构体包含了我们需要的顶点变量信息。