庄懂着色器_L13_特效篇

庄懂-BoyanTata的个人空间_哔哩哔哩_Bilibili

---

特效类Shader

透明剪切_AlphaCutout_AC

AC_AlphaTest经常用于卡通风格,一般卡通项目是后处理+抗锯齿+Bloom   

硬边缘比较符合卡通美术风格,后处理可以缓解锯齿,Bloom可以溢出辉光效果

AC没有排序问题,边缘太硬是优点也是缺点(边缘不是0就是1),移动端性能较差

Cutoff 

透贴可能是一个从白到黑的过渡,从哪个灰度算它是透的,从哪个灰度算它不是透的,你就要有一个标准,这个标准就是这个Cutoff的阈值

Shader "AP01/L13/AC"

{

    Properties

    {

        _MainTex ("RGB:颜色 A：透贴", 2d) = "gray"{}

        _Cutoff ("透切阈值", range(0.0, 1.0)) = 0.5

    }

    SubShader

    {

        Tags

        {

            "RenderType"="TransparentCutout"    // 对应改为Cutout

            "ForceNoShadowCasting"="True"       // 关闭阴影投射

            "IgnoreProjector"="True"            // 不响应投射器

        }

        Pass

        {

            Name "FORWARD"

            Tags { "LightMode"="ForwardBase"  }

            CGPROGRAM

            #pragma vertex vert

            #pragma fragment frag

            #include "UnityCG.cginc"

            #pragma multi_compile_fwdbase_fullshadows

            #pragma target 3.0

            // 输入参数

            uniform sampler2D _MainTex; uniform float4 _MainTex_ST;

            uniform half _Cutoff;

            // 输入结构

            struct VertexInput

            {

                float4 vertex : POSITION;       // 顶点位置 总是必要

                float2 uv : TEXCOORD0;          // UV信息 采样贴图用

            };

            // 输出结构

            struct VertexOutput

            {

                float4 pos : SV_POSITION;       // 顶点位置 总是必要

                float2 uv : TEXCOORD0;          // UV信息 采样贴图用

            };

            // 输入结构>>>顶点Shader>>>输出结构

            VertexOutput vert (VertexInput v)

            {

                VertexOutput o = (VertexOutput)0;

                o.pos = UnityObjectToClipPos( v.vertex);    // 顶点位置 OS>CS

                o.uv = TRANSFORM_TEX(v.uv, _MainTex);       // UV信息 支持TilingOffset

                return o;

            }

            // 输出结构>>>像素

            half4 frag(VertexOutput i) : COLOR

            {

                half4 var_MainTex = tex2D(_MainTex, i.uv);      // 采样贴图 RGB颜色 A透贴

                clip(var_MainTex.a - _Cutoff);                  // 透明剪切

                return var_MainTex;                             // 返回值

            }

            ENDCG

        }

    }

}

透明混合_AlphaBlend_AB

排序有问题,不太适合做那种空间关系错杂的效果,可以实现半透明效果

特效上打底用,移动端性能比AC强,边缘效果好

AB不需要Cutoff值

渲染不透明物体,是从前往后渲染

渲染透明物体,是从后往前渲染

SrcFactor 源因子  DstFactor 目标因子

混合有两个主体,A混到B上,要混的物体是源因子A,被混到的物体是目标因子B

无论是源因子还是目标因子,它都是一个图像,它是图像的话它就有RGBA

SrcAlpha就是源因子的A通道

Shader "AP01/L13/AB"
{
    Properties
    {
        _MainTex ("RGB:颜色 A:透贴", 2d) = "gray"{}
        _Opacity ("透明度", range(0, 1)) = 0.5
    }

    SubShader
    {
        Tags
        {
            "Queue"="Transparent"               // 调整渲染顺序
            "RenderType"="Transparent"          // 对应改为Cutout
            "ForceNoShadowCasting"="True"       // 关闭阴影投射
            "IgnoreProjector"="True"            // 不响应投射器
        }

        Pass
        {
            Name "FORWARD"
            Tags { "LightMode"="ForwardBase" }

            Blend One OneMinusSrcAlpha          // 修改混合方式One/SrcAlpha OneMinusSrcAlpha
           
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            #include "UnityCG.cginc"
            #pragma multi_compile_fwdbase_fullshadows
            #pragma target 3.0

            // 输入参数
            uniform sampler2D _MainTex; uniform float4 _MainTex_ST;
            uniform half _Opacity;

            // 输入结构
            struct VertexInput
            {
                float4 vertex : POSITION;       // 顶点位置 总是必要
                float2 uv : TEXCOORD0;          // UV信息 采样贴图用
            };

            // 输出结构
            struct VertexOutput
            {
                float4 pos : SV_POSITION;       // 顶点位置 总是必要
                float2 uv : TEXCOORD0;          // UV信息 采样贴图用
            };

            // 输入结构>>>顶点Shader>>>输出结构
            VertexOutput vert (VertexInput v)
            {
                VertexOutput o = (VertexOutput)0;
                o.pos = UnityObjectToClipPos( v.vertex);    // 顶点位置 OS>CS
                o.uv = TRANSFORM_TEX(v.uv, _MainTex);       // UV信息 支持TilingOffset
                return o;
            }

            // 输出结构>>>像素
            half4 frag(VertexOutput i) : COLOR
            {
                half4 var_MainTex = tex2D(_MainTex, i.uv);      // 采样贴图 RGB颜色 A透贴
                half3 finalRGB = var_MainTex.rgb;
                half opacity = var_MainTex.a * _Opacity;
                return half4(finalRGB * opacity, opacity);                // 返回值
            }
            ENDCG
        }
    }
}

透明叠加_Addtive_AD

特效灵魂手段

Shader "AP01/L13/AD"
{
    Properties
    {
        _MainTex ("RGB:颜色 A:透贴", 2d) = "gray"{}
        _Opacity ("透明度", range(0, 1)) = 0.5
    }

    SubShader
    {
        Tags {
            "Queue"="Transparent"               // 调整渲染顺序
            "RenderType"="Transparent"          // 对应改为Cutout
            "ForceNoShadowCasting"="True"       // 关闭阴影投射
            "IgnoreProjector"="True"            // 不响应投射器
        }

        Pass
        {
            Name "FORWARD"
            Tags { "LightMode"="ForwardBase" }

            Blend One One                       // 修改混合方式
           
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            #include "UnityCG.cginc"
            #pragma multi_compile_fwdbase_fullshadows
            #pragma target 3.0

            // 输入参数
            uniform sampler2D _MainTex; uniform float4 _MainTex_ST;
            uniform half _Opacity;

            // 输入结构
            struct VertexInput
            {
                float4 vertex : POSITION;       // 顶点位置 总是必要
                float2 uv : TEXCOORD0;          // UV信息 采样贴图用
            };
           
            // 输出结构
            struct VertexOutput
            {
                float4 pos : SV_POSITION;       // 顶点位置 总是必要
                float2 uv : TEXCOORD0;          // UV信息 采样贴图用
            };

            // 输入结构>>>顶点Shader>>>输出结构
            VertexOutput vert (VertexInput v)
            {
                VertexOutput o = (VertexOutput)0;
                o.pos = UnityObjectToClipPos( v.vertex);    // 顶点位置 OS>CS
                o.uv = TRANSFORM_TEX(v.uv, _MainTex);       // UV信息 支持TilingOffset
                return o;
            }
           
            // 输出结构>>>像素
            half4 frag(VertexOutput i) : COLOR {
                half4 var_MainTex = tex2D(_MainTex, i.uv);      // 采样贴图 RGB颜色 A透贴不必须
                half3 finalRGB = var_MainTex.rgb;
                half opacity = var_MainTex.a * _Opacity;
                return half4(finalRGB * opacity, opacity);                // 返回值
            }
            ENDCG
        }
    }
}

混合模式

混合原理

在Shader里面算出来的结果就是源因子,在Shader算出结果之前的背景叫做目标因子

Shader "AP01/L13/BlendMode"
{
    Properties
    {
        _MainTex ("RGB:颜色 A:透贴", 2d) = "gray"{}
        _Opacity ("透明度", range(0, 1)) = 0.5
        [Enum(UnityEngine.Rendering.BlendMode)]
        _BlendSrc ("混合源乘子", int) = 0
        [Enum(UnityEngine.Rendering.BlendMode)]
        _BlendDst ("混合目标乘子", int) = 0
        [Enum(UnityEngine.Rendering.BlendOp)]
        _BlendOp ("混合算符", int) = 0
    }

    SubShader
    {
        Tags
        {
            "Queue"="Transparent"               // 调整渲染顺序
            "RenderType"="Transparent"          // 对应改为Cutout
            "ForceNoShadowCasting"="True"       // 关闭阴影投射
            "IgnoreProjector"="True"            // 不响应投射器
        }

        Pass
        {
            Name "FORWARD"
            Tags { "LightMode"="ForwardBase" }

            BlendOp [_BlendOp]                  // 可自定义混合算符
            Blend [_BlendSrc] [_BlendDst]       // 可自定义混合模式

            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            #include "UnityCG.cginc"
            #pragma multi_compile_fwdbase_fullshadows
            #pragma target 3.0

            // 输入参数
            uniform sampler2D _MainTex; uniform float4 _MainTex_ST;
            uniform half _Opacity;

            // 输入结构
            struct VertexInput
            {
                float4 vertex : POSITION;       // 顶点位置 总是必要
                float2 uv : TEXCOORD0;          // UV信息 采样贴图用
            };

            // 输出结构
            struct VertexOutput
            {
                float4 pos : SV_POSITION;       // 顶点位置 总是必要
                float2 uv : TEXCOORD0;          // UV信息 采样贴图用
            };

            // 输入结构>>>顶点Shader>>>输出结构
            VertexOutput vert (VertexInput v)
            {
                VertexOutput o = (VertexOutput)0;
                o.pos = UnityObjectToClipPos( v.vertex);    // 顶点位置 OS>CS
                o.uv = TRANSFORM_TEX(v.uv, _MainTex);       // UV信息 支持TilingOffset
                return o;
            }

            // 输出结构>>>像素
            half4 frag(VertexOutput i) : COLOR
            {
                half4 var_MainTex = tex2D(_MainTex, i.uv);      // 采样贴图 RGB颜色 A透贴不必须
                half3 finalRGB = var_MainTex.rgb;
                half opacity = var_MainTex.a * _Opacity;
                return half4(finalRGB * opacity, opacity);                // 返回值
            }
            ENDCG
        }
    }
}