UnityShader--高光反射

逐顶点

Shader "Custom/Specular/SpecularVertexLevel"
{
	Properties{
		_Diffuse("Diffuse", Color) = (1, 1, 1, 1)
		_Specular("Specular", Color) = (1, 1, 1, 1)
		_Gloss("Gloss", Range(8.0, 256)) = 20
	}
		SubShader{
			Pass{
				Tags{"LightMode" = "ForwardBase"}
			CGPROGRAM
			#pragma vertex vert
			#pragma fragment frag

			#include "Lighting.cginc"

			fixed4 _Diffuse;
			fixed4 _Specular;
			float _Gloss;

			struct a2v {
				float4 vertex : POSITION;
				float3 normal : NORMAL;
			};

			struct v2f {
				float4 pos : SV_POSITION;
				fixed3 color : COLOR;
			};

			v2f vert(a2v v) {
				v2f o;
				o.pos = UnityObjectToClipPos(v.vertex);//把顶点位置从模型空间转换到裁剪空间
				fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.rgb;//通过unity内置变量UNITY_LIGHTMODEL_AMBIENT得到环境光 
				
				fixed3 worldNormal = normalize(mul(v.normal, (float3x3)unity_WorldToObject));//世界空间的法线
				fixed3 worldLightDir = normalize(_WorldSpaceLightPos0.xyz);//世界空间的光源方向
				fixed3 diffuse = _LightColor0.rgb * _Diffuse.rgb * saturate(dot(worldNormal, worldLightDir));//saturate函数可以把参数截取到[0,1]的范围内
				
				fixed3 reflectDir = normalize(reflect(-worldLightDir, worldNormal));//世界空间的反射方向
				fixed3 viewDir = normalize(_WorldSpaceCameraPos.xyz - mul(unity_ObjectToWorld, v.vertex).xyz);//世界空间摄像机位置减去世界空间顶点位置得到世界空间下的视角方向
				fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(saturate(dot(reflectDir, viewDir)), _Gloss);
				o.color = ambient + diffuse + specular;
				return o;
			}

			fixed4 frag(v2f i) :SV_Target{
				return fixed4(i.color, 1);
			}

			ENDCG
		}

	}
		FallBack "Specular"
}

 

逐像素

Shader "Custom/Specular/SpecularPixelLevel"
{
	Properties{
		_Diffuse("Diffuse", Color) = (1, 1, 1, 1)
		_Specular("Specular", Color) = (1, 1, 1, 1)
		_Gloss("Gloss", Range(8.0, 256)) = 20
	}
		SubShader{
			Pass{
				Tags{"LightMode" = "ForwardBase"}
			CGPROGRAM
			#pragma vertex vert
			#pragma fragment frag

			#include "Lighting.cginc"

			fixed4 _Diffuse;
			fixed4 _Specular;
			float _Gloss;

			struct a2v {
				float4 vertex : POSITION;
				float3 normal : NORMAL;
			};

			struct v2f {
				float4 pos : SV_POSITION;
				fixed3 worldNormal : TEXCOORD0;
				fixed3 worldPos : TEXCOORD1;
			};

			v2f vert(a2v v) {
				v2f o;
				o.pos = UnityObjectToClipPos(v.vertex);//把顶点位置从模型空间转换到裁剪空间
				o.worldNormal = normalize(mul(v.normal, (float3x3)unity_WorldToObject));//世界空间的法线
				o.worldPos = mul(unity_ObjectToWorld, v.vertex).xyz;
				return o;
			}

			fixed4 frag(v2f i) :SV_Target{
				fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.rgb;//通过unity内置变量UNITY_LIGHTMODEL_AMBIENT得到环境光 
				
				fixed3 worldNormal = normalize(i.worldNormal);//世界空间的法线
				fixed3 worldLightDir = normalize(_WorldSpaceLightPos0.xyz);//世界空间的光源方向
				fixed3 diffuse = _LightColor0.rgb * _Diffuse.rgb * saturate(dot(worldNormal, worldLightDir));//saturate函数可以把参数截取到[0,1]的范围内
				
				fixed3 reflectDir = normalize(reflect(-worldLightDir, worldNormal));//世界空间的反射方向
				fixed3 viewDir = normalize(_WorldSpaceCameraPos.xyz - i.worldPos.xyz);//世界空间摄像机位置减去世界空间顶点位置得到世界空间下的视角方向
				fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(saturate(dot(reflectDir, viewDir)), _Gloss);
				return fixed4(ambient + diffuse + specular, 1);
			}

			ENDCG
		}

	}
		FallBack "Specular"
}

 

BlinnPhong

Shader "Custom/Specular/BlinnPhong"
{
	Properties{
		_Diffuse("Diffuse", Color) = (1, 1, 1, 1)
		_Specular("Specular", Color) = (1, 1, 1, 1)
		_Gloss("Gloss", Range(8.0, 256)) = 20
	}
		SubShader{
			Pass{
				Tags{"LightMode" = "ForwardBase"}
			CGPROGRAM
			#pragma vertex vert
			#pragma fragment frag

			#include "Lighting.cginc"

			fixed4 _Diffuse;
			fixed4 _Specular;
			float _Gloss;

			struct a2v {
				float4 vertex : POSITION;
				float3 normal : NORMAL;
			};

			struct v2f {
				float4 pos : SV_POSITION;
				fixed3 worldNormal : TEXCOORD0;
				fixed3 worldPos : TEXCOORD1;
			};

			v2f vert(a2v v) {
				v2f o;
				o.pos = UnityObjectToClipPos(v.vertex);//把顶点位置从模型空间转换到裁剪空间
				//o.worldNormal = normalize(mul(v.normal, (float3x3)unity_WorldToObject));//世界空间的法线//下面这行是用Unity内置函数替换的
				o.worldNormal = UnityObjectToWorldNormal(v.normal);
				o.worldPos = mul(unity_ObjectToWorld, v.vertex).xyz;
				return o;
			}

			fixed4 frag(v2f i) :SV_Target{
				fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.rgb;//通过unity内置变量UNITY_LIGHTMODEL_AMBIENT得到环境光 

				fixed3 worldNormal = normalize(i.worldNormal);//世界空间的法线
				//fixed3 worldLightDir = normalize(_WorldSpaceLightPos0.xyz);//世界空间的光源方向//下面这行是用Unity内置函数替换的
				fixed3 worldLightDir = normalize(UnityWorldSpaceLightDir(i.worldPos));
				fixed3 diffuse = _LightColor0.rgb * _Diffuse.rgb * saturate(dot(worldNormal, worldLightDir));//saturate函数可以把参数截取到[0,1]的范围内

				//fixed3 reflectDir = normalize(reflect(-worldLightDir, worldNormal));//世界空间的反射方向
				//fixed3 viewDir = normalize(_WorldSpaceCameraPos.xyz - i.worldPos.xyz);//世界空间下的视角方向//下面这行是用Unity内置函数替换的
				fixed3 viewDir = normalize(UnityWorldSpaceViewDir(i.worldPos));
				fixed3 halfDir = normalize(worldLightDir + viewDir);
				fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(max(0, dot(worldNormal, halfDir)), _Gloss);
				return fixed4(ambient + diffuse + specular, 1);
			}

			ENDCG
		}

	}
		FallBack "Specular"
}