FPGA实现uart协议

已于 2023-05-10 16:04:20 修改
阅读量1.2k 收藏 14
点赞数 2
分类专栏： FPGA uart串口 文章标签： fpga开发
于 2022-10-07 11:11:11 首次发布
版权声明：本文为博主原创文章，遵循 CC 4.0 BY-SA 版权协议，转载请附上原文出处链接和本声明。
本文链接：https://blog.csdn.net/lzl1342848782/article/details/127112791
版权

简介

使用verilog实现uart协议，能够和pc进行通信，实现串口回环功能，各参数设置如下：

  • 波特率：115200
  • 数据位：8
  • 停止位：任意
  • 校验位：无

系统时钟为50M，115200波特率下，每一个bit占50M/115200 = 434时钟周期。
停止位任意即不考虑停止位。代码追求简洁，能用就行。
注意：uart协议是LSB优先的

接收模块

接收模块从pc端接收到异步的串行信号，解析为valid信号+一字节并行数据，传递到其他模块，回环的话，直接传递到发送模块。
流程：

  1. 首先对输入的异步信号rx打两拍防止亚稳态
  2. 检测rx下降沿，拉高计数器使能
  3. 波特计数器循环计数0到433，比特计数器根据波特计数器溢出，从0计数到8，其中0是起始位，1-8是数据位
  4. 在每一位中间进行采样，即波特计数器=433/2时，数据比较稳定，所以在此刻采样进移位寄存器
  5. 波特计数器和比特计数器都结束时，拉低计数器使能，拉高valid一时钟周期，输出移位寄存器中的数据。

代码：

module uart_rx(
    input               clk,            // 50M
    input               rst_n,
    
    // uart side
    input               rx,

    // host side
    output reg          valid,
    output reg  [7:0]   data
);
//---------------------------------信号声明-----------------------------------
    localparam BAUD_RATE    = 115200;
    localparam BAUD_CNT_MAX = (50_000_000 / BAUD_RATE) - 1;
    // rx打两拍，第三拍检测下降沿
    reg [2:0]   rx_shift;
    // 计数器使能
    reg         cnt_ena;
    // baud计数器
    reg [12:0]  baud_cnt;
    // bit计数器
    reg [3:0]   bit_cnt;
//---------------------------------------------------------------------------
    // rx打两拍，第三拍检测下降沿
    always @(posedge clk, negedge rst_n) begin
        if(!rst_n)
            rx_shift <= 3'b111;
        else
            rx_shift <= {rx, rx_shift[2:1]};
    end

    // 计数器使能
    always @(posedge clk, negedge rst_n) begin
        if(!rst_n)
            cnt_ena <= 0;
        else if(~rx_shift[1] & rx_shift[0])// rx下降沿
            cnt_ena <= 1'b1;
        else if(baud_cnt == BAUD_CNT_MAX && bit_cnt == 4'd8)
            cnt_ena <= 1'b0;
    end

    // baud cnt
    always @(posedge clk, negedge rst_n) begin
        if(!rst_n)
            baud_cnt <= 0;
        else if(cnt_ena) begin
            if(baud_cnt == BAUD_CNT_MAX)
                baud_cnt <= 0;
            else
                baud_cnt <= baud_cnt + 13'd1;
        end  
    end

    // bit cnt
    always @(posedge clk, negedge rst_n) begin
        if(!rst_n)
            bit_cnt <= 0;
        else if(cnt_ena && baud_cnt == BAUD_CNT_MAX) begin
            if(bit_cnt == 4'd8)
                bit_cnt <= 0;
            else
                bit_cnt <= bit_cnt + 4'd1;
        end
    end

    // output valid
    always @(posedge clk, negedge rst_n) begin
        if(!rst_n)
            valid <= 0;
        else if(baud_cnt == BAUD_CNT_MAX && bit_cnt == 4'd8)
            valid <= 1'b1;
        else
            valid <= 1'b0;
    end

    // output data
    always @(posedge clk, negedge rst_n) begin
        if(!rst_n)
            data <= 0;
        else if(cnt_ena && baud_cnt == (BAUD_CNT_MAX / 2))    // 在每个bit中间采样进入移位寄存器
            data <= {rx_shift[0], data[7:1]};
    end
endmodule

对该模块进行简单的波形仿真，对其发送三次数据，分别是8’h01, 8’hab, 8’hff, tb如下：

`timescale 1ps/1ps
module uart_rx_tb;
    reg clk = 1'b1;
    always #10 clk = ~clk;
    reg rst_n = 1'b0;

    reg rx = 1'b1;

    wire       valid;
    wire [7:0] data;

    integer i = 0;

    initial begin
        #30 rst_n = 1'b1;
        #10;
        #10000;
        receieve_data(8'h01);
        receieve_data(8'hab);
        receieve_data(8'hff);
        #100 $stop(2);// $finish;
    end

    task receieve_data;
        input [7:0] sim_data;
        begin
            // 起始位
            rx <= 1'b0;
            #(20 * 434);
            // 8bit数据
            for(i = 0; i < 8; i = i + 1) begin
                rx <= sim_data[i];
                #(20 * 434);
            end
            // 停止位
            rx <= 1'b1;
            #(20 * 434);
            #1000;
        end
    endtask

    uart_rx inst_uart_rx (
        .clk   (clk), 
        .rst_n (rst_n), 
        .rx    (rx), 
        .valid (valid), 
        .data  (data)
    );

endmodule

波形图如下，可以观察到，三次valid拉高时的data正好对应了8’h01, 8’hab, 8’hff：
在这里插入图片描述

发送模块

发送模块接收内部的valid+data，转化为uart串行信号通过io输出。
流程：

  1. 检测到valid信号，则对data进行寄存，并拉高计数器使能
  2. 波特计数器循环计数0到433，比特计数器根据波特计数器溢出，从0计数到8，其中0是起始位，1-8是数据位
  3. 根据比特计数器值输出对应的数据位

代码：

module uart_tx(
    input           clk,            // 50M
    input           rst_n,
    
    // host side
    input           valid,
    input   [7:0]   data,
    
    // uart side
    output          tx
);
//------------------------------------信号声明---------------------------
    localparam BAUD_RATE    = 115200;
    localparam BAUD_CNT_MAX = (50_000_000 / BAUD_RATE) - 1;
    // 数据寄存 + 起始位
    reg [8:0]   data_start_reg;
    // 计数器使能
    reg         cnt_ena;
    // baud计数器
    reg [12:0]  baud_cnt;
    // bit计数器
    reg [3:0]   bit_cnt;
//----------------------------------------------------------------------
    // 数据寄存 + 起始位
    always @(posedge clk, negedge rst_n) begin
        if(!rst_n)
            data_start_reg <= 0;
        else if(valid)
            data_start_reg <= {data, 1'b0};
    end

    // cnt_ena
    always @(posedge clk, negedge rst_n) begin
        if(!rst_n)
            cnt_ena <= 0;
        else if(valid)
            cnt_ena <= 1'b1;
        else if(baud_cnt == BAUD_CNT_MAX && bit_cnt == 4'd8)
            cnt_ena <= 0;
    end

    // baud_cnt
    always @(posedge clk, negedge rst_n) begin
        if(!rst_n)
            baud_cnt <= 0; 
        else if(cnt_ena) begin
            if(baud_cnt == BAUD_CNT_MAX)
                baud_cnt <= 0;
            else
                baud_cnt <= baud_cnt + 13'd1;
        end
    end

    // bit_cnt
    always @(posedge clk, negedge rst_n) begin
        if(!rst_n)
            bit_cnt <= 0;
        else if(cnt_ena && baud_cnt == BAUD_CNT_MAX) begin
            if(bit_cnt == 4'd8)
                bit_cnt <= 0;
            else
                bit_cnt <= bit_cnt + 4'd1;
        end
    end

    // tx
    assign tx = cnt_ena ? data_start_reg[bit_cnt] : 1'b1;
endmodule

对该模块进行简单的波形仿真，让其发送三次数据，分别是8’h01, 8’hab, 8’hff, tb如下：

`timescale 1ps/1ps
module uart_tx_tb;
    reg clk = 1'b1;
    always #10 clk = ~clk;
    reg rst_n = 1'b0;

    reg       valid = 1'b0;
    reg [7:0] data  = 8'd0;

    wire tx;

    initial begin
        #30 rst_n = 1'b1;
        #10;
        #10000;
        uart_send(8'h01);
        uart_send(8'hab);
        uart_send(8'hff);
        #100 $stop(2);// $finish;
    end

    task uart_send;
        input [7:0] send_data;
        begin
            valid <= 1'b1;
            data  <= send_data;
            #20;
            valid <= 1'b0;
            data  <= 8'd0;
            #(20 * 434 * 10);   // 10baud
            #1000;
        end
    endtask

    uart_tx inst_uart_tx (
        .clk   (clk),
        .rst_n (rst_n),
        .valid (valid),
        .data  (data),
        .tx    (tx)
    );

endmodule

波形如下，可以看到，valid信号后，tx端会将数据转化为uart串行数据发送出去，由于data只持续1时钟周期，所以图片看不清楚，三次valid对应的data分别是8’h01, 8’hab, 8’hff：
在这里插入图片描述

效果演示

顶层模块就不细说了，将接收模块的valid+data接到发送模块的valid+data即可
串口软件使用正点原子的XCOM，发送字符串hello world!，接收如下：
在这里插入图片描述

学习就van事了
关注
  • 2
    点赞
  • 踩
  • 14
    收藏
    觉得还不错? 一键收藏
  • 0
    评论
专栏目录
UART串口verilog hdl实现（1）波特率产生模块
yx
07-05 6212
串口通信主要包括三个模块：波特率产生模块、发射模块和接收模块。 本节以波特率为115200bps为例来说明波特率模块设计方法，其余波特率可以以此类推。由于我的开发板上的时钟为50MHz，周期T=20ns，而波特率为115200bps，所以1个bit持续的时间是8.7us，那么每个bit占用的周期数N=(8.7us / 20ns) = 434，所以可以定义一个计数器，每当计数器从0计数到433的时候...
15、 Uart串口通信
冷心为王的博客
09-04 2445
由基础知识知50M系统时钟—波特率为115200条件下传输1bit需要计数个数为434。那么1Byte(串口传输格式为：1bit起始位+8bit数据位+1bit停止位)是不是循环计数10次434就可以传输完毕。观察上图，Buad_Flag信号(通道2)表示了传输1Bit传输的间隔，每遇到1个Buad_Flag=1的信号，数据线上切换1次数据，图中序号①-⑩分别为10bit数据的采样点，采样点处提取数据为0101_0101(0x55)，低位在前。直接上图：图中描述了1Byte数据传输的示意图，重点都在图里！
干货 | 在FPGA上实现UART串口通信
最新发布
dpwkj的博客
06-12 461
UART（Universal Asynchronous Receiver/Transmitter）是一种通信协议，用于在电子设备之间传输数据。它是一种串行通信协议，意味着数据位按顺序一个接一个地传输。
FPGA_Verilog学习之旅（1）---浅谈UART
Coca_Tian的博客
10-31 2360
文章目录前言一、UART是什么？二、UART--协议层1、数据格式2、传输速率三、UART--物理层1、接口标准RS-232标准的串口常见接口类型：DB9四、FPGA--UART硬件设计五、FPGA--UART程序设计1、系统框图2、协议层3、顶层模块RTL Viewer4、Verilog HDL代码实现总结 前言 记录第一次CSDN发帖，开启FPGA学习记录之旅，不定时更新 ------这篇文章主要记录一下：FPGA-UART学习笔记（RS232） 一、UART是什么？ UART（Universal
关于串口波特率的的记录
欢迎来到我的博客
05-31 7074
串口使用 串口波特率
为啥波特率常用115200，115200怎么来的？
qq_57320111的博客
05-29 9773
在现代计算机和嵌入式系统中，晶振频率通常很高，标准晶振频率通常为11.0592 MHz（或者12 MHz），这个频率是由外部晶振提供的，但UART芯片需要的时钟信号频率通常较低。这个波特率的选择主要是基于现代计算机和微控制器的性能和传输速度需求，而且与传统的9600波特率相比，它可以实现更快的数据传输。在UART通讯中，发送方和接收方都需要按照相同的波特率（baud rate）进行工作，同时UART芯片也需要一个稳定的时钟，才能够保证数据的正确传输。波特率（baud rate）指的是每秒钟传输的比特数。
FPGA用verilog HDL实现串口通讯协议
qq_45248833的博客
06-26 3352
串口通信是一种通过串行传输数据的通信方式。它使用单个数据线将数据位逐个传输，而不是同时传输多个数据位。串口通信常用于连接计算机与外部设备，如打印机、调制解调器、传感器等。串口通信一般使用的是异步传输方式，即发送方和接收方的时钟不同步。数据传输时，发送方将数据位、起始位、停止位和校验位按照一定的规则组合成数据帧，然后逐位地通过数据线发送。接收方在接收到起始位后开始接收数据位，并在接收到停止位后完成接收。校验位用于检测数据传输的错误。串口通信有多种标准，常见的包括RS-232、RS-485等。
FPGA实现UART传输
04-25
在本主题中，我们将深入探讨如何使用FPGA（现场可编程门阵列）来实现UART协议。 **UART协议基础知识** UART协议的核心是串行数据传输，它将数据字节转换为串行位流进行发送，并接收串行位流还原为数据字节。UART...
FPGA—UART
12-26
本项目以"FPGA—UART"为主题，旨在讲解如何在FPGA中实现UART功能，包括数据的发送和接收，并将接收到的数据存储到FIFO（First-In-First-Out，先进先出）中。FIFO是一种常见的数据缓冲结构，通过IP核（Intellectual ...
FPGA实现UART代码.rar
11-19
以上是关于“FPGA实现UART代码”的核心知识点，这些内容涵盖了UART通信的基本原理、VERILOG编程技术以及FPGA设计流程。通过理解和掌握这些，你可以自己编写或修改代码，实现符合需求的UART功能。
FPGA中uart代码工程实现
03-07
在本文中，我们将深入探讨如何在FPGA（Field-Programmable Gate Array）中实现UART（通用异步接收发送器）代码，并通过仿真测试确保其功能的正确性。UART是一种常见的串行通信接口，广泛应用于各种设备之间的数据...
基于FPGA的UART设计
05-15
最后，使用VHDL语言描述UART的电路行为，并在FPGA上实现UART的设计。 在UART设计中，VHDL语言扮演着重要角色，它可以描述电路的功能或行为，使得设计者能够更好地理解和优化电路的性能。使用VHDL语言，可以将UART的...
FPGA基础之UART通信
makeflyeasy的博客
06-08 2092
串口协议简介 串口通讯(Universal Asynchronous Receiver/Transmitter，UART)是一种异步传输的通用数据总线，包括了RS232、RS485等接口标准和总线标准，传输简单，将数据在串行通信与并行通信之间转换，可以实现全双工发送和接收。 UART的工作原理是将数据的每一个bit从低到高，依次输出到总线上，其通信协议时序如下： 图1 串口时序 如上图所示，为串口协议进行数据传输的时序状态。一个完整的字节传输包括了1个起始位，8个数据位和1个停止位，总共10位数据来计算。
115200波特率-串口基本知识
热门推荐
smxr
03-16 1万+
串口基础 最近再用安卓做上位机用RS485和组件通信，记录下学到的知识； 115200波特率(bps)：代表1秒可以传送115200 bits的数据。 1T=1024G 1G=1024M 1M=1024KB 1KB=1024B(byte) 1B=8bit 案例：
UART总结与波特率计算方法
qq_42848805的博客
05-05 4710
UART/USART串口通信、波特率。
ZYNQ-FPGA-UART
weixin_48444982的博客
10-19 244
1.异步信号电平检测打两拍，边沿检测打三拍2.接受和发送停止位采集方法3.波特率的理解4.uart发送数据打包结构：起始位0 数据8位 校验位（可有可无） 停止位1问题：1.仿真模块编码时候将输出定义为reg将无法运行仿真，改为wire就好了这是为啥？
FPGA入门 —— FPGA UART 串口通信
m0_51592017的博客
06-07 962
UART 通用异步收发传输器（ Universal Asynchronous Receiver/Transmitter） ，通常称作 UART。UART 是一种通用的数据通信协议，也是异步串行通信口（串口）的总称，它在发送数据时将并行数据转换成串行数据来传输，在接收数据时将接收到的串行数据转换成并行数据。它包括了ch340、 RS232、 RS499、 RS423、 RS422 和 RS485 等接口标准规范和总线标准规范。
Verilog学习笔记（串口RS232，基于野火教程）
欢迎一起交流问题！
05-31 2381
其中SPI和I2C为同步通信接口，双方时钟频率相同。而UART属于异步通信接口，没有统一时钟，靠起始位和终止位来接收数据。上图为 串口的通信方式，可以同时收发（全双工通信）。其中rx负责接收，tx负责发送，每次发送10bit数据（起始位+8bit数据+停止位），从最低位开始发送。波特率为每秒钟传输的码元数量，单位为Bps。而比特率为每秒传输的bit个数，单位为bps。比特率=波特率x单个调制状态对应的二进制数。在串口中比特率=比特率x1。
基于FPGA的UART多字节环回实验verilog代码(含帧头帧尾和解码部分)
芯想是陈的博客
04-09 2273
发送数据为：aa ff 03 00 0E 03 B1 86 10 00 40 01 11 00 00 00 00 00 00 00 11 00 00 00 00 00 11 11 55 CC。链接：https://pan.baidu.com/s/1M_E8hh8MNzZKfbq3mVitig?采用VIVADO开发环境，频率50MHz，波特率 256000，8位数据位，1位停止位。串口接收程序源自正点原子的例程。
评论
添加红包

请填写红包祝福语或标题

个

红包个数最小为10个

元

红包金额最低5元

当前余额3.43元 前往充值 >
需支付：10.00元
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包
实付元
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明：

1.余额是钱包充值的虚拟货币，按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载，可以购买VIP、付费专栏及课程。

余额充值