UnityShader 逐顶点漫反射效果与逐像素漫反射效果的实现

逐顶点漫反射

//逐顶点漫反射着色器
Shader "Test/DiffuseShader"
{
    Properties
    {
        //设置初始颜色为白色
        _Diffuse("Diffuse",Color) = (1,1,1,1)
    }
    SubShader
    {
        Pass
        {
            //定义光照模式
            Tags{"LightMode" = "ForwardBase"}
            CGPROGRAM

            #pragma vertex vert
            #pragma fragment frag
            #include "Lighting.cginc"

            fixed4 _Diffuse;

            struct a2v{
                float4 vertex : POSITION;//定点
                float3 normal : NORMAL; //法线
            };

            struct v2f{
                float4 pos : SV_POSITION;
                fixed3 color :COLOR;
            };

            v2f vert(a2v v){
                v2f o;
                o.pos = UnityObjectToClipPos(v.vertex);
                //UNITY_LIGHTMODEL_AMBIENT : 获取环境光部分
                fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz;
                fixed3 worldNormal = normalize(mul(v.normal,(float3x3)unity_WorldToObject));
                //_WorldSpaceLightPos0:世界坐标中光源的位置或方向向量
                fixed3 worldLight = normalize(_WorldSpaceLightPos0.xyz);
                //漫反射颜色 = 直射光颜色 * max(0, cos(光源方向和法线方向夹角)) * 材质自身颜色
                //其中 max(0, cos(光源方向和法线方向夹角))部分可以改用半兰伯特光照模型以增强背光面的光照效果
                //_LightColor0 : 访问Pass中处理的光源颜色和强度信息（注意，想要得到正确 的值需要定义合适的 LightMode标签）

                fixed3 diffuse = _LightColor0.rgb * _Diffuse.rgb * saturate(dot(worldNormal, worldLight));
                o.color = ambient + diffuse;
                return o;
            }
            fixed4 frag(v2f i) : SV_Target {
                return fixed4(i.color, 1.0);
            }  

            ENDCG
        }
    }
}

逐像素漫反射

//逐像素漫反射着色器
Shader "Test/DiffusePixelLevelShader"
{
    Properties
    {
        //设置初始颜色为白色
        _Diffuse("Diffuse",Color) = (1,1,1,1)
    }
    SubShader
    {
        Pass
        {
            //定义光照模式
            Tags{"LightMode" = "ForwardBase"}
            CGPROGRAM

            #pragma vertex vert
            #pragma fragment frag
            #include "Lighting.cginc"

            fixed4 _Diffuse;

            struct a2v{
                float4 vertex : POSITION;//定点
                float3 normal : NORMAL; //法线
            };

            struct v2f{
                float4 pos : SV_POSITION;
                fixed3 worldNormal : TEXCOORD0;
            };

            v2f vert(a2v v){
                v2f o;
                o.pos = UnityObjectToClipPos(v.vertex);
                o.worldNormal = mul(v.normal,(float3x3)unity_WorldToObject);
                return o;
            }
            fixed4 frag(v2f i) : SV_Target {
                fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz;
                fixed3 worldNormal = normalize(i.worldNormal);
                fixed3 worldLightDir = normalize(_WorldSpaceLightPos0.xyz);
                fixed3 diffuse = _LightColor0.rgb * _Diffuse.rgb * saturate(dot(worldNormal,worldLightDir));
                fixed3 color = ambient + diffuse;
                return fixed4(color, 1.0);
            }  

            ENDCG
        }
    }
}