遮罩的原理很简单,就是用一张存储着遮罩信息的遮罩纹理来计算出片元的遮罩系数,在之前的高光反射上乘于这个系数,就能得到遮罩效果了。
Shader "Custom/BaseLight&Mask"
{
Properties
{
_Color ("Color", Color) = (1,1,1,1)//物体本身颜色
_MainTex ("Main Tex", 2D) = "white" {}//2D纹理
_BumpMap("Normal Map",2d)="bump"{}//法线贴图
_Specular("Specular Color",Color) = (1,1,1,1)//高光反射颜色
_SpecularScale("Specular Scale",Float) = 1.0//遮罩系数
_SpecularMask("Specular Mask", 2D) = "white"{}//遮罩纹理
_Gloss("Gloss",Range(8.0,256)) = 20//高光反射系数
}
SubShader//子Shader1
{
Tags{"RenderType" = "Opaque" "Queue" = "Geometry"}//渲染类型为不透明物体,渲染队列为默认
Pass
{
Tags{"LightMode" = "ForwardBase"}//光照类型为前向渲染
CGPROGRAM //CG代码块(C FOR Graphics)
#pragma multi_compile_fwdbase //编译指示:前向渲染需要的关键字
#pragma vertex vert//编译指示:顶点着色器
#pragma fragment frag//编译指示:片元着色器
#include "UnityCG.cginc"//预编译,该文件包含了很多UnityShader的基础关键字
#include "Lighting.cginc"//该文件包含了很多关照所需要的关键字
#include"AutoLight.cginc"//光照
fixed4 _Color;//对应属性里的color,精度类型为fixed(最低的)
sampler2D _MainTex;//sampler2D类型,(0~1,0~1)
float4 _MainTex_ST;//固定名称,纹理名+_ST,S为scale,T为偏移量
sampler2D _BumpMap;
float4 _BumpMap_ST;
fixed4 _Specular;
float _Gloss;
float _SpecularScale;
sampler2D _SpecularMask;
struct a2v//由应用程序到顶点着色器
{
float4 vertex:POSITION;//固定名称,顶点位置
float3 normal:NORMAL;//固定,法线
float4 tangent : TANGENT;//切线
float4 texcoord : TEXCOORD0;//纹理0
};
struct v2f//由顶点着色器到片元着色器
{
float4 pos:SV_POSITION;//固定名称,顶点位置
float4 uv:TEXCOORD0;//纹理0的uv坐标
float4 TtoW0:TEXCOORD1;//切线空间到世界空间变换矩阵第一行,用于计算法线贴图
float4 TtoW1:TEXCOORD2;//切线空间到世界空间变换矩阵第二行,用于计算法线贴图
float4 TtoW2:TEXCOORD3;//切线空间到世界空间变换矩阵第三行,用于计算法线贴图
SHADOW_COORDS(4)//阴影处理三剑客其一,4是因为上面已经有4个TEXCOORD了
};
v2f vert(a2v v)//顶点着色器,参数为结构体a2v,会自动引用上面的
{
v2f o;//定义结构体v2f,会传给片元着色器
o.pos = UnityObjectToClipPos(v.vertex);//将坐标从模型空间转换到裁剪空间,也可以用MVP的形式写
o.uv.xy = v.texcoord.xy * _MainTex_ST.xy + _MainTex_ST.zw;//计算纹理贴图坐标
o.uv.zw = v.texcoord.xy * _BumpMap_ST.xy + _BumpMap_ST.zw;//计算法线贴图坐标
TANGENT_SPACE_ROTATION;//UnityCG的一个宏,相当于
/* float3 binormal = cross( normalize(v.normal), normalize(v.tangent.xyz) ) * v.tangent.w;
float3x3 rotation = float3x3(v.tangent.xyz, binormal, v.normal); 计算出由模型空间到切线空间的转换矩阵,由于此处在世界空间下计算,所以没有用到*/
float3 worldPos = mul(unity_ObjectToWorld, v.vertex).xyz;//将顶点坐标由模型空间转换到世界空间,用于之后的计算
fixed3 worldNormal = UnityObjectToWorldNormal(v.normal);//将法线从模型空间转换到世界空间
fixed3 worldTangent = UnityObjectToWorldDir(v.tangent.xyz);//将切线...
fixed3 worldBinormal = cross(worldNormal, worldTangent) * v.tangent.w;//求副切线(副法线),副切线为同时垂直于切线是法线的向量,tangent.w是用来确定方向的
o.TtoW0 = float4(worldTangent.x, worldBinormal.x, worldNormal.x, worldPos.x);//用坐标系构建转换矩阵
o.TtoW1 = float4(worldTangent.y, worldBinormal.y, worldNormal.y, worldPos.y);//用坐标系构建转换矩阵
o.TtoW2 = float4(worldTangent.z, worldBinormal.z, worldNormal.z, worldPos.z);//用坐标系构建转换矩阵,并把世界空间内顶点的位置存放在w分量中,充分利用空间
TRANSFER_SHADOW(o);//阴影三剑客其二
return o;
}
fixed4 frag(v2f i) :SV_Target//片元着色器,SV_Target为固定名称,语义绑定,标记着色器输出
{
float3 worldPos = float3(i.TtoW0.w,i.TtoW1.w,i.TtoW2.w);
fixed3 lightDir = normalize(UnityWorldSpaceLightDir(worldPos));//得到世界空间下的光照方向并归一化
fixed3 viewDir = normalize(UnityWorldSpaceViewDir(worldPos));//得到世界空间下视线方向并归一化
fixed3 bump = UnpackNormal(tex2D(_BumpMap, i.uv.zw));//用内置函数对法线纹理进行采样和解码(因为坐标系方向问题)
bump = normalize(half3(dot(i.TtoW0.xyz, bump), dot(i.TtoW1.xyz, bump), dot(i.TtoW2.xyz, bump)));//通过点乘实现将法线从法线空间转换到世界空间(需要推理)
fixed3 albedo = tex2D(_MainTex, i.uv.xy).rgb * _Color.rgb;//计算反射率(物体是什么颜色,它就反射什么颜色)
fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz * albedo;//自然光对物体颜色的影响
fixed3 diffuse = _LightColor0.rgb * albedo * max(0, dot(bump, lightDir));//计算漫反射光对物体颜色的影响
fixed3 halfDir = normalize(lightDir + viewDir);//取视线和光照中间方向并归一化(半角向量)
fixed specularMask = tex2D(_SpecularMask, i.uv).r * _SpecularScale;//计算遮罩系数
fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(max(0, dot(bump, halfDir)), _Gloss)*specularMask;//计算法线纹理下的高光反射,此处为blinn-phong模型
UNITY_LIGHT_ATTENUATION(atten, i, worldPos);//计算光照衰减的内置函数(内部用了渐变纹理)
return fixed4(ambient + (diffuse + specular) * atten, 1.0);//返回物体颜色
}
ENDCG
}
Pass{
Tags{"LightMode" = "ForwardAdd"}//标记该Pass会计算额外的像素光源,一个光源一个Pass
Blend One One //设置混合模式,都为1的混合因子
CGPROGRAM
#pragma multi_compile_fwdadd //前向渲染计算额外光照所需
//pragma multi_compile_fwdadd_fullshadows //可以给点光源和聚光灯增加阴影
#pragma vertex vert
#pragma fragment frag
#include "Lighting.cginc"
#include"AutoLight.cginc"
fixed4 _Color;
sampler2D _MainTex;//sampler2D类型,(0~1,0~1)
float4 _MainTex_ST;//固定名称,纹理名+_ST,S为scale,T为偏移量
sampler2D _BumpMap;
float4 _BumpMap_ST;
fixed4 _Specular;
float _Gloss;
float _SpecularScale;
sampler2D _SpecularMask;
struct a2v//由应用程序到顶点着色器
{
float4 vertex:POSITION;//固定名称,顶点位置
float3 normal:NORMAL;//固定,法线
float4 tangent : TANGENT;//切线
float4 texcoord : TEXCOORD0;//纹理0
};
struct v2f//由顶点着色器到片元着色器
{
float4 pos:SV_POSITION;//固定名称,顶点位置
float4 uv:TEXCOORD0;//纹理0的uv坐标
float4 TtoW0:TEXCOORD1;//切线空间到世界空间变换矩阵第一行,用于计算法线贴图
float4 TtoW1:TEXCOORD2;//切线空间到世界空间变换矩阵第二行,用于计算法线贴图
float4 TtoW2:TEXCOORD3;//切线空间到世界空间变换矩阵第三行,用于计算法线贴图
SHADOW_COORDS(4)//阴影处理三剑客其一,4是因为上面已经有4个TEXCOORD了
};
v2f vert(a2v v)//顶点着色器,参数为结构体a2v,会自动引用上面的
{
v2f o;//定义结构体v2f,会传给片元着色器
o.pos = UnityObjectToClipPos(v.vertex);//将坐标从模型空间转换到裁剪空间,也可以用MVP的形式写
o.uv.xy = v.texcoord.xy * _MainTex_ST.xy + _MainTex_ST.zw;//计算纹理贴图坐标
o.uv.zw = v.texcoord.xy * _BumpMap_ST.xy + _BumpMap_ST.zw;//计算法线贴图坐标
// TANGENT_SPACE_ROTATION;//UnityCG的一个宏,相当于
/* float3 binormal = cross( normalize(v.normal), normalize(v.tangent.xyz) ) * v.tangent.w;
float3x3 rotation = float3x3(v.tangent.xyz, binormal, v.normal); 计算出由模型空间到切线空间的转换矩阵,由于此处在世界空间下计算,所以没有用到*/
float3 worldPos = mul(unity_ObjectToWorld, v.vertex).xyz;//将顶点坐标由模型空间转换到世界空间,用于之后的计算
fixed3 worldNormal = UnityObjectToWorldNormal(v.normal);//将法线从模型空间转换到世界空间
fixed3 worldTangent = UnityObjectToWorldDir(v.tangent.xyz);//将切线...
fixed3 worldBinormal = cross(worldNormal, worldTangent) * v.tangent.w;//求副切线(副法线),副切线为同时垂直于切线是法线的向量,tangent.w是用来确定方向的
o.TtoW0 = float4(worldTangent.x, worldBinormal.x, worldNormal.x, worldPos.x);//用坐标系构建转换矩阵
o.TtoW1 = float4(worldTangent.y, worldBinormal.y, worldNormal.y, worldPos.y);//用坐标系构建转换矩阵
o.TtoW2 = float4(worldTangent.z, worldBinormal.z, worldNormal.z, worldPos.z);//用坐标系构建转换矩阵,并把世界空间内顶点的位置存放在w分量中,充分利用空间
TRANSFER_SHADOW(o);//阴影三剑客其二
return o;
}
fixed4 frag(v2f i) :SV_Target//片元着色器,SV_Target为固定名称,语义绑定,标记着色器输出
{
float3 worldPos = float3(i.TtoW0.w,i.TtoW1.w,i.TtoW2.w);
fixed3 lightDir = normalize(UnityWorldSpaceLightDir(worldPos));//得到世界空间下的光照方向并归一化
fixed3 viewDir = normalize(UnityWorldSpaceViewDir(worldPos));//得到世界空间下视线方向并归一化
fixed3 bump = UnpackNormal(tex2D(_BumpMap, i.uv.zw));//用内置函数对法线纹理进行采样和解码(因为坐标系方向问题)
bump = normalize(half3(dot(i.TtoW0.xyz, bump), dot(i.TtoW1.xyz, bump), dot(i.TtoW2.xyz, bump)));//通过点乘实现将法线从法线空间转换到世界空间(需要推理)
fixed3 albedo = tex2D(_MainTex, i.uv.xy).rgb * _Color.rgb;//计算反射率(物体是什么颜色,它就反射什么颜色)
// fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz * albedo;//其他光源不再计算自然光
fixed3 diffuse = _LightColor0.rgb * albedo * max(0, dot(bump, lightDir));//计算漫反射光对物体颜色的影响
fixed3 halfDir = normalize(lightDir + viewDir);//取视线和光照中间方向并归一化
fixed specularMask = tex2D(_SpecularMask, i.uv).r * _SpecularScale;//计算遮罩系数
fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(max(0, dot(bump, halfDir)), _Gloss)* specularMask;//计算法线纹理下的高光反射,此处为blinn-phong模型
UNITY_LIGHT_ATTENUATION(atten, i, worldPos);//计算光照衰减的内置函数(内部用了渐变纹理),这里面同时计算了阴影
return fixed4((diffuse + specular) * atten, 1.0);//返回物体颜色
}
ENDCG
}
}
FallBack "Specular"
}
和基础光照的区别其实不大,因为只对高光反射部分进行了处理。因为透明的东西一般都反光,这里我就没有加入透明混合了。
遮罩之前的效果。
遮罩之后的效果。
可以明显看到遮罩部分的高光减少很多。