曲面细分着色器与几何着色器

已于 2022-03-24 14:34:52 修改
阅读量919 收藏 7
点赞数
分类专栏： TA 文章标签： shader
于 2022-03-23 23:11:04 首次发布
版权声明：本文为博主原创文章，遵循 CC 4.0 BY-SA 版权协议，转载请附上原文出处链接和本声明。
本文链接：https://blog.csdn.net/weixin_51327051/article/details/123697867
版权

着色器执行顺序

顶点着色器—>曲面细分着色器—>几何着色器—>片元着色器

曲面细分着色器细分后的顶点属于重心空间。

曲面细分着色器

应用：海浪、雪地等

与置换贴图结合：只使用法线贴图模型的边缘凹凸感差，使用曲面细分着色器增强模型边缘的凹凸感

输入Patch,可以看成是多个顶点的集合，包含每个顶点的属性，可以指定一个Patch包含的顶点数以及自己的属性
功能将图元细分(可以是三角形，矩形等)
输出细分后的顶点

工作流程：

●HULL Shader
        1.决定细分的数量(设定Tessellation factor以及Inside Tessellationfactor)
        2.对输入的Patch参数进行改变(如果需要)
●Tessellation Primitive Generation
        进行细分操作
●Domain Shader
        对细分后的点进行处理，从重心空间(Barycentric coordinate system)转换到屏幕空间

参数解析：

HULL Shader：

●Tessellation Factor：决定将一条边分成几部分
        equal_ Spacing        等分
        fractional_ even_ spacing         向上取偶数，最小值是2
        fractional odd_ spacing             向上取奇数，最小值是1
●Inner Tessellation Factor：【3等分】将三角形每条边3等分，并通过等分点做边的垂线，交点为新的内部三角形顶点，直到不可再等分。

 在使用曲面细分着色器前需要定义shader：

Shader "Unlit/TessShader"
{
    Properties
    {
        _TessellationUniform("TessellationUniform",Range(1,64)) = 1
    }
    SubShader
    {
        Tags { "RenderType"="Opaque" }
        LOD 100
        Pass
        {
            CGPROGRAM
            //定义2个函数 hull domain
            #pragma hull hullProgram
            #pragma domain ds
           
            #pragma vertex tessvert
            #pragma fragment frag

            #include "UnityCG.cginc"
            //引入曲面细分的头文件
            #include "Tessellation.cginc" 

            #pragma target 5.0
            
            struct VertexInput
            {
                float4 vertex : POSITION;
                float2 uv : TEXCOORD0;
                float3 normal : NORMAL;
                float4 tangent : TANGENT;
            };

            struct VertexOutput
            {
                float2 uv : TEXCOORD0;
                float4 vertex : SV_POSITION;
                float3 normal : NORMAL;
                float4 tangent : TANGENT;
            };

            VertexOutput vert (VertexInput v)
            //这个函数应用在domain函数中，用来空间转换的函数
            {
                VertexOutput o;
                o.vertex = UnityObjectToClipPos(v.vertex);
                o.uv = v.uv;
                o.tangent = v.tangent;
                o.normal = v.normal;
                return o;
            }

            //有些硬件不支持曲面细分着色器，定义了该宏就能够在不支持的硬件上不会变粉，也不会报错
            #ifdef UNITY_CAN_COMPILE_TESSELLATION
                //顶点着色器结构的定义
                struct TessVertex{
                    float4 vertex : INTERNALTESSPOS;
                    float3 normal : NORMAL;
                    float4 tangent : TANGENT;
                    float2 uv : TEXCOORD0;
                };

                struct OutputPatchConstant { 
                    //不同的图元，该结构会有所不同
                    //该部分用于Hull Shader里面
                    //定义了patch的属性
                    //Tessellation Factor和Inner Tessellation Factor
                    float edge[3] : SV_TESSFACTOR;
                    float inside  : SV_INSIDETESSFACTOR;
                };

                TessVertex tessvert (VertexInput v){
                    //顶点着色器函数
                    TessVertex o;
                    o.vertex  = v.vertex;
                    o.normal  = v.normal;
                    o.tangent = v.tangent;
                    o.uv      = v.uv;
                    return o;
                }

                float _TessellationUniform;
                OutputPatchConstant hsconst (InputPatch<TessVertex,3> patch){
                    //定义曲面细分的参数
                    OutputPatchConstant o;
                    o.edge[0] = _TessellationUniform;
                    o.edge[1] = _TessellationUniform;
                    o.edge[2] = _TessellationUniform;
                    o.inside  = _TessellationUniform;
                    return o;
                }

                [UNITY_domain("tri")]//确定图元，quad,triangle等
                [UNITY_partitioning("fractional_odd")]//拆分edge的规则，equal_spacing,fractional_odd,fractional_even
                [UNITY_outputtopology("triangle_cw")]
                [UNITY_patchconstantfunc("hsconst")]//一个patch一共有三个点，但是这三个点都共用这个函数
                [UNITY_outputcontrolpoints(3)]      //不同的图元会对应不同的控制点
              
                TessVertex hullProgram (InputPatch<TessVertex,3> patch,uint id : SV_OutputControlPointID){
                    //定义hullshaderV函数
                    return patch[id];
                }

                [UNITY_domain("tri")]//同样需要定义图元
                VertexOutput ds (OutputPatchConstant tessFactors, const OutputPatch<TessVertex,3>patch,float3 bary :SV_DOMAINLOCATION)
                //bary:重心坐标
                {
                    VertexInput v;
                    v.vertex = patch[0].vertex*bary.x + patch[1].vertex*bary.y + patch[2].vertex*bary.z;
			        v.tangent = patch[0].tangent*bary.x + patch[1].tangent*bary.y + patch[2].tangent*bary.z;
			        v.normal = patch[0].normal*bary.x + patch[1].normal*bary.y + patch[2].normal*bary.z;
			        v.uv = patch[0].uv*bary.x + patch[1].uv*bary.y + patch[2].uv*bary.z;

                    VertexOutput o = vert (v);
                    return o;
                }
            #endif

            float4 frag (VertexOutput i) : SV_Target
            {

                return float4(1.0,1.0,1.0,1.0);
            }
            ENDCG
        }
    }
    Fallback "Diffuse"
}

与置换图结合

Shader "Unlit/Tess_Diss_Shader"
{
    Properties
    {
        _MainTex("MainTex",2D) = "white"{}
        _DisplacementMap("_DisplacementMap",2D)="gray"{}
        _DisplacementStrength("DisplacementStrength",Range(0,1)) = 0
        _Smoothness("Smoothness",Range(0,5))=0.5
        _TessellationUniform("TessellationUniform",Range(1,64)) = 1
    }
    SubShader
    {
        Tags { "RenderType"="Opaque" 
               "LightMode"="ForwardBase"}
        LOD 100
        Pass
        {
            CGPROGRAM
            //定义2个函数 hull domain
            #pragma hull hullProgram
            #pragma domain ds
           
            #pragma vertex tessvert
            #pragma fragment frag

            #include "UnityCG.cginc"
            #include "Lighting.cginc"
            //引入曲面细分的头文件
            #include "Tessellation.cginc" 

            #pragma target 5.0
            float _TessellationUniform;
            sampler2D _MainTex;
            float4 _MainTex_ST;

            sampler2D _DisplacementMap;
            float4 _DisplacementMap_ST;
            float _DisplacementStrength;
            float _Smoothness;

            struct VertexInput
            {
                float4 vertex : POSITION;
                float2 uv : TEXCOORD0;
                float3 normal : NORMAL;
                float4 tangent : TANGENT;
            };

            struct VertexOutput
            {
                float2 uv : TEXCOORD0;
                float4 pos : SV_POSITION;
                float4 worldPos:TEXCOORD1;
                half3 tspace0 :TEXCOORD2;
                half3 tspace1 :TEXCOORD3;
                half3 tspace2 :TEXCOORD4;
            };

            VertexOutput vert (VertexInput v)
            //这个函数应用在domain函数中，用来空间转换的函数
            {
                VertexOutput o;
                o.uv = TRANSFORM_TEX(v.uv,_MainTex);
                //Displacement
                //由于并不是在Fragnent shader中读取图片，GPU无法获取mipmap信息，因此需要使用tex2Dlod来读取图片，使用第四坐标作为mipmap的level，这里取了0
                float Displacement = tex2Dlod(_DisplacementMap,float4(o.uv.xy,0.0,0.0)).g;
                Displacement = (Displacement-0.5)*_DisplacementStrength;
                v.normal = normalize(v.normal);
                v.vertex.xyz += v.normal * Displacement;

                o.pos = UnityObjectToClipPos(v.vertex);
                o.worldPos = mul(unity_ObjectToWorld, v.vertex);

                //计算切线空间转换矩阵
                half3 vNormal = UnityObjectToWorldNormal(v.normal);
                half3 vTangent = UnityObjectToWorldDir(v.tangent.xyz);
                //compute bitangent from cross product of normal and tangent
                half tangentSign = v.tangent.w * unity_WorldTransformParams.w;
                half3 vBitangent = cross(vNormal,vTangent)*tangentSign;
                //output the tangent space matrix
                o.tspace0 = half3(vTangent.x,vBitangent.x,vNormal.x);
                o.tspace1 = half3(vTangent.y,vBitangent.y,vNormal.y);
                o.tspace2 = half3(vTangent.z,vBitangent.z,vNormal.z);
                return o;
            }

            //有些硬件不支持曲面细分着色器，定义了该宏就能够在不支持的硬件上不会变粉，也不会报错
            #ifdef UNITY_CAN_COMPILE_TESSELLATION
                //顶点着色器结构的定义
                struct TessVertex{
                    float4 vertex : INTERNALTESSPOS;
                    float3 normal : NORMAL;
                    float4 tangent : TANGENT;
                    float2 uv : TEXCOORD0;
                };

                struct OutputPatchConstant { 
                    //不同的图元，该结构会有所不同
                    //该部分用于Hull Shader里面
                    //定义了patch的属性
                    //Tessellation Factor和Inner Tessellation Factor
                    float edge[3] : SV_TESSFACTOR;
                    float inside  : SV_INSIDETESSFACTOR;
                };

                TessVertex tessvert (VertexInput v){
                    //顶点着色器函数
                    TessVertex o;
                    o.vertex  = v.vertex;
                    o.normal  = v.normal;
                    o.tangent = v.tangent;
                    o.uv      = v.uv;
                    return o;
                }

                //float _TessellationUniform;
                OutputPatchConstant hsconst (InputPatch<TessVertex,3> patch){
                    //定义曲面细分的参数
                    OutputPatchConstant o;
                    o.edge[0] = _TessellationUniform;
                    o.edge[1] = _TessellationUniform;
                    o.edge[2] = _TessellationUniform;
                    o.inside  = _TessellationUniform;
                    return o;
                }

                [UNITY_domain("tri")]//确定图元，quad,triangle等
                [UNITY_partitioning("fractional_odd")]//拆分edge的规则，equal_spacing,fractional_odd,fractional_even
                [UNITY_outputtopology("triangle_cw")]
                [UNITY_patchconstantfunc("hsconst")]//一个patch一共有三个点，但是这三个点都共用这个函数
                [UNITY_outputcontrolpoints(3)]      //不同的图元会对应不同的控制点
              
                TessVertex hullProgram (InputPatch<TessVertex,3> patch,uint id : SV_OutputControlPointID){
                    //定义hullshaderV函数
                    return patch[id];
                }

                [UNITY_domain("tri")]//同样需要定义图元
                VertexOutput ds (OutputPatchConstant tessFactors, const OutputPatch<TessVertex,3>patch,float3 bary :SV_DOMAINLOCATION)
                //bary:重心坐标
                {
                    VertexInput v;
                    v.vertex = patch[0].vertex*bary.x + patch[1].vertex*bary.y + patch[2].vertex*bary.z;
			        v.tangent = patch[0].tangent*bary.x + patch[1].tangent*bary.y + patch[2].tangent*bary.z;
			        v.normal = patch[0].normal*bary.x + patch[1].normal*bary.y + patch[2].normal*bary.z;
			        v.uv = patch[0].uv*bary.x + patch[1].uv*bary.y + patch[2].uv*bary.z;

                    VertexOutput o = vert (v);
                    return o;
                }
            #endif

            float4 frag (VertexOutput i) : SV_Target
            {
                float3 lightDir =_WorldSpaceLightPos0.xyz;
                float3 tnormal = UnpackNormal (tex2D (_DisplacementMap, i.uv));
                half3 worldNormal;
                worldNormal.x=dot(i.tspace0,tnormal);
                worldNormal.y= dot (i.tspace1, tnormal);
                worldNormal.z=dot (i.tspace2, tnormal);
                float3 albedo=tex2D (_MainTex, i.uv). rgb;
                float3 lightColor = _LightColor0.rgb;
                float3 diffuse = albedo * lightColor * DotClamped(lightDir,worldNormal);
                float3 viewDir = normalize (_WorldSpaceCameraPos. xyz-i. worldPos. xyz);
                float3 halfVector = normalize(lightDir + viewDir);
                float3 specular = albedo * pow (DotClamped (halfVector, worldNormal), _Smoothness * 100);
                float3 result = specular + diffuse;
                return float4(result, 1.0);

                return float4(result,1.0);
            }
            ENDCG
        }
    }
    Fallback "Diffuse"
}

使用顶点片元着色器实现https://mp.weixin.qq.com/s?__biz=MzIxMzgzMzQxOA==&mid=2247485821&idx=1&sn=b319cd540eee34f8a064270b9cb933e2&chksm=97b18ad8a0c603ce412bab0666aa57f57320bb009cf9af2c0ce76ac14b10fa8bbe77a564436e&scene=178&cur_album_id=1745807625885171715#rd 使用表面着色器实现https://zhuanlan.zhihu.com/p/141021857

几何着色器

应用：几何动画、草地生成（与曲面细分着色器结合，控制草的密度）

输入图元(三角形，矩形，线等)，根据图元的不同，shader中会出现对应不同数量的顶点
输出同样为图元，一个或多个，需要自己从顶点构建，顺序很重要同时需要定义最大输出的顶点数


几何着色器https://blog.csdn.net/sinat_25415095/article/details/111403397


无尽草地https://zhuanlan.zhihu.com/p/29632347

粒子和毛发效果https://blog.csdn.net/qq_36107199/article/details/88579359参考视频

参考大佬笔记

果冻喜之郎
关注
专栏目录
图形学进阶——曲面细分与几何着色器
whitebreeze的博客
07-04 3149
Tesselaation Shader & Geometry Shader 曲面细分着色与几何着色 百人计划学习地址：图形 3.3 曲面细分与几何着色器 大规模草渲染 一、曲面细分着色器的应用 可以不断细化一个锐利的几何体，将它变成球体 也可以不断细分一条直线，向曲线逼近 也可以与置换贴图结合： 二、几何着色器的应用 三、着色器的执行顺序 顶点着色器——》曲面细分着色器——》几何着色器——》片元着色器 注： Hull Shader 细分控制着色器 和 Domain Shader 细分计算着
Shader入门---曲面细分着色器和几何着色器
m0_56399931的博客
07-31 2281
Shader入门—曲面细分着色器和几何着色器 前记：学不可以停止-------------------------------mx 基础知识： 曲面细分着色器：可以将一个几何体细化为一个球体也能将一根直线无限向曲线逼近 使用曲面细分的好处：直接使用顶点数更多的模型会带来更高的性能消耗，曲面细分能根据规则来动态调整模型的复杂度，达到对应的效果 曲面细分着色器的输入输出： 输入：Patch,可以看成是多个顶点的集合，包含每个顶点的属性，可以指定一个Patch包含的顶点数以及自己的属性 功能：将图元细分（可以是
Unity细分曲面：打造极致细节的3D模型
最新发布
gitblog_00978的博客
09-15 1050
Unity细分曲面：打造极致细节的3D模型 unity-subdivision-surface Loop subdivision surface algorithm implementation in Unity. 项目地址: h...
Tessellation Shader（细分曲面着色器）
arag2009的学习专栏
07-22 7463
Tessellation Shader（细分曲面着色器） Tessellation Shader）是OpenGLES4.0引入的，处于顶点着色器阶段的下一个阶段，它是由ATI在2001年率先设计出来的。   细分曲面着色器 直到这个阶段，对于操作几何图元而言，只有顶点着色器对我们可用。尽管使用顶点着色器可以使用不少图形技术，不过顶点着色器也确实存在一些限
百人计划（图形）3.3曲面细分与几何着色器
qq_63133691的博客
05-29 274
曲面细分（TESS）是利用镶嵌化处理技术对网格中三角形进行细分，以此来增加物体表面上三角形数量，表现出更多的细节。
曲面细分着色器总结
木马人
04-28 693
先看unity下 Plane的曲面细分效果： 顶点数 由少到多的变化效果。 重点： 数据传输和处理 a2v, v2t, v2f 明白这三个数据的存储和赋值， 是理解曲面细分着色器的关键 代码中注释（最后会附上代码） （1）domain: patch 类型或者叫做模型图元的拓扑结构有效参数为tri,quad,isoline。tri表示三角面 （2）partitioning:指定曲面细分的拆分模式 integer:新的顶点只在细分因子为整数时进行添加或删除,细分因子的小数部分被忽略，这种情
百人计划（图形部分）曲面细分与几何着色器
WINDGRIN23313的博客
09-07 1163
https://space.bilibili.com/7398208?spm_id_from=333.788.b_765f7570696e666f.1 曲面细分着色器与几何着色器都是在顶点着色器之后，裁剪之前，其中曲面细分着色器在几何着色器之前，两个都是可选的着色器，并不是必须要写的，且曲面细分着色器目前在手机上基本上没应用，而几何着色器最常用的则是用来渲染草地； 曲面细分着色器（TESS） ...
从0开始的技术美术之路（十五）曲面细分与几何着色器
qq_43210334的博客
07-04 2069
本篇参考B站视频 “技术美术百人计划”·霜狼_may ； 《Shader入门精要》·冯乐乐女神著； 本篇主要用于自我复习，其中会掺入一些个人观点，如有疑问或发现有什么错误，请多指教~ 本篇内容主要包括：曲面细分着色器与几何着色器（缩写分别为TESS和GS）； 写在前面 在正式开始之前，我觉得应该先回顾下渲染管线，尤其是这两个着色器的位置，因为在面试中也有被问到，如下图； 本篇要说的这两位都是在顶点着色器之后，裁剪之前，其中曲面细分着色器在几何着色器之前，两个都是可选的着色器，并不是必须要写的，且曲面细.
Unity几何着色器和曲面细分的学习示例
10-10
Unity是一款强大的跨平台游戏开发引擎，它提供了丰富的图形渲染功能，包括几何着色器和曲面细分技术。在Unity中，着色器是用于控制物体表面颜色、光照、纹理等视觉效果的脚本。几何着色器（Geometry Shader）和曲面...
OpenGL中的曲面细分和几何着色器
m0_56903617的博客
04-17 3405
[摘要]本文我们先介绍OpenGL中的曲面细分的一些基本概念，然后给两个例子说明不得不用这项技术的理由。 曲面细分是OpenGL 4.0之后才定义的功能，使用之前请确认你的显卡驱动支持OpenGL4.0以上。 1. 曲面细分的目的 OpenGL用透视变换将三维几何模型映射到二维平面上，这样随着透视参数（比如模拟相机位置，方向，角度，焦距等等）的不同，以及几何模型在场景中的位置和大小不同，几何模型在二维平面显示的大小会不同。在传统的OpenGL应用中，一个几何模型建立后，GPU是不能增减模型中的顶点的。这样一
曲面细分着色器学习记录
学习学习学习
04-02 3418
曲面细分着色器 前言： 今天终于走通了Catlike大佬的曲面细分着色器教程，感慨一番，自己的学习之路还曼曼啊。。 先上个链接：Catlike的曲面细分教程 什么是曲面细分着色器
行业-电子政务-用于曲面细分和几何着色器的电力高效属性处置.zip
11-22
"行业-电子政务-用于曲面细分和几何着色器的电力高效属性处置.zip" 这个压缩包文件，显然关注的是在电子政务环境中如何利用技术提升能源效率，特别是针对曲面细分（Tessellation）和几何着色器（Geometry Shaders）...
曲面细分着色器（Tessellation）
万里归来少年心
10-24 3970
图形渲染流水线如下： 1.顶点着色器 #version 410 core void main(void) ...
曲面细分着色器---细分二维四边形
aoxuestudy的专栏
05-02 792
openGL系列文章目录 文章目录openGL系列文章目录前言一、曲面细分二、使用步骤1.引入库2.读入数据总结 前言 术语Tessellation（镶嵌）是指一大类设计活动，通常是指在平坦的表面上，用各种几何形状的瓷砖相邻排列以形成图案。它的目的可以是艺术性的或实用性的，很多例子可以追溯到几千年前在3D 图形学中，Tessellation 指的是有点不同的东西（曲面细分），但显然是由它的经典对应物（镶嵌）启发而成的。在这里，曲面细分指的是生成并且操控大量三角形以渲染复杂的形状和表面，尤其是使用硬件进行渲染
几何着色器与细分(镶嵌)着色器
c1sdn19的专栏
08-10 925
几何着色器与细分(镶嵌)着色器 GL细分着色器：https://www.cnblogs.com/zenny-chen/p/4280100.html GL几何着色器：https://blog.csdn.net/iron_lzn/article/details/48729849 posted on 2018-0...
个人学习笔记 ——【技术美术百人计划】图形 3.3 曲面细分与几何着色器 大规模草渲染
Lokakuu的博客
07-27 949
个人学习笔记 ——【技术美术百人计划】图形 3.3 曲面细分与几何着色器 大规模草渲染 图形 3.3 曲面细分与几何着色器个人学习笔记 ——【技术美术百人计划】图形 3.3 曲面细分与几何着色器 大规模草渲染一 、曲面细分与几何着色器的应用1.1 曲面细分着色器的应用1.2 几何着色器的应用二、着色器执行顺序三、曲面细分着色器-Tessellation shader（TESS）1.TESS的输入和输出2. TESS流程3. HULL Shader各参数解析3.1 Tessellation Factor3.
使用曲面细分着色器在GPU上生成地形
"GPU地形生成与 Tessellation 着色器技术在现代图形处理中的应用" 在游戏和电影行业中，地形生成是一项广泛应用的技术。然而，传统方法在CPU上创建精细的地形时面临时间消耗大和性能影响的问题。由于地形生成算法...
【一步步学OpenGL 30】 -《曲面细分基础》
Mr_厚厚的博客
07-03 5434
教程 30 曲面细分基础 原文： http://ogldev.atspace.co.uk/www/tutorial30/tutorial30.html CSDN完整版专栏： http://blog.csdn.net/column/details/13062.html 背景 曲面细分技术是OpenGL 4.x加入的一个令人振奋的新特性。曲面细分处理的核心是3d模型的细节和多...
Vulkan Cookbook 第七章 3 编写曲面细分控制着色器
qq_19473837的博客
06-23 661
编写曲面细分控制着色器 译者注：示例代码点击此处 细分是一个将几何划分为更小部分的过程。 在图形编程中，它允许我们以更灵活的方式改进渲染对象的细节数量或动态地改变它们的参数，例如平滑度或形状。 是否启用是可选的。 如果启用，则在顶点着色器之后执行。 它有三个步骤，其中两个是可编程的。 第一个可编程曲面细分阶段用于设置控制曲面细分执行方式的参数。 我们通过编写指定曲面细分因子值的曲面细分控制着...
评论
添加红包

请填写红包祝福语或标题

个

红包个数最小为10个

元

红包金额最低5元

当前余额3.43元 前往充值 >
需支付：10.00元
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包
实付元
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明：

1.余额是钱包充值的虚拟货币，按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载，可以购买VIP、付费专栏及课程。

余额充值