{Unity} Shader初步

官方文档：http://docs.unity3d.com/Manual/ShadersOverview.html

Unity支持三种shader:
1) Surface Shaders: 主要处理光照和阴影，利用了Unity的光照流水线，是一种较高层次的抽象。如果不使用光照则不要使用这种shader，因为会有不必要的性能消耗。使用Cg/HLSL编写shader代码，但最终的shader是需要编译生成的。
2）Vertex and Fragment Shaders: 这个就是一般话的shader了，可以实现任意效果，当然也要处理所有的事情，并且不能利用Unity的光照系统了。同样也使用Cg/HLSL编写。
3）Fixed Function Shaders: 固定功能，只能实现简单效果，且某些平台支持不好，因此已经不推荐使用了，完全使用ShaderLab编写。

ShaderLab：
以上三种shader都需要使用ShaderLab格式封装。基本的结构是：

Shader “MyShader” {
Properties {
_MyTexture (“My Texture”, 2D) = “white” { }
// other properties like colors or vectors go here as well
}
SubShader {
// here goes the ‘meat’ of your
// - surface shader or
// - vertex and fragment shader or
// - fixed function shader
}
SubShader {
// here goes a simpler version of the SubShader above that
// can run on older graphics cards
}
}

核心内容写在SubShader中，根据不同平台从上往下找到可以支持的执行。

代码中动态切换shader:
var sprite_renderer = FooObject.GetComponent ();
sprite_renderer.material.shader = Shader.Find (“Custom/MyNBEffect”);
注意：Shader.Find会去创建Shader,某些平台可能会卡一下，最好把shader预先创建好。方法是在Project Setting/Graphics里面，把自定义shader加入到“Always Included Shaders”里面。

ps:共享一个实用的shader, sprite变灰：

Shader "Custom/SpriteGray"
{
Properties
{
    [PerRendererData] _MainTex ("Sprite Texture", 2D) = "white" {}
    _Color ("Tint", Color) = (1,1,1,1)
    [MaterialToggle] PixelSnap ("Pixel snap", Float) = 0
}

SubShader
{
    Tags
    { 
        "Queue"="Transparent" 
        "IgnoreProjector"="True" 
        "RenderType"="Transparent" 
        "PreviewType"="Plane"
        "CanUseSpriteAtlas"="True"
    }

    Cull Off
    Lighting Off
    ZWrite Off
    Fog { Mode Off }
    Blend One OneMinusSrcAlpha

    Pass
    {
    CGPROGRAM
        #pragma vertex vert
        #pragma fragment frag
        #pragma multi_compile DUMMY PIXELSNAP_ON
        #include "UnityCG.cginc"

        struct appdata_t
        {
            float4 vertex   : POSITION;
            float4 color    : COLOR;
            float2 texcoord : TEXCOORD0;
        };

        struct v2f
        {
            float4 vertex   : SV_POSITION;
            fixed4 color    : COLOR;
            half2 texcoord  : TEXCOORD0;
        };

        fixed4 _Color;

        v2f vert(appdata_t IN)
        {
            v2f OUT;
            OUT.vertex = mul(UNITY_MATRIX_MVP, IN.vertex);
            OUT.texcoord = IN.texcoord;
            OUT.color = IN.color * _Color;
            #ifdef PIXELSNAP_ON
            OUT.vertex = UnityPixelSnap (OUT.vertex);
            #endif

            return OUT;
        }

        sampler2D _MainTex;

        fixed4 frag(v2f IN) : SV_Target
        {
            fixed4 c = tex2D(_MainTex, IN.texcoord) * IN.color;
            c.rgb *= c.a;
            float gray = dot(c.xyz, float3(0.299, 0.587, 0.114));
            c.xyz = float3(gray, gray, gray);
            return c;
        }
    ENDCG
    }
}
}