‘10010’序列检测器的两种实现方法（有限状态机、移位寄存器）

已于 2024-08-06 23:24:48 修改
阅读量4.2w 收藏 389
点赞数 103
分类专栏： FPGA设计与调试 文章标签： verilog fpga 单片机 序列检测
于 2021-01-12 02:10:25 首次发布
版权声明：本文为博主原创文章，遵循 CC 4.0 BY-SA 版权协议，转载请附上原文出处链接和本声明。
本文链接：https://blog.csdn.net/wuzhikaidetb/article/details/112505075
版权

1、序列检测器？

         序列检测器指的就是将一个指定的序列（以‘10010’为例）从数字码流中识别出来，是一个经典的数字电路实例。通常的序列检测方法有2种：有限状态机法（FSM）；移位寄存器法。

        序列检测还分为重复检测和非重复检测。假设在输入码流“10010010”中进行重复检测，则会在检测到第一个“10010”和第二个“10010”后分别拉高输出表示成功检测；若非重复检测则只在检测到第一个“10010”拉高输出。

        接下来就几种情况分别进行说明并提供代码、仿真及仿真结果说明。

2、有限状态机法

        FSM（有限状态机）又可分为两种，根据状态机的输出是否与输入条件相关，可将状态机分为两大类，即摩尔(Moore)型状态机和米勒(Mealy) 型状态机。可参考FPGA状态机（一段式、二段式、三段式）、摩尔型（Moore）和米勒型（Mealy）

  • Moore 状态机：组合逻辑的输出只取决于当前状态，而与输入状态无关。
  • Mealy 状态机：输出不仅取决于当前状态，还取决于输入状态。

2.1、Moore 状态机

        先将状态转移图贴出：

  • IDLE：初始状态，对输入的码流进行检测，若为1则跳转到状态A，则为0保留在该状态
  • A： 对输入的码流进行检测，若为0则跳转到状态B（10），则为1保留在该状态
  • B： 对输入的码流进行检测，若为0则跳转到状态C（100），则为1则跳转到状态A（101）
  • C： 对输入的码流进行检测，若为1则跳转到状态D（1001），则为0则跳转到状态IDLE（1000）
  • D： 对输入的码流进行检测，若为0则跳转到状态E（10010），则为1则跳转到状态A（10011）
  • E： 此时已经成功检测到了序列”10010“，可以拉高输出。
    • 重复检测：然后对输入的码流进行检测，若为0则跳转到状态C（100_100，后面的100可视为新的一轮检测），则为1则跳转到状态A（10010_1）
    • 非重复检测：然后对输入的码流进行检测，若为0则跳转到状态IDLE（10010_0，后面的100不可视为新的一轮检测），则为1则跳转到状态A（10010_1）

2.1.1、Verilog代码

        根据状态转移图可编写Verilog代码如下：需要注意的是，将是否进行重复检测设为了参数REPEAT，1--重复检测；0--非重复检测，提供程序复用性。

//检测序列“10010”，使用三段式Moore型状态机
module seqdet_moore
#(
	parameter	REPEAT = 1'b1		//1--重复检测；0--非重复检测
)
( 
	input 		x		,			//输入
	input		clk		, 			//时钟
	input		rst_n	,			//复位信号，低电平有效
	output 	reg	z					//输出采用时序逻辑，避免毛刺
);
//reg define
reg [2:0] 	cur_state	,			//现态
			next_state	;			//状态
//parameter define
localparam 	IDLE = 3'd0,
			A	 = 3'd1, 
			B	 = 3'd2,
			C	 = 3'd3, 
			D	 = 3'd4,
			E	 = 3'd5;

//三段式状态机第1段
always @(posedge clk or negedge rst_n)begin
	if(!rst_n)
		cur_state <= IDLE;
	else             
		cur_state <= next_state;
end
//三段式状态机第2段
always@(*)begin
	next_state = IDLE;
	case(cur_state)
		IDLE:	next_state = x ? A : IDLE;	
		A	:	next_state = x ? A : B;		
		B	:	next_state = x ? A : C;		
		C	:	next_state = x ? D : IDLE;	
		D	:	next_state = x ? A : E;		
		E	:	next_state = REPEAT ? (x ? A : C) : (x ? A : IDLE);		
		default:next_state = IDLE;
	endcase
end
//三段式状态机第3段
always @(posedge clk or negedge rst_n)begin
	if(!rst_n)
		z <= 1'b0;	
	else
		case(cur_state)
			E		:	z <= 1'b1;	
			default	:	z <= 1'b0;	
		endcase
end

endmodule

2.1.2、testbench

        在测试代码我们分别例化两个检测模块，一个用来检测重复输出，另一个用来检测非重复输出。

//检测序列“10010”，使用三段式Moore型状态机
`timescale 1ns/1ns

module tb_seqdet_moore;

reg		x		;
reg 	clk		; 
reg		rst_n	;

wire	z1		;			//重复检测输出结果
wire	z0		;			//非重复检测输出结果

parameter	REPEAT1 = 1'b1;	//重复检测
parameter	REPEAT0 = 1'b0; //非重复检

initial begin
 	clk = 1'b1;
 	rst_n <= 1'b0;
	x <= 1'b0;
 	#30 rst_n<=1; 						//拉高复位信号
	forever	#20	x <= ({$random} % 2);	//生成1bit的随机数
end

always #10 clk <= ~clk; 				//时钟信号50M
 
//例化序列检测器模块--重复检测
seqdet_moore
#(
	.REPEAT	(REPEAT1	)
)
seqdet_moore_isnt1( 
	.x		(x			),
	.clk	(clk		), 
	.rst_n	(rst_n		),
	.z		(z1			)	
);
//例化序列检测器模块--非重复检测
seqdet_moore
#(
	.REPEAT	(REPEAT0	)
)
seqdet_moore_isnt0( 
	.x		(x			),
	.clk	(clk		), 
	.rst_n	(rst_n		),
	.z		(z0			)	
);

endmodule

2.1.3、仿真结果

        仿真结果如下：

        可以看到重复检测的结果比非重复检测的结果还是多一些的，接下来选取几个典型的局部：

         上图中，成功检测到序列”10010“,因为后续输入不满足条件，所以不存在重复检测。检测到序列 ”10010“后系统进入状态E，在状态E拉高输出表示一次成功的检测，由于输出采用时序逻辑，输出会延迟一个时钟周期，所以总体看来，Moore状态机的输出要落后序列 ”10010“1个时钟周期。

        重复检测的结果如下：

         上图中，输入码流为”10010_010“，在重复检测模式中，后面的10010又组成了一次成功的序列输入，所以一共输出两次成功检测标志；而非重复检测标志则只输出一次成功检测标志。

2.2、Mealy 状态机

        Mealy 状态机的输出不仅取决于当前状态，还取决于输入状态。所以在检测到序列”1001“后，若下一个输入为0则会拉高输出；若下一个输入为1则无输出。据此可以画出状态转移图如下：

  • IDLE：初始状态，对输入的码流进行检测，若为1则跳转到状态A，则为0保留在该状态
  • A： 对输入的码流进行检测，若为0则跳转到状态B（10），则为1保留在该状态
  • B： 对输入的码流进行检测，若为0则跳转到状态C（100），则为1则跳转到状态A（101）
  • C： 对输入的码流进行检测，若为1则跳转到状态D（1001），则为0则跳转到状态IDLE（1000）
  • D： 对输入的码流进行检测，则为1则跳转到状态A（10011）；若为0则成功检测到了序列”10010“，可以拉高输出。
    • 重复检测：则跳转到状态E（100_10，后面的10可视为新的一轮检测）
    • 非重复检测：则跳转到状态IDLE（10010_，开始新的一轮检测）

2.2.1、Verilog代码

        根据状态转移图可编写Verilog代码如下：需要注意的是，将是否进行重复检测设为了参数REPEAT，1--重复检测；0--非重复检测，提供程序复用性。

//检测序列“10010”，重复检测，使用三段式Mealy型状态机
module seqdet_mealy
#(
	parameter	REPEAT = 1'b1		//1--重复检测；0--非重复检测
)
( 
	input 		x		,			//输入
	input		clk		,   		//时钟
	input		rst_n	,   		//复位信号，低电平有效
	output 	reg	z					//输出采用时序逻辑，避免毛刺
);		
//reg define		
reg [2:0] 	cur_state	,   		//现态
			next_state	;			//状态
//parameter define
localparam 	IDLE= 3'd0,
			A	= 3'd1, 
			B	= 3'd2,
			C	= 3'd3, 
			D	= 3'd4;
//三段式状态机第1段
always @(posedge clk or negedge rst_n)begin
	if(!rst_n)
		cur_state <= IDLE;
	else             
		cur_state <= next_state;
end
//三段式状态机第2段
always@(*)begin
	next_state = IDLE;
	case(cur_state)
		IDLE:	next_state = x ? A : IDLE;	
		A	:	next_state = x ? A : B;		
		B	:	next_state = x ? A : C;		
		C	:	next_state = x ? D : IDLE;	
		D	:	next_state = REPEAT ? (x ? A : B) : (x ? A : IDLE);	
		default:next_state = IDLE;
	endcase
end
//三段式状态机第3段
always @(posedge clk or negedge rst_n)begin
	if(!rst_n)
		z <= 1'b0;	
	else begin
		case(cur_state)
			D: begin
				if(x == 1'b0)	//10010
					z <= 1'b1;	
				else			//10011
					z <= 1'b0;	
			end			
			default	:	z <= 1'b0;	
		endcase
	end
end

endmodule

2.2.2、testbench

        在测试代码我们分别例化两个检测模块，一个用来检测重复输出，另一个用来检测非重复输出。

//检测序列“10010”，使用三段式MEALY型状态机
`timescale 1ns/1ns

module tb_seqdet_mealy;

reg		x		;
reg 	clk		; 
reg		rst_n	;

wire	z1		;						//重复检测输出结果
wire	z0		;						//非重复检测输出结果

parameter	REPEAT1 = 1'b1;				//重复检测
parameter	REPEAT0 = 1'b0;             //非重复检测

initial begin
 	clk = 1'b1;
 	rst_n <= 1'b0;
	x <= 1'b0;
 	#30 rst_n<=1; 						//拉高复位信号
	forever	#20	x <= ({$random} % 2);	//生成1bit的随机数
end

always #10 clk <= ~clk; 				//时钟信号50M
 
//例化序列检测器模块--重复检测
seqdet_mealy
#(
	.REPEAT	(REPEAT1	)
)
seqdet_mealy_isnt1( 
	.x		(x			),
	.clk	(clk		), 
	.rst_n	(rst_n		),
	.z		(z1			)	
);
//例化序列检测器模块--非重复检测
seqdet_mealy
#(
	.REPEAT	(REPEAT0	)
)
seqdet_mealy_isnt0( 
	.x		(x			),
	.clk	(clk		), 
	.rst_n	(rst_n		),
	.z		(z0			)	
);

endmodule

2.2.3、仿真结果

        仿真结果如下：

         可以看到重复检测的结果比非重复检测的结果还是多一些的，接下来选取几个典型的局部图：

        在检测到后1001后，接下来的输入为0构成10010所以立即输出成功检测标志。

        重复检测的结果如下：

        上图中，输入码流为”10010_010“，在重复检测模式中，后面的10010又组成了一次成功的序列输入，所以一共输出两次成功检测标志；而非重复检测标志则只输出一次成功检测标志。

3、移位寄存器法

3.1、说明

        移位寄存器法比较简单粗暴，直接使用一个5位的寄存器寄存每一个码流，并在下一个时钟周期对其移位，再与需要的结果（10010）进行对比，根据对比结果输出检测结果。

        非重复检测：最少都是码流”10010——10010“，那么两次成功输出会间隔最少5个时钟。所以我们可以设计一个计数器，当成功检测时将其清零，其他时候递加1。

        实际上重复检测的时候直接输出即可，而非重复检测则需要根据计数器的值进行判断。每次成功输出时需要判断此时计数器的值，若非重复检测则计数器的值应大于等于4（0-4共5个时钟）。

3.2、Verilog代码

        将是否进行重复检测设为了参数REPEAT，1--重复检测；0--非重复检测，编写Verilog代码如下：

//检测序列“10010”，使用移位寄存器法
module seqdet_reg
#(
	parameter	REPEAT = 1'b1			//1--重复检测；0--非重复检测
)                                       
(                                       
	input 		x		,				//输入	
	input		clk		,               //时钟
	input		rst_n	,               //复位信号，低电平有效
	output 	reg	z			            //输出采用时序逻辑，避免毛刺
);

reg	[4:0]	z_reg;						//移位寄存器
reg	[9:0]	cnt;						//计数器，这里位宽设置大点，留点余量1024
reg			first_flag;					//第一次检测标志，拉高则表示已经检测到了第一个“10010”

//将输入向左移位寄存
always @(posedge clk or negedge rst_n)begin
	if(!rst_n)
		z_reg <= 5'd0;	
	else
		z_reg <= {z_reg[3:0],x};		//向左移位
end
//对比结果进行输出
always @(posedge clk or negedge rst_n)begin
	if(!rst_n)begin
		z <= 1'b0;	
		first_flag <= 1'b0;		
		cnt <= 10'd0;	
	end
	else if(REPEAT)begin				//重复检测到序列
			first_flag <= 1'b0;		
			cnt <= 10'd0;	
		if(z_reg == 5'b10010)			//捕捉到10010
			z <= 1'b1;		
		else
			z <= 1'b0;	
	end
	else begin							//非重复检测到序列
		if(z_reg == 5'b10010)begin		//捕捉到10010
			if(!first_flag)begin		//是第一个“10010”
				z <= 1'b1;
				first_flag <= 1'b1;		//拉高标志信号
				cnt <= 10'd0;			//计数器清零
			end
			else begin					//不是第一个“10010”
				if(cnt >= 'd4)begin		//间隔5个时钟以上（0-4）
					z <= 1'b1;
					cnt <= 10'd0;		//计数器清零
					first_flag <= first_flag;		
				end
				else begin
					z <= 1'b0;
					cnt <= cnt + 1;		//计数器累加1	
					first_flag <= first_flag;		
				end
			end
		end
		else begin						//没有捕捉到10010
			z <= 1'b0;
			cnt <= cnt + 1;				//计数器累加1	
			first_flag <= first_flag;		
		end
	end	
end

endmodule

3.3、 testbench

        在测试代码我们分别例化两个检测模块，一个用来检测重复输出，另一个用来检测非重复输出。基本和FSM的tb文件一致。

3.4、仿真结果

        仿真结果见下图：

        方框内都是进行了重复检测的部分，由于重复检测的逻辑比较简单，所以我们只截取重复部分的非重复检测的典型图：

孤独的单刀
关注
专栏目录
序列检测的两种实现方式：状态机与移位寄存器
梅菜扣肉
05-06 1719
背景 序列检查是笔试中常考的编程题 ，如果笔试中没有的话，同一家公司的面试中大概率会在手撕代码环节进行考察，总的来说，序列检测是一个不太困难却又非常重要、易考的知识点。 比较常用的序列检测实现方式是状态机，逻辑清晰，写起来方便。但也见过面试官会问知不知道其他的实现方式，这时他要考察的点其实就是移位寄存器的方式实现，下面将分别介绍两种方式的实现。 我们将以1101的检测为例。 状态机方式实现 ...
10010序列检测器
记录和分享学习和工作过程中的个人总结
05-12 3840
10010序列检测器 重复检测输入，当检测到输入端顺序输入10010序列时，输出为1。 1.使用同步状态机 1.状态转移图 2.Verilog 实现 module detect_10010( input clk, input rst_n, input in_a, output reg detect); parameter S0 = 3'b000, S1 = 3'b001, S2 = 3'b010, S3 = 3'
Xilinx FPGA:vivado状态机实现序列检测
loveyousosad的博客
06-11 217
一、项目内容：检测序列10010。
Verilog -- 序列检测器及其最小状态数
darknessdarkness的博客
03-27 1829
Verilog – 序列检测器 笔试题：序列检测器检测11011001序列，最少需要几个状态？ Mearly 型： State\Input 0 1 IDLE 0\0 1\0 0 0\0 1\0 1 0\0 11\0 11 110\0 11\0 110 0\0 1101\0 1101 0\0 11011\0 11011 110110\0 11\0 11...
FPGA状态机设计详解
weixin_66634995的博客
05-21 1256
• IDLE：初始状态，对输入的码流进行检测，若为1则跳转到状态A，则为0保留在该状态• A: 对输入的码流进行检测，若为0则跳转到状态B（10），则为1保留在该状态• B: 对输入的码流进行检测，若为0则跳转到状态C（100），则为1则跳转到状态A（101）• C: 对输入的码流进行检测，若为1则跳转到状态D（1001），则为0则跳转到状态IDLE（1000）• D: 对输入的码流进行检测，若为0则跳转到状态E（10010），则为1则跳转到状态A（10011）
FPGA——状态机
Morzart的博客
01-07 2302
首先，FPGA是Field Programmable Gate Array的简写，翻译过来就是“现场可编程门阵列”。它是一个集成电路，可以对其反复配置以执行无限多的功能。具体而言，FPGA就是由可编程逻辑功能块和可编程I/O模块排成阵列组成，并由可编程的内部连线连接这些逻辑功能块和I/O模块来实现不同的设计，而一般来说，现在都是用的Verilog来进行这些方面的编程。
10010序列检测
06-23
检测串行输入代码流中10010特定序列的verilog代码
FPGA状态机详解
居安士的博客
02-05 8189
本篇文章介绍了状态机原理，Mealy和Moore状态机分类，一段式状态机与三段式状态机写法，并用流水灯举例分析了一段式状态机和三段式状态机的异同
FPGA实现序列检测器两种实现方式（状态机+移位寄存器）
10-29
在FPGA中，序列检测器的实现有多种方法，其中状态机和移位寄存器是两种常用的技术。本文将深入探讨这两种实现方式，并阐述它们的工作原理和优缺点。 一、状态机实现 1. 工作原理：状态机实现序列检测器的核心是...
vivado关于1101011的同步时钟状态机、移位寄存器的序列检测器的设计
12-24
在数字电路设计中，同步时钟状态机和移位寄存器是两个核心概念，尤其在Verilog这样的硬件描述语言中，它们常用于构建复杂的数字系统。本设计任务旨在使用Vivado工具来实现一个针对特定序列“1101011”的检测器，这个...
FSM.rar_register fsm_序列检测器_移位寄存器 FSM
09-24
总之，有限状态机结合移位寄存器的序列检测器是一种强大的工具，它能够有效地识别和处理二进制数据中的特定模式。这种技术在数字系统设计中具有重要的实用价值，特别是在需要实时监控和解析数据流的场合。
1001序列检测器（mealy机）
04-04
利用JK触发器设计，输入一段信号，每当检测到1001后输出高电压。
FPGA-状态机
FG的博客
01-19 298
理论知识 状态机，全称：同步有限状态机(FSM)，同步，指的是状态跳转是在时钟的控制下进行；有限，指的是状态的个数有限。 分为两类： Moore型状态机：输出时只与状态有关 Mealy型状态机：输出时不止于状态有关，和输入也有关 可以用状态机图来表示整个系统的结构流程，十分的好用。 在程序的编写中，会有如下三种编码： 独热码：最适合高速系统，但是占用的寄存器资源比较多，有多少个状态就要有多少个位宽 二进制码：位宽用的少，但是不适合告诉系统，一般不用 格雷码：相邻状态只有1位不一样，性能折中的码 ...
FPGA状态机
最新发布
weixin_56416791的博客
08-28 175
【代码】FPGA状态机。
【FPGA】状态机
weixin_43778388的博客
12-26 2601
【 1、状态机 1.1、理论 FPGA不同于CPU的一点特点就是CPU是顺序执行的，而FPGA是同步执行（并行）的。那么FPGA如何处理明显具有时间上先后顺序的事件呢？这个时候我们就需要使用到状态机了。 状态机简写为 FSM（Finite State Machine），也称为同步有限状态机，我们一般简称为状态机，之所以说“同步”是因为状态机中所有的状态跳转都是在时钟的作用下进行的，而“有限”则是说状态的个数是有限的。状态机的每一个状态代表一个事件，从执行当前事件到执行另一事件我们称之为状态的跳转或状
verilog写一个10010序列检测器，用FSM状态机实现
04-01
以下是一个使用FSM状态机实现的Verilog代码，用于检测输入序列10010： ``` module sequence_detector( input clk, // 时钟信号 input reset, // 复位信号 input data_in, // 输入数据信号 output reg detected // 检测到序列的信号 ); // 定义状态 typedef enum logic [1:0] { IDLE, // 空闲状态 STATE1, // 检测到1状态 STATE2, // 检测到10状态 STATE3, // 检测到100状态 STATE4 // 检测到1001状态 } state_t; // 定义当前状态和下一个状态信号 reg [1:0] state, next_state; // 定义状态转移条件 always @(*) begin case(state) IDLE: if(data_in == 1) next_state = STATE1; else next_state = IDLE; STATE1: if(data_in == 0) next_state = IDLE; else next_state = STATE2; STATE2: if(data_in == 1) next_state = STATE3; else next_state = IDLE; STATE3: if(data_in == 0) next_state = STATE4; else next_state = STATE2; STATE4: if(data_in == 1) next_state = STATE3; else next_state = IDLE; endcase end // 定义状态更新 always @(posedge clk or posedge reset) begin if(reset) state <= IDLE; else state <= next_state; end // 定义检测到序列的输出信号 always @(state) begin if(state == STATE4) detected = 1; else detected = 0; end endmodule ``` 该代码使用了一个状态转移表来定义状态和状态之间的转移条件。在每个时钟上升沿时，当前状态会根据下一个状态进行更新。如果检测到序列10010，则输出检测到的信号detected为1，否则为0。
评论 37
添加红包

请填写红包祝福语或标题

个

红包个数最小为10个

元

红包金额最低5元

当前余额3.43元 前往充值 >
需支付：10.00元
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包

打赏作者

孤独的单刀

你的鼓励将是我创作的最大动力

¥1 ¥2 ¥4 ¥6 ¥10 ¥20
扫码支付：¥1
获取中
扫码支付

您的余额不足，请更换扫码支付或充值

打赏作者

实付元
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明：

1.余额是钱包充值的虚拟货币，按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载，可以购买VIP、付费专栏及课程。

余额充值