在世界空间坐标系下计算光照,用于需要Cubemap环境映射时。
顶点着色器中需要计算切线空间转换成世界空间的变换矩阵
切线空间下计算光照
顶点着色器要干些什么:
MVP变换
uv.xy记载贴图纹理坐标,zw记录法线纹理坐标缩放
光照方向、视角方向变换到切线空间下
片元着色器要干些什么:
光源方向和观察点方向归一化
从凹凸纹理中获取法线的纹理值
纹理值从【0,1】像素变换成【-1,1】法线值(UnpackNormal)
计算
世界空间下计算光照
顶点着色器中需要干的事:
MVP变换
uv缩放和位移
计算世界空间坐标系下的法线切线副切线顶点坐标
用矩阵存储以上四个值
片元着色器中需要干的事:
获取世界空间坐标系下的顶点坐标
光源方向和观察点方向归一化
从凹凸纹理中获取法线的纹理值
纹理值从【0,1】像素变换成【-1,1】法线值(UnpackNormal)
(多出来的一步)用上面的矩阵把法线从切线空间转换到世界空间中
计算
// Upgrade NOTE: replaced '_Object2World' with 'unity_ObjectToWorld'
Shader "Custom/2"
{
Properties
{
_Color("Color",Color) = (1,1,1,1)
_MainTex("Main Tex",2D) = "white"{}
_BumpTex("Bump Tex",2D) = "bump"{}
_BumpScale("Bump Scale",float) = 1.0
_Specular("Specular",Color) = (1,1,1,1)
_Gloss("Gloss",Range(8.0,256)) = 20
}
SubShader
{
pass
{
Tags{"LightMode" = "ForwardBase"}
CGPROGRAM
#pragma vertex vert
#pragma fragment frag
#include "Lighting.cginc"
fixed4 _Color;
sampler2D _MainTex;
sampler2D _BumpTex;
float4 _MainTex_ST;
float4 _BumpTex_ST;
float _BumpScale;
fixed4 _Specular;
float _Gloss;
struct a2v
{
float4 vertex : POSITION;
float3 normal : NORMAL;
float4 tangent : TANGENT;
float4 texcoord : TEXCOORD0;
};
struct v2f
{
float4 pos : SV_POSITION;
float4 uv : TEXCOORD0;
float4 TtoW0 : TEXCOORD1;
float4 TtoW1 : TEXCOORD2;
float4 TtoW2 : TEXCOORD3;
};
v2f vert (a2v v)
{
v2f o;
o.pos = UnityObjectToClipPos(v.vertex);
o.uv.xy = v.texcoord.xy * _MainTex_ST.xy + _MainTex_ST.zw;
o.uv.zw = v.texcoord.xy * _BumpTex_ST.xy + _BumpTex_ST.zw;
float3 worldPos = mul(unity_ObjectToWorld,v.vertex).xyz;
fixed3 worldNormal = UnityObjectToWorldNormal(v.normal);
fixed3 worldTangent = UnityObjectToWorldDir(v.tangent.xyz);
fixed3 worldBinormal = cross(worldNormal, worldTangent) * v.tangent.w;
o.TtoW0 = float4(worldTangent.x,worldBinormal.x,worldNormal.x,worldPos.x);
o.TtoW1 = float4(worldTangent.y,worldBinormal.y,worldNormal.y,worldPos.y);
o.TtoW2 = float4(worldTangent.z,worldBinormal.z,worldNormal.z,worldPos.z);
//三行三列是变换矩阵,第四列是世界坐标系下顶点坐标
return o;
}
fixed4 frag(v2f i): SV_Target
{
float3 worldPos = float3(i.TtoW0.w, i.TtoW1.w,i.TtoW2.w);
fixed3 lightDir = normalize(UnityWorldSpaceLightDir(worldPos));
fixed3 viewDir = normalize(UnityWorldSpaceViewDir(worldPos));
fixed3 bump = UnpackNormal(tex2D(_BumpTex,i.uv.zw));
//得到切线空间下的法线方向
bump.xy *= _BumpScale;
bump.z = sqrt(1.0 - saturate(dot(bump.xy,bump.xy)));
//sqrt() 用来求给定值的平方根
//dot()点积
//如果x取值小于0,则返回值为0。如果x取值大于1,则返回值为1
bump = normalize(half3(dot(i.TtoW0.xyz, bump), dot(i.TtoW1.xyz, bump), dot(i.TtoW2.xyz, bump)));
//法线变换到世界空间中
//点乘操作 变换矩阵每一行和法线相乘
//此时法线变换成世界空间坐标
fixed3 albedo = _Color.rgb * tex2D(_MainTex,i.uv).rgb;
fixed3 diffuse = _LightColor0.rgb * albedo * max(0, dot(bump, lightDir));
fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz * albedo;
fixed3 halfDir = normalize(lightDir + viewDir);
fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(max(0, dot(bump, halfDir)), _Gloss);
return fixed4(ambient + diffuse + specular, 1.0);
}
ENDCG
}
}
FallBack "Specular"
}
变换矩阵这里是线代的问题(头晕
后面再看吧。。
这里用float4存储多一个世界坐标系顶点位置,为了节省资源。
UnpackNormal一定要先将纹理设置成normal map类型
如果是高度图,则需要勾选Create from Grayscale
Bumpiness用于控制凹凸程度
Filtering中Smooth法线纹理更平滑 Sharp。