《UnityShader入门精要》 高光反射部分笔记 代码及详细注释

高光反射

高光反射计算公式 ： C specular   = (C light · M specular ) [max(0 ，  v · r ) ^ M gloss ]

C light : 入射光线的颜色和强度

M specular :  高 光反射系数

v ：视角方向单位向量

r ： 反射方向单位向量    可由表面法线 单位向量  n  和 光源方向单位向量 l   计算而得  r = l - 2 (n  · l ) n

        当然 在Cg 代码中 提供了 简便 的函数  refkect(i,n)  i --> 入射方向   n --> 法线方向

 

逐顶点高光反射代码 ：

效果图：

 

Shader "SpecularVertex"
{
    Properties
    {
    _Diffuse ("Diffuse",Color) = (1,1,1,1)
    _Specular ("Specular",Color) = (1,1,1,1) //控制材质的高光反射颜色
    _Gloss ("Gloss",Range(8.0 , 256)) = 20   //控制高光区域的大小
    }
    SubShader
    {
        Pass{
            Tags{"LightMode" = "ForwardBase"}  //定义了对应的标签才能 使用一些unity内置光照 比如 _LightColor0
            CGPROGRAM
                #pragma vertex vert
                #pragma fragment frag

                #include "Lighting.cginc"

                fixed4 _Diffuse;
                fixed4 _Specular;
                float _Gloss;

                struct a2v{
                    float4 vertex : POSITION;
                    float3 normal : NORMAL;
                };
                struct v2f{
                    float4 pos : SV_POSITION;
                    fixed3 color : COLOR;
                };
                v2f vert(a2v v){
                    v2f o;
                    o.pos = UnityObjectToClipPos(v.vertex);//空间变化
                    //获得环境光
                    fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz;
                    //将法线转换成世界空间单位向量
                    fixed3 worldNormal = normalize(mul(v.normal,(float3x3)unity_WorldToObject));
                    // 获得光的单位向量
                    fixed3 worldLightDir = normalize(_WorldSpaceLightPos0.xyz);
                    //漫反射计算
                    fixed3 diffuse = _LightColor0.rgb * _Diffuse.rgb * saturate(dot(worldNormal,worldLightDir));
                   
                    //获取在世界空间下的反射单位向量  reflect() 函数用于计算反射方向
                    fixed3 reflectDir = normalize(reflect(-worldLightDir,worldNormal));
                    // 获取观察视角单位向量
                    fixed3 viewDir = normalize(_WorldSpaceCameraPos.xyz - mul(unity_ObjectToWorld,v.vertex).xyz);
                    //计算高光反射 pow（）是乘方函数 pow() 函数用来求 x 的 y 次幂(次方)
                    fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(saturate(dot(reflectDir,viewDir)),_Gloss);
                   //进行颜色叠加
                    o.color = ambient + diffuse + specular;
                    return o;
                }
                fixed4 frag(v2f i) : SV_Target{
                    return fixed4(i.color,1.0);
                }
            ENDCG
        }        
    }
    Fallback "Specular"
}

逐片元（像素）高光反射代码 ：

效果图：

 

Shader "Custom/SpecularPixel"
{
    Properties
    {
    _Diffuse ("Diffuse",Color) = (1,1,1,1)
    _Specular ("Specular",Color) = (1,1,1,1) //控制材质的高光反射颜色
    _Gloss ("Gloss",Range(8.0 , 256)) = 20   //控制高光区域的大小
    }
    SubShader
    {
        Pass{
            Tags{"LightMode" = "ForwardBase"}  //定义了对应的标签才能 使用一些unity内置光照 比如 _LightColor0
            CGPROGRAM
                #pragma vertex vert
                #pragma fragment frag

                #include "Lighting.cginc"

                fixed4 _Diffuse;
                fixed4 _Specular;
                float _Gloss;

                struct a2v{
                    float4 vertex : POSITION;
                    float3 normal : NORMAL;
                };
                struct v2f{
                    float4 pos : SV_POSITION;
                    float3 worldNormal : TEXCOORD0;
                    float3 worldPos : TEXCOORD1;
                };
                v2f vert(a2v v){
                    v2f o;
                    //转换空间坐标
                    o.pos = UnityObjectToClipPos(v.vertex);
                    //将法线向量从模型空间转换为世界空间
                    o.worldNormal = mul(v.normal,(float3x3)unity_WorldToObject);
                    //将顶点向量从模型空间转换到世界空间
                    o.worldPos = mul(unity_ObjectToWorld,v.vertex).xyz;

                    return o;
                }
               
                fixed4 frag(v2f i) : SV_Target{
                    //获取环境光
                    fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz;
                    //计算单位法线和光照向量
                    fixed3 worldNormal = normalize(i.worldNormal);
                    fixed3 worldLightDir = normalize(_WorldSpaceLightPos0.xyz);
                    //计算漫反射
                    fixed3 diffuse = _LightColor0.rgb * _Diffuse.rgb * saturate(dot(worldNormal,worldLightDir));
                    //计算反射光线 的 单位向量
                    fixed3 reflectDir = normalize(reflect(-worldLightDir,worldNormal));
                    //获取世界空间的视图单位向量 得到相机位置 和 顶点向量位置 相减即可得到高光反射的光照向量
                    fixed3 viewDir = normalize(_WorldSpaceCameraPos.xyz - i.worldPos.xyz);
                    //计算高光反射
                    fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(saturate(dot(reflectDir,viewDir)),_Gloss);
                    //返回高光反射
                    return fixed4(ambient + diffuse + specular,1.0);
                }
            ENDCG
        }        
    }
    Fallback "Specular"
}

冯布林BLINNPHONE高光反射代码：

C specular = (C light · M specular)[max(0,n·h)]^M a 

C light : 入射光线的颜色和强度

M specular : 高光反射系数

v ：视角方向单位向量

r ： 反射方向单位向量    可由表面法线单位向量 n  和 光源方向单位向量 l  计算而得  r = l - 2(n · l ) n

        当然 在Cg 代码中 提供了 简便 的函数  refkect(i,n)  i --> 入射方向   n --> 法线方向

h : 通过视角单位向量和光照方向单位向量相加后再归一化得到    h = v + l / | v + l |

 效果图：

 Blinn-Phone的高光反射部分看起来更加亮一些，更加大一些，在现实渲染中我们大多数也会选择Blinn-Phone模型。高光区域衰减比较线性

Shader "Custom/BlinnPhone"
{
    Properties
    {
    _Diffuse ("Diffuse",Color) = (1,1,1,1)
    _Specular ("Specular",Color) = (1,1,1,1) //控制材质的高光反射颜色
    _Gloss ("Gloss",Range(8.0 , 256)) = 20   //控制高光区域的大小
    }
    SubShader
    {
        Pass{
            Tags{"LightMode" = "ForwardBase"}  //定义了对应的标签才能 使用一些unity内置光照 比如 _LightColor0
            CGPROGRAM
                #pragma vertex vert
                #pragma fragment frag

                #include "Lighting.cginc"

                fixed4 _Diffuse;
                fixed4 _Specular;
                float _Gloss;

                struct a2v{
                    float4 vertex : POSITION;
                    float3 normal : NORMAL;
                };
                struct v2f{
                    float4 pos : SV_POSITION;
                    float3 worldNormal : TEXCOORD0;
                    float3 worldPos : TEXCOORD1;
                };
                v2f vert(a2v v){
                    v2f o;
                    //转换空间坐标
                    o.pos = UnityObjectToClipPos(v.vertex);
                    //将法线向量从模型空间转换为世界空间
                    o.worldNormal = mul(v.normal,(float3x3)unity_WorldToObject);
                    //将顶点向量从模型空间转换到世界空间
                    o.worldPos = mul(unity_ObjectToWorld,v.vertex).xyz;

                    return o;
                }
               
                fixed4 frag(v2f i) : SV_Target{
                    //获取环境光
                    fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz;
                    //计算单位法线和光照向量
                    fixed3 worldNormal = normalize(i.worldNormal);
                    fixed3 worldLightDir = normalize(_WorldSpaceLightPos0.xyz);
                    //计算漫反射
                    fixed3 diffuse = _LightColor0.rgb * _Diffuse.rgb * saturate(dot(worldNormal,worldLightDir));
                    //计算反射光线 的 单位向量
                    fixed3 reflectDir = normalize(reflect(-worldLightDir,worldNormal));
                    //获取世界空间的视图单位向量 得到相机位置 和 顶点向量位置 相减即可得到高光反射的光照向量
                    fixed3 viewDir = normalize(_WorldSpaceCameraPos.xyz - i.worldPos.xyz);
                    //获得 视角方向和光线方向相加后 归一化
                    fixed3 halfDir = normalize(worldLightDir + viewDir);
                    //计算高光
                    fixed3 specular = _LightColor0.rgb * _Specular * pow(max(0,dot(worldNormal,halfDir)),_Gloss);
                    //返回高光
                    return fixed4(ambient + diffuse + specular,1.0);
                }
            ENDCG
        }        
    }
    Fallback "Specular"
}

三种高光反射对比：