透明度测试

本文借鉴《Unity Shader入门精要》，算是对自己学习的总结，也希望分享下所学知识~~

透明度测试：
只要一个片元的透明度不满足条件（小于某个阈值），它对应的片元就会被舍弃。
被舍弃的片元不会再进行任何处理，也不会对颜色缓冲产生影响。
否则，就会按照普通的不透明物体处理方式来处理它。

使用函数：

clip，如果给定的参数的任何一个分量是负数，就会舍弃当前像素颜色的输出

代码如下：

Shader "AlphaTest"
{
	Properties
	{
		_Color ("Main Tint", Color) = (1, 1, 1, 1)
		_MainTex ("Texture", 2D) = "white" {}
		_Cutoff ("Alpha Cutoff", Range(0, 1)) = 0.5 //阈值，进行透明度测试的判断条件
	}
	SubShader
	{
		Tags 
		{ 
			"Queue" = "AlphaTest" //使用AlphaTest渲染队列
			"IgnoreProjector" = "True" //不受投射器影响
			"RenderType" = "TransparentCutout" //归为TransparentCutout组
		}
		LOD 100

		Pass
		{
			Tags { "LightMode" = "ForwardBase" }

			Cull Off //关闭剔除功能

			CGPROGRAM
			#pragma vertex vert
			#pragma fragment frag
			#include "UnityCG.cginc"
			#include "Lighting.cginc"

			struct v2f
			{
				float4 vertex : SV_POSITION;
				float2 uv : TEXCOORD0;
				float3 worldNormal : TEXCOORD1;
				float3 worldPos : TEXCOORD2;
			};

			fixed4 _Color;
			sampler2D _MainTex;
			float4 _MainTex_ST;
			fixed _Cutoff;
			
			v2f vert (appdata_base v)
			{
				v2f o;
				o.vertex = UnityObjectToClipPos(v.vertex);
				o.uv = TRANSFORM_TEX(v.texcoord, _MainTex);
				o.worldNormal = UnityObjectToWorldNormal(v.vertex);
				o.worldPos = mul( unity_ObjectToWorld, v.vertex ).xyz;
				return o;
			}
			
			fixed4 frag (v2f i) : SV_Target
			{
				fixed3 worldNormal = normalize( i.worldNormal );
				fixed3 worldLightDir = normalize( UnityWorldSpaceLightDir(i.worldPos) );
				fixed4 texColor = tex2D( _MainTex, i.uv );
				clip( texColor.a - _Cutoff );//检测剔除
				fixed3 albedo = texColor.rgb * _Color.rgb;
				fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz * albedo;
				fixed3 diffuse = _LightColor0.rgb * albedo * max(0, dot(worldNormal, worldLightDir));

				return fixed4(ambient + diffuse, 1.0);
			}
			ENDCG
		}
	}
	Fallback "Transparent/Cutout/VertexLit"
}