【UnityShader入门精要】从简单的shader编写到基础光照

最新推荐文章于 2024-05-05 14:40:21 发布
最新推荐文章于 2024-05-05 14:40:21 发布
阅读量778 收藏 16
点赞数 16
分类专栏： UnityShader入门精要 文章标签： 游戏引擎 游戏 游戏程序 unity
版权声明：本文为博主原创文章，遵循 CC 4.0 BY-SA 版权协议，转载请附上原文出处链接和本声明。
本文链接：https://blog.csdn.net/weixin_47309438/article/details/137423721
版权

温(mian)馨(ze)提(sheng)示(ming):

  1. 此文内容质量差，仅作为个人学习过程记录
  2. 所有内容在UnityShader入门精要上都有

unity中的shader

最简单的VS/FS

创建一个材质和shader，并且赋给一个球，可以看到现在场景如图下：

打开此shader写个最简单的vs/fs：

可以看到现在只有白色，fs这里什么都没干，只是单纯设置了个颜色

稍微修改一下代码，增加输入输出的结构以及增加属性：

Shader "Custom/simple_youyider"
{
    Properties
    {
        _Color ("Color Tint",Color)=(1.0,1.0,1.0,1.0)
    }
    SubShader
    {
        Pass
        {
            CGPROGRAM

            #pragma vertex vert
            #pragma fragment frag

            fixed4 _Color;

            struct a2v
            {
                float4 vertex:POSITION;
                float3 normal:NORMAL;
                float4 texcoord:TEXCOORD0;
            };

            struct v2f
            {
                float4 pos:SV_POSITION;
                fixed3 color:COLOR0;
            };
            
            v2f vert(a2v v)
            {
                v2f o;
                o.pos=UnityObjectToClipPos(v.vertex);
                o.color=v.normal*0.5+fixed3(0.5,0.5,0.5);
                return o;
            }

            fixed4 frag(v2f i):SV_Target
            {
                fixed3 c=i.color;
                c*=_Color.rgb;
                return fixed4(c,1.0);
            }
            
            ENDCG
        }
    }
}

这里在vs输出颜色时，通过法线进行了颜色的设置，因此不同的法线方向的shading point的颜色也不一样。虽然fs看似加了更改，但是_color都是1，fs依然是输入什么颜色就输出什么颜色

可以得到：

通过假色彩图像debug

这里vs的代码debug的话应该是只写一个color的赋值的，这边写在一起可以看到最后的输出很诡异哈哈哈

值得一提的是if中出现了两个内置函数：any() 函数是一个逻辑函数，用于判断括号内的条件表达式是否有任何一个元素为真；saturate() 函数用于将输入的值限制在 [0, 1] 的范围内

Shader "Custom/falsecolor"
{
    SubShader
    {
        pass
        {
        CGPROGRAM

        #pragma vertex vert
        #pragma fragment frag

        #include "UnityCG.cginc"

        struct v2f
        {
                float4 pos:SV_POSITION;
                fixed4 color:COLOR0;
        };
        v2f vert(appdata_full v)
        {
            v2f o;
            o.pos=UnityObjectToClipPos(v.vertex);

            o.color=fixed4(v.normal*0.5+fixed3(0.5,0.5,0.5),1.0);

            o.color=fixed4(v.tangent.xyz*0.5+fixed3(0.5,0.5,0.5),1.0);
            
            fixed3 binormal=cross(v.normal,v.tangent.xyz)*v.tangent.w;
            o.color=fixed4(binormal*0.5+fixed3(0.5,0.5,0.5),1.0);

            o.color=fixed4(v.texcoord.xy,0.0,1.0);

            o.color=fixed4(v.texcoord1.xy,0.0,1.0);

            o.color=frac(v.texcoord);
            if(any(saturate(v.texcoord)-v.texcoord))
            {
                o.color.b=0.5;
            }
            o.color.a =1.0;

            o.color=frac(v.texcoord1);
            if(any(saturate(v.texcoord1)-v.texcoord1))
            {
                o.color.b=0.5;
            }
            o.color.a =1.0;

            return o;
        }

        fixed4 frag(v2f i):SV_Target
        {
            return i.color;
        }
        ENDCG
        }
    }
}

这里右边开启了帧调试器，可以在里面看到各个步骤的输出和数据

unity的基础光照

实现Gouraud shading的漫反射

值得一提的是 fixed3 worldNormal=normalize(mul(v.normal,(float3x3)unity_WorldToObject));我们知道法线在坐标变换的时候会变形，这就需要用到顶点变换矩阵的逆转置矩阵来获得法线该有的样子。由于这里是要把法线从局部坐标变为世界坐标，所以unity_WorldToObject是局部变世界坐标的逆矩阵，然后可以看到代码中mul函数是向量在左，矩阵在右，放在左边是为了实现同矩阵转置后右乘向量的一样效果。经过上面两步我们就获得了需要的逆转置矩阵。

Shader "Custom/DiffuseVertexLevel_youyider"
{
    Properties
    {
        _Diffuse("Diffuse",Color)=(1,1,1,1)
    }
    SubShader
    {
        pass
        {
            Tags{"LightMode"="ForwardBase"}
            CGPROGRAM

            #pragma vertex vert
            #pragma fragment frag

            #include"Lighting.cginc"

            fixed4 _Diffuse;
            
            struct a2v
            {
                float4 vertex:POSITION;
                float3 normal:NORMAL;
            };

            struct v2f
            {
                float4 pos:SV_POSITION;
                fixed3 color:COLOR;
            };

            v2f vert(a2v v)
            {
                v2f o;
                o.pos=UnityObjectToClipPos(v.vertex);

                fixed3 ambient=UNITY_LIGHTMODEL_AMBIENT.xyz;

                fixed3 worldNormal=normalize(mul(v.normal,(float3x3)unity_WorldToObject));
                fixed3 worldLight=normalize(_WorldSpaceLightPos0.xyz);
                fixed3 diffuse=_LightColor0.rgb*_Diffuse.rgb*saturate(dot(worldNormal,worldLight));

                o.color=ambient+diffuse;

                return o;
            }

            fixed4 frag(v2f i):SV_Target
            {
                return fixed4(i.color,1.0);
            }
            ENDCG
        }

    }
    Fallback"Diffuse"
}

可以看到结果是这个样子

实现Phong shading的漫反射

这里的实现和上面的区别其实就是把上面在vs进行的颜色计算变道fs中

Shader "Custom/DiffusePixelLevel_youyider"
{
    Properties
    {
        _Diffuse("Diffuse",Color)=(1,1,1,1)
    }
    SubShader
    {
        pass
        {
            Tags{"LightMode"="ForwardBase"}
            CGPROGRAM

            #pragma vertex vert
            #pragma fragment frag

            #include"Lighting.cginc"

            fixed4 _Diffuse;
            
            struct a2v
            {
                float4 vertex:POSITION;
                float3 normal:NORMAL;
            };

            struct v2f
            {
                float4 pos:SV_POSITION;
                float3 worldNormal:TEXCOORD0;
            };

            v2f vert(a2v v)
            {
                v2f o;
                o.pos=UnityObjectToClipPos(v.vertex);

                o.worldNormal=mul(v.normal,(float3x3)unity_WorldToObject);

                return o;
            }

            fixed4 frag(v2f i):SV_Target
            {
                fixed3 ambient=UNITY_LIGHTMODEL_AMBIENT.xyz;
                
                fixed3 worldNormal=normalize(i.worldNormal);

                fixed3 worldLightDir=normalize(_WorldSpaceLightPos0.xyz);

                fixed3 diffuse=_LightColor0.rgb*_Diffuse.rgb*saturate(dot(worldNormal,worldLightDir));

                fixed3 color=ambient+diffuse;

                return fixed4(color,1.0);
            }
            ENDCG
        }

    }
    FallBack "Diffuse"
}

可以看到逐像素着色的阴影更细腻，逐顶点的有不平滑的地方（左下角亮面和暗面的交界处可以看到区别）

实现halfLambert光照

兰伯特光照模型是一种描述物体表面如何反射光线的模型，它假设物体表面是完全漫反射的，也就是说，光线会均匀地向所有方向反射。

然而，兰伯特模型有一个问题，那就是当光线与物体表面的夹角接近90度时，反射的光线会变得非常暗，这在某些情况下可能会导致不真实的效果。为了解决这个问题，人们提出了半兰伯特光照模型。

半兰伯特光照模型的主要思想是将兰伯特模型的反射强度曲线稍微调整一下，使得当光线与物体表面的夹角接近90度时，反射的光线不会变得太暗。这样可以使得物体表面在各种光照条件下都能保持一定的亮度，从而得到更真实的效果。

在实际应用中，半兰伯特光照模型常常用于游戏和动画的渲染，因为它可以在保持计算效率的同时，提供比兰伯特模型更好的视觉效果。

修改的地方非常少：

Shader "Custom/HalfLambert_youyider"
{
    Properties
    {
        _Diffuse("Diffuse",Color)=(1,1,1,1)
    }
    SubShader
    {
        pass
        {
            Tags{"LightMode"="ForwardBase"}
            CGPROGRAM

            #pragma vertex vert
            #pragma fragment frag

            #include"Lighting.cginc"

            fixed4 _Diffuse;
            
            struct a2v
            {
                float4 vertex:POSITION;
                float3 normal:NORMAL;
            };

            struct v2f
            {
                float4 pos:SV_POSITION;
                float3 worldNormal:TEXCOORD0;
            };

            v2f vert(a2v v)
            {
                v2f o;
                o.pos=UnityObjectToClipPos(v.vertex);

                o.worldNormal=mul(v.normal,(float3x3)unity_WorldToObject);

                return o;
            }

            fixed4 frag(v2f i):SV_Target
            {
                fixed3 ambient=UNITY_LIGHTMODEL_AMBIENT.xyz;
                
                fixed3 worldNormal=normalize(i.worldNormal);

                fixed3 worldLightDir=normalize(_WorldSpaceLightPos0.xyz);

                fixed halfLambert=dot(worldNormal,worldLightDir)*0.5+0.5;
                fixed3 diffuse=_LightColor0.rgb*_Diffuse.rgb*halfLambert;

                fixed3 color=ambient+diffuse;

                return fixed4(color,1.0);
            }
            ENDCG
        }

    }
    FallBack "Diffuse"
}

这个其实就只是在fs中的diffuse项上稍作修改，可以看到shader的改动或许不大，但是效果却可能因为一行或两行代码而发生很大的区别，即使他们每个步骤都几乎一样

实现Gouraud shading的镜面反射

这里的代码不只有逐顶点的镜面反射，还包含了逐顶点的漫反射

Shader "Custom/SpecularVertexLevel_youyider"
{
    Properties
    {
        _Diffuse("Diffuse", Color) = (1,1,1,1)
        _Specular("Specular",Color)=(1,1,1,1)
        _Gloss("Gloss",Range(8.0,256))=20
    }
    SubShader
    {
        Pass
        {
        Tags { "LightMode"="ForwardBase" }

        CGPROGRAM

            #pragma vertex vert
            #pragma fragment frag

            #include"Lighting.cginc"

            fixed4 _Diffuse;
            float _Gloss;
            fixed4 _Specular;
        
            struct a2v
            {
                float4 vertex:POSITION;
                float3 normal:NORMAL;
            };

            struct v2f
            {
                float4 pos:SV_POSITION;
                fixed3 color:COLOR;
            };

            v2f vert(a2v v)
            {
                v2f o;
                o.pos=UnityObjectToClipPos(v.vertex);

                fixed3 ambient=UNITY_LIGHTMODEL_AMBIENT.xyz;

                fixed3 worldNormal=normalize(mul(v.normal,(float3x3)unity_WorldToObject));
                fixed3 worldLightDir=normalize(_WorldSpaceLightPos0.xyz);

                fixed3 diffuse=_LightColor0.rgb*_Diffuse.rgb*saturate(dot(worldNormal,worldLightDir));

                fixed3 reflectDir=normalize(reflect(-worldLightDir,worldNormal));
                fixed3 viewDir=normalize(_WorldSpaceCameraPos.xyz-mul(unity_ObjectToWorld,v.vertex).xyz);

                fixed3 specular=_LightColor0.rgb*_Specular.rgb*pow(saturate(dot(reflectDir,viewDir)),_Gloss);

                o.color = ambient + diffuse +specular;
                return o;
            }

            fixed4 frag(v2f i):SV_Target
            {
                return fixed4(i.color,1.0);
            }
        ENDCG
        }
    }
    FallBack "Specular"
}

效果图如下：

实现Phong shading的镜面反射

直接放代码：

Shader "Custom/SpecularPixelLevel_youyider"
{
    Properties
    {
        _Diffuse("Diffuse", Color) = (1,1,1,1)
        _Specular("Specular",Color)=(1,1,1,1)
        _Gloss("Gloss",Range(8.0,256))=20
    }
    SubShader
    {
        Pass
        {
        Tags { "LightMode"="ForwardBase" }

        CGPROGRAM

            #pragma vertex vert
            #pragma fragment frag

            #include"Lighting.cginc"

            fixed4 _Diffuse;
            float _Gloss;
            fixed4 _Specular;
        
            struct a2v
            {
                float4 vertex:POSITION;
                float3 normal:NORMAL;
            };

            struct v2f
            {
                float4 pos:SV_POSITION;
                float3 worldNormal:TEXCOORD0;
                float3 worldPos:TEXCOORD1;
            };

            v2f vert(a2v v)
            {
                v2f o;
                o.pos=UnityObjectToClipPos(v.vertex);

                o.worldNormal=mul(v.normal,(float3x3)unity_WorldToObject);

                o.worldPos=mul(unity_ObjectToWorld,v.vertex).xyz;

                return o;
            }

            fixed4 frag(v2f i):SV_Target
            {                
                fixed3 ambient=UNITY_LIGHTMODEL_AMBIENT.xyz;

                fixed3 worldNormal=normalize(i.worldNormal);
                fixed3 worldLightDir=normalize(_WorldSpaceLightPos0.xyz);

                fixed3 diffuse=_LightColor0.rgb*_Diffuse.rgb*saturate(dot(worldNormal,worldLightDir));

                fixed3 reflectDir=normalize(reflect(-worldLightDir,worldNormal));
                fixed3 viewDir=normalize(_WorldSpaceCameraPos.xyz-i.worldPos.xyz);

                fixed3 specular=_LightColor0.rgb*_Specular.rgb*pow(saturate(dot(reflectDir,viewDir)),_Gloss);

                return fixed4(ambient + diffuse +specular,1.0);
            }
        ENDCG
        }
    }
    FallBack "Specular"
}

实现Blinn-Phong光照模型

前面的镜面反射已经是加上了漫反射，但是在高光反射的时候计算了反射方向，通过Blinn光照模型使用视角方向和光照方向相加并且归一化得到，这样的计算量没有之前的计算量那么费。

代码如下：

Shader "Custom/BlinnPhong_youyider"
{
    Properties
    {
        _Diffuse("Diffuse", Color) = (1,1,1,1)
        _Specular("Specular",Color)=(1,1,1,1)
        _Gloss("Gloss",Range(8.0,256))=20
    }
    SubShader
    {
        Pass
        {
        Tags { "LightMode"="ForwardBase" }

        CGPROGRAM

            #pragma vertex vert
            #pragma fragment frag

            #include"Lighting.cginc"

            fixed4 _Diffuse;
            float _Gloss;
            fixed4 _Specular;
        
            struct a2v
            {
                float4 vertex:POSITION;
                float3 normal:NORMAL;
            };

            struct v2f
            {
                float4 pos:SV_POSITION;
                float3 worldNormal:TEXCOORD0;
                float3 worldPos:TEXCOORD1;
            };

            v2f vert(a2v v)
            {
                v2f o;
                o.pos=UnityObjectToClipPos(v.vertex);

                o.worldNormal=mul(v.normal,(float3x3)unity_WorldToObject);

                o.worldPos=mul(unity_ObjectToWorld,v.vertex).xyz;

                return o;
            }

            fixed4 frag(v2f i):SV_Target
            {                
                fixed3 ambient=UNITY_LIGHTMODEL_AMBIENT.xyz;

                fixed3 worldNormal=normalize(i.worldNormal);
                fixed3 worldLightDir=normalize(_WorldSpaceLightPos0.xyz);

                fixed3 diffuse=_LightColor0.rgb*_Diffuse.rgb*saturate(dot(worldNormal,worldLightDir));

                fixed3 viewDir=normalize(_WorldSpaceCameraPos.xyz-i.worldPos.xyz);
                fixed3 halfDir=normalize(worldLightDir+viewDir);

                fixed3 specular=_LightColor0.rgb*_Specular.rgb*pow(max(dot(halfDir,worldNormal),0),_Gloss);

                return fixed4(ambient + diffuse +specular,1.0);
            }
        ENDCG
        }
    }
    FallBack "Specular"
}

效果如下：

YouYider
关注
  • 16
    点赞
  • 踩
  • 16
    收藏
    觉得还不错? 一键收藏
  • 0
    评论
专栏目录
Unity Shader初步编写
weixin_45081191的博客
02-24 860
Shader中CG代码结构理解
Unity Shader入门学习（1）：基础shader
ljylmly的博客
12-02 6683
1.基础光照shader+贴图 Shader "01"{//这里指定的路径与名字与文件名名不要求一致 Properties{//属性 //格式：属性名（显示出来的属性名，类型）=默认值 _Color("Color",Color) = (1,1,1,1)//颜色 _Specular("Specular",Color) = (1,1,1,1)//高光颜色 _Gloss("Gloss",Range(8.0,256)) = 20//光泽度。（cos角的指数）。一般大于10 _MainT.
Unity Shader 入门书籍高清完整版PDF
01-29
Unity Shader的入门书籍,讲得很好,由浅入深,适合初学者
Unity Shader 入门精要——第6章Unity中的基础光照
weixin_38844255的博客
05-05 163
反射方向可通过表面法线、光源方向信息计算得到。假设这些矢量都是单位向量。计算高光反射需要知道的信息比较多，如表面法线(
Unity Shader入门精要 第六章——Unity中的基础光照
buzhengli的博客
07-21 1818
逐像素光照，以每个像素为基础，得到它的法线（可以是对顶点法线插值得到的，也可以是从法线纹理中采样得到的），然后进行光照模型计算，这种在面片之间对顶点法线进行插值的技术称为Phong着色，也被称为Phong插值或法线插值技术，这不同于Phong光照模型。上面两个模型(也叫兰伯特光照模型)有个问题就是，光照没有照射到的地方是全黑的，没有明暗变化，导致背面就像是有个平面一样。与原来的兰伯特光照模型相比，半兰伯特光照模型没有使用max操作来防止n*I的点积为负值，而是进行了一个α倍的缩放和β大小的偏移。
Unity可视化Shader工具ASE介绍——2、ASE的Shader创建和输入输出
阿赵的博客
10-07 1042
上一篇介绍了ASE的安装和编辑器界面分布，这一篇主要是通过一个简单的例子介绍shader的创建和输入输出。
unity3D中通过代码修改模型模型半透明度，并动态修改模型半透明度效果
qq_38753193的博客
04-20 1332
学习在Unity中怎么创建shader，实现模型半透明效果，同时从C#代码中获取shader中的参数进行不透明度的修改。下一期讲解模型中如果有很复杂的贴图，非常多的材质的情况下，如何在UnityEditor中一键生成并替换对应的shader材质，将原本的材质替换为新的、挂载自己的shader脚本的材质球prefabs.
UnityShader入门精要学习笔记
01-12
UnityShader入门精要学习笔记UnityShader入门精要学习笔记
unity shader 入门精要 读书笔记1
03-01
unity shader 入门精要 读书笔记1 提供前8章的一些概念，中英文信息
《Unity Shader入门精要》源代码.rar
最新发布
05-20
《Unity Shader入门精要》源代码 《Unity Shader入门精要》源代码 《Unity Shader入门精要》源代码
Unity Shader入门教程（一）
ali013719291765的博客
07-21 3018
参考文献：http://www.360doc.com/content/13/0923/15/12282510_316492286.shtml Unity Shader是着色器，将纹理、网格信息输入，得到材质的一段程序，具体是个什么东西，还需要亲自实践才知道。一个Unity大神推荐我：如果要学计算机图形编程（游戏编程的基础），可以先学习UnityShader，往后再学习OpenGL...
第一章 创建一个shader
唐僧的专栏
02-08 704
创建一个shader 什么是Shader Shader（着色器）是一段能够针对3D对象进行操作、并被GPU所执行的程序。Shader并不是一个统一的标准，不同的图形接口的Shader并不相同。OpenGL的着色语言是GLSL， NVidia开发了Cg，而微软的Direct3D使用高级着色器语言（HLSL）。而Uni...
学习Shader Unity Shader 基础
i我的丢丢呢的博客
09-29 2137
Unity Shader 基础;如何充分利用 Unity Shader 来为我们的游戏增光添彩;Unity 中的材质;Unity 中的 Shader;Unity Shader 的形式;Unity Shader 答疑解惑;
U3D_Shader编程（第一篇：快速入门篇）
热门推荐
VRunSoftYanlz的博客
05-19 1万+
《U3D_Shader编程》##《U3D_Shader编程》发布说明：++++Shader一个高大上的领域，不管怎么样，我来了。++++立钻哥哥从2018年开始正式对Shader进行战略布局。++++《U3D_Shader编程》将从零开始，循序渐进探索，还是先探索一段时间吧，后期根据需要再推出一个精品博文，这篇就算一个杂谈吧。##《U3D_Shader编程》目录：#第一篇：快速入门篇#第二篇：基础...
自己写Shader—【shader的几种制作思路】
suixinger_lmh的随笔
04-27 967
制作二维效果时： 可以对UI组件(Image)上挂载新的shader材质来实现效果。注意：需要写shader时对UI做一些特殊支持【否则一些UI的特性会覆盖掉，例如mask遮挡无效等。】 可以提取unity默认UI/Default的shader内容来修改。 可以通过屏幕后效的方式来实现效果。 方式： 相机挂载脚本，实现OnRenderImage(RenderTexture source, RenderTexture destination)函数。在函数里对shader赋值和对纹理的计算等。 直接通过s
Unity Shader学习6 —— Unity创建一个Shader
linshuhe1的专栏
09-14 9261
Unity引擎是一个非常强大的支持跨平台开发的游戏引擎，基于Mono这个开源.Net的框架设计而成，在Unity中定义了ShaderLab来组织Shader的内容，针对不同平台进行编译。了解了Shader和Cg的一些基础知识之后，接下来我们要做的就是：学会如何在Unity中使用Cg编写Shader并实现一些简单的Shader效果。Unity Shader：说到底，Shader其实只是一段规定好输入（
零基础入门Unity Shader（一）
Technical Art
10-21 1640
前言 Shader，中文名为着色器，对很多开发者来说它是一个神秘的存在，想学但是又不知道如何去学，或者学了一段时间发现Get不到它的点，始终感觉游离在外，无法开窍。 那么本专栏（Unity技术美术）在前几篇介绍了美术资源标准后，打算接下来花一些篇章来讲下如何从零基础入门Shader，目的在于让初学Shader的程序或者美术可以快速进入这个丰富多彩的世界。 什么是Shader 虽然上面有简单的说了下...
unity中创建的四种系统shader
Gxy_w的博客
12-14 2612
仅为个人理解！勿喷 1、Unlit Shader 会产生一个不包含光照，但是包含雾效的基础顶点/片元着色器。 2、Image Effect Shader 实现各种屏幕后处理效果提供了一个基础模板，可在此模板上进行修改。 3、Compute Shader 会产生一种特殊的Shader文件，一般在利用GPU的并行性来进行一些与常规的渲染流水线无关的计算。一般在做渲染的时候，不会创建这类文件，当然，具情况而定！ 4、Standard Surface Shader 有典型的表面着色器的实现方法。 当然，我们在游戏当
unity-shader（入门）
qq_50682713的博客
07-13 7136
Legacy Shaders/Particles/Additive 实现部分叠加效果,并非完全叠加,没有Addtive明亮,颜色更加接近贴图自身的颜色。 半透渲染效果。 Sprites/Diffuse 使图像接受全局光
unity shader入门精要
07-08
Unity Shader是一种用于渲染图形的程序，它可以控制对象的表面颜色、纹理、透明度、反射等属性，从而实现特殊的视觉效果。对于游戏开发者来说，掌握Shader编写技巧是非常重要的。 以下是关于Unity Shader的入门精要： 1. ShaderLab语言 ShaderLab是Unity中用于编写Shader的语言，它是一种基于标记的语言，类似于HTML。ShaderLab可以用于定义Shader的属性、子着色器、渲染状态等信息。 2. CG语言 CG语言是Unity中用于编写Shader的主要语言，它是一种类似于C语言的语言，可以进行数学运算、向量计算、流程控制等操作。CG语言可以在ShaderLab中嵌入，用于实现Shader的具体逻辑。 3. Unity的渲染管线 Unity的渲染管线包括顶点着色器、片元着色器、几何着色器等组件，每个组件都有不同的作用。顶点着色器用于对对象的顶点进行变换，片元着色器用于计算每个像素的颜色，几何着色器用于处理几何图形的变形和细节等。 4. 模板和纹理 在Shader中，我们可以使用纹理来给对象添加图案或者贴图，也可以使用模板来控制对象的透明度、反射等属性。纹理可以通过内置函数tex2D()来获取，模板可以通过内置函数clip()来实现裁剪。 5. Shader的实现 Shader的实现需要注意以下几点： - 在ShaderLab中定义Shader的属性、子着色器、渲染状态等信息。 - 在CG语言中实现Shader的具体逻辑，包括顶点着色器、片元着色器等内容。 - 使用纹理和模板来实现特定的视觉效果。 - 在对象上应用Shader，通过调整Shader的属性来达到不同的效果。 以上是关于Unity Shader的入门精要，希望对你有所帮助。如果你想更深入地了解Shader的编写技巧，可以参考官方文档或者相关教程。

“相关推荐”对你有帮助么？

  • 非常没帮助
  • 没帮助
  • 一般
  • 有帮助
  • 非常有帮助
提交
评论
添加红包

请填写红包祝福语或标题

个

红包个数最小为10个

元

红包金额最低5元

当前余额3.43元 前往充值 >
需支付：10.00元
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包
实付元
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明：

1.余额是钱包充值的虚拟货币，按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载，可以购买VIP、付费专栏及课程。

余额充值