透明度混合

本文借鉴《Unity Shader入门精要》，算是对自己学习的总结，也希望分享下所学知识~~

透明度混合：
可以实现半透明效果。
使用当前片元的透明度作为混合因子，与已经存储在颜色缓冲中的颜色值进行混合，得到新的颜色。
同时需要关闭深度写入，注意渲染顺序问题。

混合命令：

Blend

这个命令在设置的同时也开启了混合模式，开启之后才能使用混合。
混合是一个逐片元操作。

常用语义：
Blend Off 关闭混合
Blend SrcFactor DstFactor 开启混合，设置混合因子
Blend SrcFactor DstFactor, SrcFactorA DstFactorA
BlendOp BlendOperation

公式：

Blend：目标颜色 = 该片元的颜色乘以SrcFactor + 颜色缓存区内的颜色乘以DstFactor

Factor 因子：
One：1
Zero：0
SrcColor：原像素的颜色值
SrcAlpha：原像素的a值
DstColor：颜色缓冲区的颜色值
DstAlpha：颜色缓冲区的a值
OneMinusSrcColor：1-原像素的颜色值
OneMinusSrcAlpha：1-原像素的a值
OneMinusDstColor：1-颜色缓冲区的颜色值
OneMinusDstAlpha：1-颜色缓冲区的a值

BlendOperation：
Add：混合后的颜色相加
Sub：混合后的颜色相减
RevSub：反过来，目标颜色减去原颜色
Min：原颜色和目标颜色每个分量的最小值
MAX：原颜色和目标颜色每个分量的最大值

常用：
Blend SrcAlpha OneMinusSrcAlpha 正常透明度混合
Blend OneMinusDstColor One 柔和相加

代码如下：

Shader "AlphaBlend"
{
	Properties
	{
		_Color ("Main Tint", Color) = (1, 1, 1, 1)
		_MainTex ("Texture", 2D) = "white" {}
		_AlphaScale ("Alpha Scale", Range(0, 1)) = 1 //控制透明度
	}
	SubShader
	{
		Tags 
		{ 
			"Queue" = "Transparent" //使用Transparent渲染队列
			"IgnoreProjector" = "True" //不受投射器影响
			"RenderType" = "Transparent" //归为Transparent组
		}
		LOD 100

		Pass
		{
			Tags { "LightMode" = "ForwardBase" }

			ZWrite Off
			Blend SrcAlpha OneMinusSrcAlpha//SrcAlpha 代表原像素的a值，OneMinusSrcAlpha 代表1-目标像素的a值

			CGPROGRAM
			#pragma vertex vert
			#pragma fragment frag
			#include "UnityCG.cginc"
			#include "Lighting.cginc"

			struct v2f
			{
				float4 vertex : SV_POSITION;
				float2 uv : TEXCOORD0;
				float3 worldNormal : TEXCOORD1;
				float3 worldPos : TEXCOORD2;
			};

			fixed4 _Color;
			sampler2D _MainTex;
			float4 _MainTex_ST;
			fixed _AlphaScale;
			
			v2f vert (appdata_base v)
			{
				v2f o;
				o.vertex = UnityObjectToClipPos(v.vertex);
				o.uv = TRANSFORM_TEX(v.texcoord, _MainTex);
				o.worldNormal = UnityObjectToWorldNormal(v.vertex);
				o.worldPos = mul( unity_ObjectToWorld, v.vertex ).xyz;
				return o;
			}
			
			fixed4 frag (v2f i) : SV_Target
			{
				fixed3 worldNormal = normalize( i.worldNormal );
				fixed3 worldLightDir = normalize( UnityWorldSpaceLightDir(i.worldPos) );
				fixed4 texColor = tex2D( _MainTex, i.uv );
				fixed3 albedo = texColor.rgb * _Color.rgb;
				fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz * albedo;
				fixed3 diffuse = _LightColor0.rgb * albedo * max(0, dot(worldNormal, worldLightDir));
				return fixed4(ambient + diffuse, texColor.a * _AlphaScale);//叠加a值
			}
			ENDCG
		}
	}
	Fallback "Transparent/VertexLit"
}

---

注意：
当模型有复杂的遮挡关系，会出现因为排序错误产生的错误透明效果。
可以使用两个 Pass 通道。
第一个 Pass 开启深度写入，但不输出颜色，仅将深入值写入到深度缓冲中。
第二个 Pass 进行正常的透明度混合，因为第一个已经得到了逐像素的正确的深度信息。
得到的结果就是：模型内部不会存在半透明效果，但是模型与背景可以进行正常颜色混合。

代码如下：

...

Pass
{
	ZWrite On //开启深度写入
	ColorMask 0 //设置颜色通道的写掩码，0代表不写入任何颜色通道
}

...

同时这种方式的缺点：浪费性能。

---

一般透明的效果都需要进行双面渲染，因为默认引擎剔除了物体背面。
但是透明的是需要看到内部的。
如果透明度混合需要进行开启双面渲染，不能简单的使用

Cull Off

如果想要得到正确的透明效果，就必须保证正确的渲染顺序。
使用两个 Pass 通道。
第一个只渲染背面。
第二个只渲染正面。

代码如下:

Pass
{
      ...
      Cull Front
      ...
}
Pass 
{
      ...
      Cull Back
      ...
}