[UnityShader2]表面着色器实例(一)

最新推荐文章于 2022-09-18 01:18:34 发布
最新推荐文章于 2022-09-18 01:18:34 发布
阅读量2k 收藏
点赞数 1
分类专栏： UnityShader2 文章标签： 表面着色器实例

官方文档：http://docs.unity3d.com/Manual/SL-SurfaceShaderExamples.html


1.纹理采样

Shader "Example/Diffuse Texture" {
    Properties {
      _MainTex ("Texture", 2D) = "white" {}
    }
    SubShader {
      Tags { "RenderType" = "Opaque" }
      CGPROGRAM
      #pragma surface surf Lambert
      struct Input {
          float2 uv_MainTex;
      };
      sampler2D _MainTex;
      void surf (Input IN, inout SurfaceOutput o) {
          o.Albedo = tex2D (_MainTex, IN.uv_MainTex).rgb;
      }
      ENDCG
    } 
    Fallback "Diffuse"
  }



2.法线贴图

Shader "Example/Diffuse Bump" {
    Properties {
      _MainTex ("Texture", 2D) = "white" {}
      _BumpMap ("Bumpmap", 2D) = "bump" {}
    }
    SubShader {
      Tags { "RenderType" = "Opaque" }
      CGPROGRAM
      #pragma surface surf Lambert
      struct Input {
        float2 uv_MainTex;
        float2 uv_BumpMap;
      };
      sampler2D _MainTex;
      sampler2D _BumpMap;
      void surf (Input IN, inout SurfaceOutput o) {
        o.Albedo = tex2D (_MainTex, IN.uv_MainTex).rgb;
        o.Normal = UnpackNormal (tex2D (_BumpMap, IN.uv_BumpMap));
      }
      ENDCG
    } 
    Fallback "Diffuse"
  }



3.边缘光：在表面法线和观察方向的夹角间给予一些自发光

a.viewDir：观察方向

b.saturate(x)：cg函数，将x限制在(0,1)之间

Shader "Example/Rim" {
    Properties {
      _MainTex ("Texture", 2D) = "white" {}
      _BumpMap ("Bumpmap", 2D) = "bump" {}
      _RimColor ("Rim Color", Color) = (0.26,0.19,0.16,0.0)
      _RimPower ("Rim Power", Range(0.5,8.0)) = 3.0
    }
    SubShader {
      Tags { "RenderType" = "Opaque" }
      CGPROGRAM
      #pragma surface surf Lambert
      struct Input {
          float2 uv_MainTex;
          float2 uv_BumpMap;
          float3 viewDir;
      };
      sampler2D _MainTex;
      sampler2D _BumpMap;
      float4 _RimColor;
      float _RimPower;
      void surf (Input IN, inout SurfaceOutput o) {
          o.Albedo = tex2D (_MainTex, IN.uv_MainTex).rgb;
          o.Normal = UnpackNormal (tex2D (_BumpMap, IN.uv_BumpMap));
          half rim = 1.0 - saturate(dot (normalize(IN.viewDir), o.Normal));
          o.Emission = _RimColor.rgb * pow (rim, _RimPower);
      }
      ENDCG
    } 
    Fallback "Diffuse"
  }



4.细节纹理

For a different effect, let’s add a detail texture that is combined with the base texture. Detail texture uses the same UVs, but usually different Tiling in the Material, so we have to use different input UV coordinates.

Shader "Example/Detail" {
    Properties {
      _MainTex ("Texture", 2D) = "white" {}
      _BumpMap ("Bumpmap", 2D) = "bump" {}
      _Detail ("Detail", 2D) = "gray" {}
    }
    SubShader {
      Tags { "RenderType" = "Opaque" }
      CGPROGRAM
      #pragma surface surf Lambert
      struct Input {
          float2 uv_MainTex;
          float2 uv_BumpMap;
          float2 uv_Detail;
      };
      sampler2D _MainTex;
      sampler2D _BumpMap;
      sampler2D _Detail;
      void surf (Input IN, inout SurfaceOutput o) {
          o.Albedo = tex2D (_MainTex, IN.uv_MainTex).rgb;
          o.Albedo *= tex2D (_Detail, IN.uv_Detail).rgb * 2;
          o.Normal = UnpackNormal (tex2D (_BumpMap, IN.uv_BumpMap));
      }
      ENDCG
    } 
    Fallback "Diffuse"
  }



5.在屏幕空间的细节纹理

 Shader "Example/ScreenPos" {
    Properties {
      _MainTex ("Texture", 2D) = "white" {}
      _Detail ("Detail", 2D) = "gray" {}
    }
    SubShader {
      Tags { "RenderType" = "Opaque" }
      CGPROGRAM
      #pragma surface surf Lambert
      struct Input {
          float2 uv_MainTex;
          float4 screenPos;
      };
      sampler2D _MainTex;
      sampler2D _Detail;
      void surf (Input IN, inout SurfaceOutput o) {
          o.Albedo = tex2D (_MainTex, IN.uv_MainTex).rgb;
          float2 screenUV = IN.screenPos.xy / IN.screenPos.w;
          screenUV *= float2(8,6);
          o.Albedo *= tex2D (_Detail, screenUV).rgb * 2;
      }
      ENDCG
    } 
    Fallback "Diffuse"
  }



6.立方体贴图的反射

跟内置的Reflective/Diffuse很相似

Shader "Example/WorldRefl" {
    Properties {
      _MainTex ("Texture", 2D) = "white" {}
      _Cube ("Cubemap", CUBE) = "" {}
    }
    SubShader {
      Tags { "RenderType" = "Opaque" }
      CGPROGRAM
      #pragma surface surf Lambert
      struct Input {
          float2 uv_MainTex;
          float3 worldRefl;
      };
      sampler2D _MainTex;
      samplerCUBE _Cube;
      void surf (Input IN, inout SurfaceOutput o) {
          o.Albedo = tex2D (_MainTex, IN.uv_MainTex).rgb * 0.5;
          o.Emission = texCUBE (_Cube, IN.worldRefl).rgb;
      }
      ENDCG
    } 
    Fallback "Diffuse"
  }



如果你想让反射受法线贴图影响，需要在Input结构体中加入INTERNAL_DATA；WorldReflectionVector 这个函数的作用就是当你输出法线后，可以计算逐像素的放射向量。

Shader "Example/WorldRefl Normalmap" {
    Properties {
      _MainTex ("Texture", 2D) = "white" {}
      _BumpMap ("Bumpmap", 2D) = "bump" {}
      _Cube ("Cubemap", CUBE) = "" {}
    }
    SubShader {
      Tags { "RenderType" = "Opaque" }
      CGPROGRAM
      #pragma surface surf Lambert
      struct Input {
          float2 uv_MainTex;
          float2 uv_BumpMap;
          float3 worldRefl;
          INTERNAL_DATA
      };
      sampler2D _MainTex;
      sampler2D _BumpMap;
      samplerCUBE _Cube;
      void surf (Input IN, inout SurfaceOutput o) {
          o.Albedo = tex2D (_MainTex, IN.uv_MainTex).rgb * 0.5;
          o.Normal = UnpackNormal (tex2D (_BumpMap, IN.uv_BumpMap));
          o.Emission = texCUBE (_Cube, WorldReflectionVector (IN, o.Normal)).rgb;
      }
      ENDCG
    } 
    Fallback "Diffuse"
  }



7.用世界空间位置进行裁剪

Shader "Example/Slices" {
    Properties {
      _MainTex ("Texture", 2D) = "white" {}
      _BumpMap ("Bumpmap", 2D) = "bump" {}
    }
    SubShader {
      Tags { "RenderType" = "Opaque" }
      Cull Off
      CGPROGRAM
      #pragma surface surf Lambert
      struct Input {
          float2 uv_MainTex;
          float2 uv_BumpMap;
          float3 worldPos;
      };
      sampler2D _MainTex;
      sampler2D _BumpMap;
      void surf (Input IN, inout SurfaceOutput o) {
          clip (frac((IN.worldPos.y+IN.worldPos.z*0.1) * 5) - 0.5);
          o.Albedo = tex2D (_MainTex, IN.uv_MainTex).rgb;
          o.Normal = UnpackNormal (tex2D (_BumpMap, IN.uv_BumpMap));
      }
      ENDCG
    } 
    Fallback "Diffuse"
  }



8.使用顶点修改器进行法线挤出

可以使用顶点修改器去修改输入的顶点数据，这在动画、法线挤出上会很有用。surface shader的编译指令vertex:functionName就是用来指定修改顶点的函数的，它的参数是inout appdata_full

Shader "Example/Normal Extrusion" {
    Properties {
      _MainTex ("Texture", 2D) = "white" {}
      _Amount ("Extrusion Amount", Range(-1,1)) = 0.5
    }
    SubShader {
      Tags { "RenderType" = "Opaque" }
      CGPROGRAM
      #pragma surface surf Lambert vertex:vert
      struct Input {
          float2 uv_MainTex;
      };
      float _Amount;
      void vert (inout appdata_full v) {
          v.vertex.xyz += v.normal * _Amount;
      }
      sampler2D _MainTex;
      void surf (Input IN, inout SurfaceOutput o) {
          o.Albedo = tex2D (_MainTex, IN.uv_MainTex).rgb;
      }
      ENDCG
    } 
    Fallback "Diffuse"
  }



9.逐顶点地计算自定义的数据

使用顶点修改器函数可以计算自定义的数据(在顶点程序中)，然后就会被传送到surface函数中(可以把surface函数当作片段函数)。如果使用自定义的数据，那么就需要两个参数：inout appdata_full and out Input。inout表示引用，即可以修改顶点的数据；out是输出，即值会返回到Input结构中。自定义数据可以放在Input结构体中(一般Input结构体内的都是内置值)，但是要注意命名不能以"uv"开头。

Shader "Example/Custom Vertex Data" {
    Properties {
      _MainTex ("Texture", 2D) = "white" {}
    }
    SubShader {
      Tags { "RenderType" = "Opaque" }
      CGPROGRAM
      #pragma surface surf Lambert vertex:vert
      struct Input {
          float2 uv_MainTex;
          float3 customColor;
      };
      void vert (inout appdata_full v, out Input o) {
          UNITY_INITIALIZE_OUTPUT(Input,o);
          o.customColor = abs(v.normal);
      }
      sampler2D _MainTex;
      void surf (Input IN, inout SurfaceOutput o) {
          o.Albedo = tex2D (_MainTex, IN.uv_MainTex).rgb;
          o.Albedo *= IN.customColor;
      }
      ENDCG
    } 
    Fallback "Diffuse"
  }



该用处就是可以计算Input结构体中没有的内置值；或者用于shader的优化，因为逐顶点的计算要优于逐像素的计算(因为顶点数要远小于像素数)


10.最终颜色修改器

可以使用最终颜色修改器修改最终的颜色，此时要使用编译指令： finalcolor:functionName，函数的参数为Input IN, SurfaceOutput o, inout fixed4 color

Shader "Example/Tint Final Color" {
    Properties {
      _MainTex ("Texture", 2D) = "white" {}
      _ColorTint ("Tint", Color) = (1.0, 0.6, 0.6, 1.0)
    }
    SubShader {
      Tags { "RenderType" = "Opaque" }
      CGPROGRAM
      #pragma surface surf Lambert finalcolor:mycolor
      struct Input {
          float2 uv_MainTex;
      };
      fixed4 _ColorTint;
      void mycolor (Input IN, SurfaceOutput o, inout fixed4 color)
      {
          color *= _ColorTint;
      }
      sampler2D _MainTex;
      void surf (Input IN, inout SurfaceOutput o) {
           o.Albedo = tex2D (_MainTex, IN.uv_MainTex).rgb;
      }
      ENDCG
    } 
    Fallback "Diffuse"
  }



宏哥1995
关注
专栏目录
Unity3D表面着色器(Surface Shader)资料整合
蚂蚁的坚持
07-17 1225
一、Shader 表面着色器语法 Unity 的表面着色器 (Surface Shader) 是一种代码生成方法，用它来编写光照着色器比用低级的顶点/像素着色器程序容易得多 二、编写一个灰度效果的Shader 三、Shader 内置 Shader 之 Normal-Diffuse  Normal-Diffuse 是一个简单的光照模型，光照强度随着物体表面和光入射角夹角的减小
表面着色器
Fatestay_DC的专栏
11-02 256
除了几乎从头开始编写着色器之外，unity还允许我们定义一些参数，并让unity生成执行复杂光照计算的代码。 这些着色器称为“表面着色器”。 之前的basic shader转换到表面着色器 使用表面着色器时，我们不必做其他的事情，因为unity会为我们生成它们。为了转换为你表面着色器，可以完全删除顶点着色器。可以删除顶点和片段函数的编译指示定义。可以删除输入以及将片段片段化的顶点。 可以删除进行纹理缩放的MainTex_ST变量，也可以删除UnityCG包含文件的包含。 然后我们删除pass的起点和终点，U
表面着色器案例分析
fyjlf的专栏
04-12 546
下面是表面着色器案例分析，主要是自己学习，其实就是抄写一遍 首先是一个比较简单的例子 Shader"Example/Diffuse"//漫反射 { SubShader { Tags{"RenderType"="Opaque"}//渲染模式为透明物体，也就是场景中的透明物体使用该shader CGPROGRAM #pragma  surface surf  Lambert//内置光照
UnityShader之六 表面着色器-自定义光照模式
m0_37884055的博客
10-23 1070
UnityShader系列文章转载于 @浅墨_毛星云，为本人的学习笔记，转载请注明出处。 文章链接：https://blog.csdn.net/poem_qianmo/article/details/42611531 漫反射         漫反射，是投射在粗糙表面上的光向各个方向反射的现象。当一束平行的入射光线射到粗糙的表面时，表面会把光线向着四面八方反射，所以入射线虽然互相平行，由于各点...
Unity3D-CG编程：各种着色器
02-06
表面着色器是Unity中常用的着色器类型，它们简化了着色器编写过程，将光照计算集中在单个函数中。开发者可以轻松地调整材质属性，实现复杂的光照效果。 2. Vertex and Fragment Shaders（顶点和片段着色器） 对于...
Amplify Shader Editor 1.8.1 着色器编辑器附教程.zip
06-01
Amplify Shader Editor 1.8.1 是一个强大的着色器编辑工具，专为Unity游戏引擎设计。这款工具提供了一种直观的图形用户界面，允许开发者无需编写复杂的Shader语言代码，就能创建出复杂的视觉效果。它极大地简化了...
Unity Shader Forge 中文版基础+实例手册
11-20
《Unity Shader Forge 中文版基础+实例手册》是一本全面介绍Shader Forge这一强大工具的教程书籍。它不仅覆盖了Shader Forge的基础知识，还提供了丰富的实践案例，帮助读者更好地理解和掌握如何利用Shader Forge创建...
Unity Shader 入门书籍高清完整版PDF
01-29
本书可能从基本的Shader结构开始讲解，如顶点着色器（Vertex Shader）和片段着色器（Fragment Shader），这两个组件是所有Shader的基础。 顶点着色器处理场景中的每个顶点，执行诸如平移、旋转、缩放等几何变换。...
Unity Shader编程
03-27
在Unity中，Shader主要分为两种类型：Surface Shaders和Vertex/Fragment Shaders（也称为顶点/片段着色器）。Surface Shaders更适合初学者，因为它们提供了简洁的接口来描述物体表面的外观，而Vertex/Fragment ...
unity表面着色器_Unity 3技术–表面着色器
culiao6493的博客
09-13 441
unity表面着色器In Unity you can write your own custom shaders, but it’s no secret that writing them is hard, especially when you need shaders that interact with per-pixel lights & shadows. In Unity 3, ...
Unity3D - Shader - 表面着色器（Surface Shaders）
biezhihua的专栏
09-05 1997
在Unity中，包面着色器的关键代码用Cg/HLSL语言编写，然后嵌在ShaderLab的结构代码中使用。
Unity Shader之表面着色器Surface Shader
专注Android
09-20 272
表面着色器Surface Shader 是Unity中特有的着色器，其实质上是对Vertex and Fragment Shader 的一种封装，Surface Shader使得shader 的编写变动更加的容易。 Shader "Custom/SurfaceShader01" { Properties { _Color ("Color", Color) = (1,1,1,1) _M...
图形学应用_着色器实例—马赛克效果
qq_39025293的博客
05-24 340
马赛克效果的实现 最终效果： 将材质付给物体： 左侧是表面着色器，右侧是顶点和片元着色器。 将材质球用来处理屏幕特效： 上图是顶点和片元着色器来处理屏幕特效的效果。表面着色器不能用来处理屏幕特效。（不知道为什么，只显示一片黑）。 表面着色器代码： Shader "Custom/Mosaic_SurfaceShader" { Properties{ _MainTex(...
【Unity3D】表面着色器
little_fat_sheep
09-18 3699
固定管线着色器一、固定管线着色器二中介绍了 ShaderLib 的基本用法，本文将接着讲解表面着色器（Surface Shader）的用法。固定管线着色器基于 ShaderLib 命令实现，表面着色器基于 CG 语言实现。目前主流的 Shader 编程语言主要有 GLSL、HLSL、CG，如下：GLSL：OpenGL Shading Language，基于 OpenGL 接口，跨操作系统，依赖硬件。
UnityShader学习笔记 Unity的表面着色器
漫漫无期的博客
09-04 1305
将渲染流程划分为表面着色器、光照模型和光照着色器这样的层面。 其中，表面着色器定义了模型表面的反射率、法线和高光等，光照模型选择是使用兰伯特还是Blinn-Phong等模型。而光照着色器负责计算光照衰减、阴影等。 表面着色器实际上就是在顶点/片元着色器之上又添加了一层抽象。 表面着色器的一个例子 使用表面着色器来实现一个使用了法线纹理的漫反射效果。 Shader "Unity Shaders Book/Chapter 17/Bumped Diffuse" { Properties {
UnityShader入门精要——表面着色器
weixin_51327051的博客
06-23 1518
表面着色器的CG代码是直接而且也必须写在SubShader块中，Unity 会在背后为我们生成多个Pass。当然，可以在SubShader一开始处使用Tags来设置该表面着色器使用的标签。我们也可以使用LOD命令设置该表面着色器的LOD值。然后，我们使用CGPROGRAM和ENDCG定义了表面着色器的具体代码。 1 编译指令编译指令最重要的作用是指明该表面着色器使用的表面函数和光照函数，并设置一些可选参数。表面着色器的CG块中的第一句代码往往就是它的编译指令。编译指令的一般格式如下: 其中，#pra
Shader基础：5、表面着色器Surface Shader
真像大白阿的博客
05-30 559
表面着色器是通过Unity给我们制定好的一套标准，计算出需要填充输入什么，输出什么等相关信息，并产生真实的顶点(vertex)&像素(pixel)着色器，以及把渲染路径传递到正向或延时渲染路径。 输出结构 struct SurfaceOutput { half3 Albedo; //反射率，也就是纹理颜色值（r,g,b) half3 Normal; //法线，法向量(x, y, z) half3 Em...
UnityShader 表面着色器基本结构
Fanstasic的博客
01-04 251
//表面着色器的基本结构 struct SurfaceOutput { fixed3 Albedo; // 漫射颜色 fixed3 Normal; // 切线空间法线（如果已写入） fixed3 Emission; half Specular; // 0..1 范围内的镜面反射能力 fixed Gloss; // 镜面反射强度 ...
精通Unity 5.x着色器与特效：实战指南
1. **Unity 5.x 着色器基础知识**：书中将引导读者了解Unity引擎中的着色系统，包括表面着色器、顶点片段着色器等基本概念，以及如何在Unity编辑器中创建和应用自定义着色器。 2. **物理基础着色（PBR）**：讲解了...
评论 1
添加红包

请填写红包祝福语或标题

个

红包个数最小为10个

元

红包金额最低5元

当前余额3.43元 前往充值 >
需支付：10.00元
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包
实付元
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明：

1.余额是钱包充值的虚拟货币，按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载，可以购买VIP、付费专栏及课程。

余额充值