Unity-Shader-镜面高光Phong&BlinnPhong-油腻的师姐在哪里

最新推荐文章于 2024-09-19 00:27:50 发布

李嘉的博客

最新推荐文章于 2024-09-19 00:27:50 发布

阅读量374

点赞数 1

本文链接：https://blog.csdn.net/lijia4423/article/details/87263761

版权

Unity-Shader-镜面高光Phong&BlinnPhong-油腻的师姐在哪里

【旧博客转移 - 2016年4月4日 13:13 】

油腻的师姐：

以前玩过一款很火热的端游《剑灵》，剑灵刚出来的时候，某网页游戏广告视频中有句台词：“我不断的在寻找，有你的世界在哪里”，该广告中的人物，音效都模仿了剑灵，而《剑灵》中的人物模型表面看上去油光发亮，所以就被网友改成了：“我不断的洗澡，油腻的师姐在哪里”

像这样（皮肤表面的高光）

这样

还有~ 这样

其实这是使用了镜面反射着色，除了剑灵，其他很多高品质的AAA级游戏也都使用了不同的镜面高光，来增强视觉冲击力和超现实感。

Phong高光类型

Phong光照模型是图形学中表现很友好的高光类型，是一种非常常见的镜面高光模型，从游戏到电影都有诸多应用

镜面反射跟漫反射的区别就是，漫反射的反射光是很分散的。镜面反射的反射光会集中在一起，

视线离反射光越近，射入我们眼中的光也就越多，反之则看不到反射光

Phong光照计算公式

Spec = pow( max(0 ,cos<R, V>), gloss)

R：反射光向量

V：视线向量

gloss：镜面的光滑程度，gloss越大就表示越光滑

Phong光照模型的Shader实现

Shader "lijia/Phong"
{
    Properties
    {
        _MainTex ("Texture", 2D) = "white" {}
        _Specular("Specular", Range(1, 20)) = 1
        _SpecColor("SpecColor", Color) = (1,1,1,1)
    }
    SubShader
    {
        Tags { "RenderType"="Opaque" }
        LOD 100

        Pass
        {
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag

            #include "UnityCG.cginc"

            struct v2f
            {
                float2 uv : TEXCOORD0;
                float4 vertex : SV_POSITION;
                float3 normal : TEXCOORD1;
                float3 lightDir : TEXCOORD2;
                float4 objPos : TEXCOORD3;
            };

            sampler2D _MainTex;
            float4 _MainTex_ST;

            float4 _LightColor0;

            float _Specular;
            float4 _SpecColor;

            v2f vert (appdata_full v)
            {
                v2f o;
                o.objPos = v.vertex;
                o.vertex = mul(UNITY_MATRIX_MVP, v.vertex);
                o.uv = TRANSFORM_TEX(v.texcoord, _MainTex);
                o.normal = v.normal;
                o.lightDir = ObjSpaceLightDir(v.vertex);//把光向量从世界空间转成模型空间
                return o;
            }

            fixed4 frag (v2f i) : SV_Target
            {
                float3 L = normalize(i.lightDir);
                float3 N = normalize(i.normal);
                float3 viewDir = normalize(ObjSpaceViewDir(i.objPos));//计算出视线

                float diff = saturate(dot(L, N));
                float3 reflection = normalize(2.0 * N * diff - L);//反射向量
                float spec = pow(max(0, dot(reflection, viewDir)), _Specular);
                float3 finalSpec = _SpecColor.rgb * spec;
                //漫反射+镜面高光+环境光
                float3 finalLight = diff * _LightColor0 + finalSpec + UNITY_LIGHTMODEL_AMBIENT;

                fixed4 col = tex2D(_MainTex, i.uv);
                return col * float4(finalLight, 1);
            }
            ENDCG
        }
    }
}