[译]Unity3D Shader教程（六）Basic Transparency

---

原文链接：
Shader Tutorials by Ronja

---

除了只是在屏幕上绘制颜色之外，我们还可以保留一些以前在屏幕上的颜色，使物体看起来透明。 我将解释我们如何在没有照明的基本着色器中实现这种效果。要了解如何实现透明度，我建议您了解编写着色器的基础知识，如果没有这方面的知识建议先看之前的教程。
本篇的Shader是在《[译]Unity3D Shader教程（四）Basic Shader》中Shader的基础上修改的。

为了使透明物体正确渲染，我们必须告诉 unity 此物体是透明的。 我们通过更改渲染类型和渲染队列来达到此目的。 通过更改队列，我们可以保证透明材质的渲染时间晚于不透明材质。 如果透明物体和不透明材质同时渲染的话，透明物体后面的不透明物体将不得不覆盖透明物体，完全覆盖它。
更改为透明材质的渲染队列代码如下：

Tags{ "RenderType"="Transparent" "Queue"="Transparent"}

接下来我们定义“Blend Mode 混合模式”，它定义了现有颜色和新颜色如何相互混合。 混合模式由 2 个关键字定义，第一个定义与新颜色相乘的值，第二个定义与旧颜色相乘的值。 将颜色相乘后，将它们相加并绘制结果。
渲染不透明材质时，混合模式为 1 0(Blend 1 0)，因为我们采用所有新值而没有旧值。 在透明材质中，我们希望基于 alpha 值（颜色rgba中的第 4 个数字a）进行混合。 所以我们将第一个混合值设置为源透明度(source alpha)，在这种情况下，源透明度是此着色器的输出。 第二个值是 1 - 源透明度。
混合模式可以在SubShader或Pass中定义，但必须在 hlsl 区域之外。

Blend SrcAlpha OneMinusSrcAlpha

您可以在Unity官方文档查找不同的混合因子（以及我将要介绍的其他一些混合属性）。
接下来我们将举两个例子来说明。
当我们的片段着色器返回 0.5 的 alpha 值时，混合将采用新颜色的一半和旧颜色的 1 - 0.5 (0.5)，将它们平均混合（在黑色上绘制白色时，它将是中灰色）。
当我们的片段着色器返回 0.9 的 alpha 值时，混合将使用 90% 的新颜色并添加 10% 的旧颜色，使旧颜色几乎不可见。
通过这些更改，我们的着色器已经可以用于透明材质。 因为我们在片段着色器中保留了 alpha 通道，所以我们可以设置色调颜色的 alpha，它将是材质的 alpha（假设使用的纹理不包含alpha 通道）。

我们在这里要做的另一件小事是禁止深度(z)写入。 通常当一个物体被渲染时，它会将它与相机的距离写入深度缓冲区，以告诉它后面的其他物体不要在此物体上面绘制。 但是，这不适用于透明对象，因为透明对象不会完全遮挡它们后面的所有东西（为了满足这一点，首先渲染距离相机最远的物体，然后依次渲染最远的对象，直到最后渲染最近的对象，这个 unity已经自动帮我们完成了，所以我们不必担心）。 是否写入 深度缓冲区可以在SubShader或Pass中定义。

Blend SrcAlpha OneMinusSrcAlpha
ZWrite Off

当我们的纹理确实有一个 alpha 通道时，这个着色器也将使用此alpha通道，并且物体在纹理上的 alpha 值较低，越透明。

本文完整Shader.

Shader "Tutorial/006_Basic_Transparency"{
	Properties{
		_Color ("Tint", Color) = (0, 0, 0, 1)
		_MainTex ("Texture", 2D) = "white" {}
	}

	SubShader{
		Tags{ "RenderType"="Transparent" "Queue"="Transparent"}

		Blend SrcAlpha OneMinusSrcAlpha
		ZWrite off

		Pass{
			CGPROGRAM

			#include "UnityCG.cginc"

			#pragma vertex vert
			#pragma fragment frag

			sampler2D _MainTex;
			float4 _MainTex_ST;

			fixed4 _Color;

			struct appdata{
				float4 vertex : POSITION;
				float2 uv : TEXCOORD0;
			};

			struct v2f{
				float4 position : SV_POSITION;
				float2 uv : TEXCOORD0;
			};

			v2f vert(appdata v){
				v2f o;
				o.position = UnityObjectToClipPos(v.vertex);
				o.uv = TRANSFORM_TEX(v.uv, _MainTex);
				return o;
			}

			fixed4 frag(v2f i) : SV_TARGET{
				fixed4 col = tex2D(_MainTex, i.uv);
				col *= _Color;
				return col;
			}

			ENDCG
		}
	}
}

博主本文博客链接。