UnityShader初级篇——实现逐顶点高光反射光照模型

1.实现高光反射光照模型

公式：

高光反射光照值 = (光的颜色和强度 * 高光反射系数) * pow(saturate(dot(视角方向 ，反射方向)), 高光范围系数)；

反射方向 = reflect(入射方向，法线方向);

Shader "Unity Shaders Book/Chapter 6/Specular Vertex-Level"
{
	Properties
	{
		_Diffuse ("Diffuse", Color) = (1,1,1,1)
		//控制高光反射的颜色
		_Specular("Specular", Color) = (1,1,1,1)
		//控制高光区域的大小
		_Gloss("Gloss", Range(8.0,256)) = 20
	}
	SubShader
	{
		Pass
		{
		      //指明光照模式
		       Tags {"LightMode"="ForwardBase"}
		       
			CGPROGRAM
			#pragma vertex vert
			#pragma fragment frag
			//包含引用的内置文件
			#include "Lighting.cginc"

			//声明properties中定义的属性
			fixed4 _Diffuse;
			fixed4 _Specular;
			float _Gloss;

			//定义输入与输出的结构体
			struct a2v
			{
				float4 vertex : POSITION;
				float3 normal : NORMAL;
			};

			struct v2f
			{
				float4 pos : SV_POSITION;
				fixed3 color : CORLOR;
			};

			//在顶点着色器中，计算包含高光反射的光照模型
			v2f vert (a2v v)
			{
				v2f o;
				//转换顶点坐标到裁剪空间
				o.pos = UnityObjectToClipPos(v.vertex);
				//获取环境光
				fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz;

				//转换模型法线坐标到世界空间并归一化
				fixed3 worldNormal = normalize(mul(v.normal, (float3x3)_World2Object));
				//获取光源方向
				fixed3 worldLightDir = normalize(_WorldSpaceLightPos0.xyz);
				//计算漫反射光照
				fixed3 diffuse = _LightColor0.rgb * _Diffuse.rgb * saturate(dot(worldNormal,worldLightDir));

				//获取反射方向（入射方向就是光源方向的反方向）
				fixed3 reflectDir = normalize(reflect(-worldLightDir, worldNormal));
				//获取视角方向
				fixed3 viewDir = normalize(_WorldSpaceCameraPos.xyz - mul(_Object2World, v.vertex).xyz);

				//计算高光光照
				fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(saturate(dot(viewDir,reflectDir)),_Gloss);
				o.color = ambient + diffuse + specular;
				return o;
			}
			
			fixed4 frag (v2f i) : SV_Target
			{
				return fixed4(i.color,1.0);
			}
			ENDCG
		}
	}

	Fallback"Specular"
}