Shader——对图片进行剪切

对图片的四角进行剪切

Shader "Custom/Mask" {
	Properties {
		_MainTex ("Base (RGB), Alpha (A)", 2D) = "white" {}
		_Max ("Radius", Range(0,0.5)) = 0.5
	}
	SubShader 
	{
		LOD 100
		
		Tags
		{
			"Queue" = "Transparent"
			"IgnoreProjector" = "True"
			"RenderType" = "Transparent"
			"PreviewType" = "Plane"
		}
		
		ColorMask RGB
		Blend SrcAlpha OneMinusSrcAlpha

		Pass
		{
			CGPROGRAM
				#pragma target 3.0
				#pragma vertex vert
				#pragma fragment frag
				#include "UnityCG.cginc"

				float _Max;

				sampler2D _MainTex;
				half4 _MainTex_ST;
				sampler2D _ClipTex;
				struct appdata_t
				{
					float4 vertex : POSITION;
					float2 texcoord : TEXCOORD0;
					fixed4 color : COLOR;
				};
				struct v2f
				{
					float4 vertex : SV_POSITION;
					half2 texcoord : TEXCOORD0;
					fixed4 color : COLOR;
				};
				v2f vert (appdata_t v)
				{
					v2f o;
					o.vertex = UnityObjectToClipPos(v.vertex);
					o.texcoord = TRANSFORM_TEX(v.texcoord, _MainTex);
                    o.color = v.color;
					#ifdef UNITY_HALF_TEXEL_OFFSET
					o.vertex.xy += (_ScreenParams.zw-1.0)*float2(-1,1);
					#endif
					return o;
				}
				//裁剪的计算逻辑
				float calculate(float2 uv)
				{
					float c;
					float2 r;
					float mask;
					if(_Max < 0.5)
					{
						//重新校对中心点
						r.x = (uv.x < _Max) ?  uv.x - _Max : ((uv.x > 1 - _Max) ? uv.x + _Max - 1 : 0);
						r.y = (uv.y < _Max) ?  uv.y - _Max : ((uv.y > 1 - _Max) ? uv.y + _Max - 1 : 0);
						mask = _Max;
					}
					else
					{
						//
						r.x = abs(0.5 - uv.x);		//abs取绝对值的函数
						r.y = abs(0.5 - uv.y);
						
						mask = 1 - _Max;
					}
					//计算向量长度
					float rr = length(r);		//length取向量到零点的长度
					//对超出部分进行裁剪
					if(rr > mask)
					{
						c = 0;
					}
					else
					{
						c = 1;
					}
					return c;
				}
				fixed4 frag (v2f i) : COLOR
				{
					float4 c = i.color;
					c.a = calculate(i.texcoord.xy);
					fixed4 col = tex2D(_MainTex, i.texcoord) * c;
					clip (col.a - 0.01);
					return col;
			}
			ENDCG
		}
	}
}