shader学习之路——透明度测试

透明度测试：它采用一种“霸道极端”的机制，只要一个片元的透明度不满足条件（通常是小于某个阈值），那么它对应的片元就会被舍弃。被舍弃的片元将不会再进行任何处理，也不会对颜色缓冲产生任何影响；否则，就会按照普通的不透明物体的处理方式来处理它，即进行深度测试、深度写入等。也就是说，透明度测试是不需要关闭深度写入的，他和其他不透明物体最大的不同就是他会根据透明度来舍弃一些片元。虽然建安，但是它产生的效果也很极端，要么完全透明，即看不到，要么完全不透明，就像不透明物体那样。
 

通常，我们会在片元着色器中使用clip函数来进行透明度测试。clip是CG中的要给函数，他的定义如下   void clip(float4 x);void clip(flaot3 x);void clip(flaot2 x);void clip(flaot x);  参数：裁剪是使用的标量或者矢量条件

描述：如果给定参数的任何一个分量是负数，就会舍弃当前像素的输出颜色。它等同于下面的代码

void clip(float4 x){

   if(any(x < 0))

       discard;

}

Shader "Custom/AlphaTestShader" {
	Properties {
		_Color ("Color", Color) = (1,1,1,1)
		_MainTex ("Albedo (RGB)", 2D) = "white"{}
		_Cutoff ("Alpha Cutoff", Range(0,1)) = 0.5 
		//用于决定我们调用clip进行透明度测试时使用的判断条件。范围[0,1]因为透明纹理像素的透明度就在此范围内
	}
	SubShader {
		Tags { "Queue"="AlphaTest" "IgnoreProjector" = "True" "RenderType" = "TransparentCurout" }
		//"RenderType" = "TransparentCurout"  RenderType标签可以让Unity把这个Shader归入到提前定义的组 这里是“TransparentCurout”
		//RenderType 通常被用于着色器替换功能   IgnoreProjector 设置为True代表这个shader不会受投影器（Projectors）的影响
		Pass{
		Tags{"LightMode" = "ForwardBase"}
		CGPROGRAM
		#pragma vertex vert
		#pragma fragment frag
		#include "Lighting.cginc"

		fixed4 _Color;
		fixed _Cutoff;  //由于_Cutoff范围在[0，1]我们用fixed储存它
		sampler2D _MainTex;
		float4 _MainTex_ST;

		struct a2v{
			float4 vertex:POSITION;
			float3 normal:NORMAL;
			float4 texcoord:TEXCOORD0;
		};

		struct v2f{
			float4 pos:SV_POSITION;
			float3 worldNormal:TEXCOORD0;
			float3 worldPos:TEXCOORD1;
			float2 uv:TEXCOORD2;
		};

		v2f vert(a2v v)
		{
			v2f o;
			o.pos = UnityObjectToClipPos(v.vertex);
			o.worldNormal = UnityObjectToWorldNormal(v.normal);
			o.worldPos = mul(unity_ObjectToWorld,v.vertex).xyz;
			o.uv = TRANSFORM_TEX(v.texcoord,_MainTex);//TRANSFORM_TEX方法比较简单,就是将模型顶点的uv和Tiling、Offset两个变量进行运算,计算出实际显示用的定点uv。
			return o;
		}

		fixed4 frag(v2f i):SV_Target
		{
			fixed3 worldNormal = normalize(i.worldNormal);
			fixed3 worldLightDir = normalize(UnityWorldSpaceLightDir(i.worldPos));//UnityWorldSpaceLightDir根据模型世界空间坐标获得世界空间的灯光信息
			fixed4 texColor = tex2D(_MainTex,i.uv);
			clip(texColor.a - _Cutoff); //如果相减为负数则丢弃 相当于 if((texColor.a - _Cutoff) < 0) { discard; }			
			fixed3 albedo = texColor.rgb * _Color.rgb;
			fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz * albedo;//UNITY_LIGHTMODE_AMBIENT获得环境光信息
			fixed3 diffuse = _LightColor0.rgb * albedo * max(0,dot(worldNormal,worldLightDir));
			return fixed4(ambient + diffuse ,1.0);
		}

		ENDCG
		}		
	}
	FallBack "Transparent/Cutout/VertexLit"
}