庄懂着色器_L07_光照构成

庄懂-BoyanTata的个人空间_哔哩哔哩_Bilibili

---

单色环境光-1ColAmbient

一个近似的理解:环境光可以理解为四面八方均匀射过来的单一颜色单一强度的光

既然有环境光,那我们的几何形体,我们的一个形态, 会对环境光产生一个遮挡,任何物体对光都会产生遮挡,环境光也是一样的,它也会受物体的一个遮挡,这个遮挡就是 环境遮挡,也叫 环境闭塞_Ambient Occlusion

我们有一个光,它是环境里面所有光的因素的一个总和,我们将其理解为环境光

AO就是一个对环境光的阻挡

三色环境光-3ColAmbient

天光至少有一个 顶底关系

Normal的绿通道(Y轴)是朝上的,它的值是1到-1,将其乘一个-1,就是朝下的区域,将朝上和朝下的区域取出来,然后甩白色去减这两个区域,就得到了一个周围的区域,就得到了3个遮罩,一个遮罩是头顶,一个是下面,一个是侧面,然后再开放三个参数给美术,将这三个不同部位的颜色用这个遮罩去指定过去,就可以得到一个顶部,侧面,底部三个不一样过渡的环境光了,再用这个环境光去乘以环境遮挡,就得到了一个有颜色变化和顶底关系的环境光了

代码实现三色环境光

代码部分

Shader "AP01/L07/3ColAmbient"
{
    Properties
    {
        _Occlusion  ("环境遮挡图", 2d)      = "white" {}
        _EnvUpCol   ("朝上环境色", color)   = (1.0, 1.0, 1.0, 1.0)
        _EnvSideCol ("侧面环境色", color)   = (0.5, 0.5, 0.5, 1.0)
        _EnvDownCol ("朝下环境色", color)   = (0.0, 0.0, 0.0, 1.0)
    }
   
    SubShader
    {
        Tags { "RenderType"="Opaque"}

        Pass
        {
            Name "FORWARD"
            Tags { "LightMode"="ForwardBase" }

            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            #include "UnityCG.cginc"
            #pragma multi_compile_fwdbase_fullshadows
            #pragma target 3.0

            // 输入参数
            uniform float3 _EnvUpCol;
            uniform float3 _EnvSideCol;
            uniform float3 _EnvDownCol;
            uniform sampler2D _Occlusion;

            // 输入结构
            struct VertexInput
            {
                float4 vertex : POSITION;   // 将模型顶点信息输入进来
                float4 normal : NORMAL;     // 将模型法线信息输入进来
                float2 uv0 : TEXCOORD0;     // 将模型UV信息输入进来 0通道 共4通道
            };

            // 输出结构
            struct VertexOutput
            {
                float4 pos : SV_POSITION;   // 由模型顶点信息换算而来的顶点屏幕位置
                float3 nDirWS : TEXCOORD0;  // 由模型法线信息换算来的世界空间法线信息
                float2 uv : TEXCOORD1;      // 追加UV信息用语像素Shader采样贴图
            };

            // 输入结构>>>顶点Shader>>>输出结构
            VertexOutput vert (VertexInput v)
            {
                VertexOutput o = (VertexOutput)0;               // 新建一个输出结构
                o.pos = UnityObjectToClipPos( v.vertex );       // 变换顶点信息 并将其塞给输出结构
                o.nDirWS = UnityObjectToWorldNormal(v.normal);  // 变换法线信息 并将其塞给输出结构
                o.uv = v.uv0;                                   // 图森破
                return o;                                       // 将输出结构 输出
            }
           
            // 输出结构>>>像素
            float4 frag(VertexOutput i) : COLOR
             {
                // 准备向量
                float3 nDir = i.nDirWS;                         // 获取nDir
                // 计算各部位遮罩
                float upMask = max(0.0, nDir.g);                // 获取朝上部分遮罩
                float downMask = max(0.0, -nDir.g);             // 获取朝下部分遮罩
                float sideMask = 1.0 - upMask - downMask;       // 获取侧面部分遮罩
                // 混合环境色
                float3 envCol = _EnvUpCol * upMask + _EnvSideCol * sideMask + _EnvDownCol * downMask;
                // 采样Occlusion贴图
                float occlusion = tex2D(_Occlusion, i.uv);
                // 计算环境光照
                float3 envLighting = envCol * occlusion;
                // 返回最终颜色
                return float4(envLighting, 1.0);
            }
            ENDCG
        }
    }
    FallBack "Diffuse"
}

Unity自带投影实现

它对方向光是投影,还有一个点光源的范围衰减

方向光没有衰减,点光源才有衰减

代码实现投影

 

代码部分
Shader "AP01/L07/Shadow"
{
    Properties
    {


    }

    SubShader
    {
        Tags {"RenderType"="Opaque"}

        Pass
        {
            Name "FORWARD"

            Tags {"LightMode"="ForwardBase"}

            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            #include "UnityCG.cginc"
            #include "AutoLight.cginc"      // 使用Unity投影必须包含这两个库文件
            #include "Lighting.cginc"       // 同上
            #pragma multi_compile_fwdbase_fullshadows
            #pragma target 3.0

            // 输入结构
            struct VertexInput
            {
                float4 vertex : POSITION;   // 将模型的顶点信息输入进来
            };

            // 输出结构
            struct VertexOutput
            {
                float4 pos : SV_POSITION;   // 由模型顶点信息换算而来的顶点屏幕位置
                LIGHTING_COORDS(0,1)        // 投影用坐标信息 Unity已封装 不用管细节
            };

            // 输入结构>>>顶点Shader>>>输出结构
            VertexOutput vert (VertexInput v)
            {
                VertexOutput o = (VertexOutput)0;           // 新建一个输出结构
                o.pos = UnityObjectToClipPos( v.vertex );   // 变换顶点信息 并将其塞给输出结构
                TRANSFER_VERTEX_TO_FRAGMENT(o)              // Unity封装 不用管细节
                return o;                                   // 将输出结构 输出
            }

            // 输出结构>>>像素
            float4 frag(VertexOutput i) : COLOR
            {
                float shadow = LIGHT_ATTENUATION(i);        // 同样Unity封装好的函数 可取出投影
                return float4(shadow, shadow, shadow, 1.0);
            }
            ENDCG
        }
    }
    FallBack "Diffuse"
}

简化理解光照构成

光照分为两部分,光源与环境,光源可能是太阳光,在引擎内可能是平行光,探照灯,点光源等,有明确位置,方向的光源,我们将其理解为光源,它是光照的一种形式,还有一种,没有办法去描述它的准确位置和准确方向,它就是四方八方到处都存在,它就是一个环境包围着,就是环境光

光源可以用数学去描述,由模型去表达;环境很复杂,没办法用简单的数学模型去表达

无论是光源和环境,它都是光跟物体表面的一个互动,无非就是漫反射与镜面反射

光源里面发出来的光照射到物体表面,也是做漫反射和镜面反射

它的漫反射和镜面反射可能各有自身的BRDF,环境光同理,它照到物体表面,也会反射,也是会分成漫反射和镜面反射,本质都是光,无论是光源发射光还是环境发射光,本质都是光,光跟表面,都是这两种反应,漫反射和镜面反射

光反射的时候,它会有所遮挡,光源的遮挡就是投影,环境光的遮挡就是AO效果

这些光跟表面互动之后,他们结果的一个总和,就是光照

OldSchoolPlus构成

混合细节

ForwardBase

节点练习