[吾题有解] HDLBits : Lemmings2

旅鼠四题中的第二题，直接说关键点。

1. 首先是要搞清楚有几个状态，它们分别是向左（LEFT）、向右（RIGHT）、下落中保持向左（FALL_L）和下落中保持向右（FALL_R）四个状态。
2. 接下来是明白输入如何影响次态：处于地面状态（LEFT、RIGHT）时，当ground = 0，下一个状态进入保持当前方向的下落状态（分别对应FALL_L、FALL_R）；处于下落状态时，当ground = 1，下一个状态进入保持当前方向的地面状态。其中的关键是旅鼠进入、脱离下落状态以及处于下落状态中时，不受碰撞信号的影响。所以判断次态要首先确定ground信号值，在现态为地面状态时，若为1，则正常碰撞判定/次态为下落状态，若为0，进入下落状态；在现态为下落状态时，只考虑ground，若为1则回到当前方向地面状态，若为0，不受其他信号影响，保持当前方向下落状态。

Being bumped while falling does not affect the walking direction, and being bumped in the same cycle as ground disappears (but not yet falling), or when the ground reappears while still falling, also does not affect the walking direction.

3. 最后是输出，采用组合逻辑连续赋值语句描述，相比于前一题添加了一个下落时输出“aaah”，这里唯一要注意的是无论下落中保持向左还是向右均要输出“aaah”。

最后给出本题的Veirlog HDL：

module top_module(
    input clk,
    input areset,    // Freshly brainwashed Lemmings walk left.
    input bump_left,
    input bump_right,
    input ground,
    output walk_left,
    output walk_right,
    output aaah ); 
	
    localparam LEFT   = 4'b0001, // One-Hot
    		   RIGHT  = 4'b0010,
    		   FALL_L = 4'b0100,
    		   FALL_R = 4'b1000;
    
    reg [3:0] state;
    reg [3:0] next_state;
    
    // 时序逻辑描述状态切换
    always @(posedge clk or posedge areset)
        if(areset)
            state <= LEFT;
    	else
            state <= next_state;
    
    // 组合逻辑描述次态判断
    always @(*) begin
        case(state)
            LEFT   : next_state = ~ground ? FALL_L : (bump_left  ? RIGHT : LEFT);
            RIGHT  : next_state = ~ground ? FALL_R : (bump_right ? LEFT : RIGHT);
            FALL_L : next_state =  ground ? LEFT   : FALL_L;
            FALL_R : next_state =  ground ? RIGHT  : FALL_R;
        endcase
    end

	// 组合逻辑描述输出信号
    assign walk_left  = (state == LEFT);
    assign walk_right = (state == RIGHT);
    assign aaah       = (state == FALL_L) || (state == FALL_R);
    
endmodule

总结：其实组合逻辑次态判断部分也不是一开始就想出来的，最开始是使用case语句对输入集合{bump_left, bump_right, ground}的8种情况（从3’b000~3’b111）逐个确定输出，写了两个状态之后才发现可以精简为上述代码，逻辑也变得更加清晰。启发是在解决问题的时候可以不必一开始就追求最优解法，而是尝试先写出一个解，明白了其中蕴含的逻辑后再视情况进行优化。