法线纹理能产生凹凸假象的原理:法线纹理存放着模型所有点的法线信息,光线在不同的凹凸情况下会产生阴影高光,产生一种模型也有了凹凸的假象,但从模型的边缘还是可以看出是平整的。
Shader "ShaderPath/NMShader"//shader的选择路径
{
Properties//该Shader可控的属性
{
_MainTex ("MainTex", 2D) = "white" {}//纹理贴图
_BumpTex ("BumpTex", 2D) = "white" {}//法线纹理贴图
_BumpScale ("BumpScale", Range(-1,1)) = 1 //凹凸程度
_DiffuseColor ("DiffuseColor",Color) = (1,1,1,1)//漫反射的主色调
_SpecularColor ("SpecularColor",Color) = (1,1,1,1)//高光反射的主色调
_Gloss ("Gloss",Range(1,100)) = 2 //光泽度(反光度) 控制高光区域的大小
}
SubShader//子着色器
{
// 以下均为默认值,详情可查看以往博客
Cull Back ZWrite On ZTest LEqual
Pass
{
//与ENDCG相照应,将CG代码包裹
CGPROGRAM
//顶点函数定义
#pragma vertex vert
//片元函数定义
#pragma fragment frag
//引入必要的Unity库 如下面的UnityObjectToClipPos 就是库中函数
#include "UnityCG.cginc"
//引入光照库 _LightColor0需要用
#include "Lighting.cginc"
struct appdata
{
float4 vertex : POSITION;//每个顶点结构体必须有的
float3 normal : NORMAL;//定义法线
float4 tangent :TANGENT;//定义切线
float4 texcoord : TEXCOORD0;//存储第一章纹理的坐标信息
};
struct v2f
{
float3 lightDir : TEXCOORD0;
float3 viewDir : TEXCOORD1;
float4 uv : TEXCOORD2;//用于存储纹理信息
float4 pos : SV_POSITION;//每个片元结构体必须有的
};
sampler2D _MainTex;
sampler2D _BumpTex;
float4 _MainTex_ST;//图片的(平铺和偏移系数)如果要使图片的Tilling和Offset生效就必须定义
float4 _BumpTex_ST;//图片的(平铺和偏移系数)如果要使图片的Tilling和Offset生效就必须定义
float _BumpScale;
fixed4 _DiffuseColor;
fixed4 _SpecularColor;
float _Gloss;
v2f vert (appdata v)
{
v2f o;
o.pos = UnityObjectToClipPos(v.vertex);//把顶点从模型空间转换到剪裁空间
o.uv.xy = TRANSFORM_TEX(v.texcoord, _MainTex);//使图片对应的_ST生效,这里就是_MainTex_ST
o.uv.zw = TRANSFORM_TEX(v.texcoord, _BumpTex);//使图片对应的_ST生效,这里就是_BumpTex_ST
//这里是UnityCG.cginc 库里面定义函数,利用normal和tangent生成对应的rotation矩阵(模型空间转到切线空间的变换矩阵)
//这也是在上面必须定义normal和tangent的原因
TANGENT_SPACE_ROTATION;
o.lightDir = mul(rotation,ObjSpaceLightDir(v.vertex));//将模型顶点的光照方向转到切线空间
o.viewDir = mul(rotation,ObjSpaceViewDir(v.vertex));//将模型顶点的视角方向转到切线空间
return o;
}
fixed4 frag (v2f i) : SV_Target//返回一个RGBA到模型上
{
fixed3 lightDir = normalize(i.lightDir);
fixed3 viewDir = normalize(i.viewDir);
fixed4 packedNormal = tex2D(_BumpTex,i.uv.zw);//采样_BumpTex里面的法线信息
//UnpackNormal英文含义就是 解压法线 将法线从颜色信息里面解压出来
//这里涉及到一个知识点 为什么法线贴图是蓝色调的
//法线贴图里面法线都是存储在切线空间里面的
//详细请看文末提到的博客
fixed3 tangentNormal = UnpackNormal(packedNormal);
//切线空间的法线是单位长度为1的,所以只要求出其中两个就可以利用长度求出另一个值
tangentNormal.xy *= _BumpScale;
tangentNormal.z = sqrt(1-saturate(dot(tangentNormal.xy,tangentNormal.xy)));
fixed3 albedo = tex2D(_MainTex,i.uv.xy).rgb * _DiffuseColor;//采样主贴图的纹理颜色
//半罗伯特反射
fixed3 diffuse = _LightColor0.rgb * albedo * (1+dot(lightDir,tangentNormal))/2;
//Blinn-Phong模型高光
fixed3 halfView = normalize(lightDir + viewDir);
fixed3 specular = _LightColor0.rgb * _SpecularColor * pow(saturate(dot(tangentNormal,halfView)),_Gloss);
return fixed4(diffuse + specular,1);
}
ENDCG
}
}
}