Shader 阴影

已于 2023-03-14 22:24:57 修改
阅读量444 收藏 1
点赞数
分类专栏： 技术美术 文章标签： unity
于 2023-03-05 01:15:23 首次发布
版权声明：本文为博主原创文章，遵循 CC 4.0 BY-SA 版权协议，转载请附上原文出处链接和本声明。
本文链接：https://blog.csdn.net/sinat_34014668/article/details/128998560
版权

阴影生成原理

在这里插入图片描述
以平行光为例，把相机移动到光源位置，计算阴影映射纹理（shadowmap），这张shadowmap本质上是一张深度图，它记录了从该光源的位置出发、能看到的场景中距离它最近的表面位置（深度信息）。渲染时中把顶点位置变换到光源空间下，得到它在光源空间中的三维位置信息。然后，我们使用xy分量对shadowmap进行采样，得到shadowmap中该位置的深度信息。如果该深度值小于该顶点的深度值（通常由z分量得到），那么说明该点位于阴影中。如图，将顶点P转换到光源空间，得到（Px, Py, Pz），Pz = 0.9，用（Px, Py）对shadowmap采样，得到C点的深度0.4，0.4 < 0.9，所以P点在阴影中

需要注意的细节

使用内置阴影的shader大致框架如下，这里略去一些不重要的部分

Shader "MyCustom/BuildinShadow"
{
    Properties{}
    SubShader
    {
        Tags { "RenderType"="Opaque" }

        Pass
        {
            Tags {"LightMode"="ForwardBase"}

            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            #pragma multi_compile_fwdbase

            #include "UnityCG.cginc"
            #include "Lighting.cginc"
            #include "AutoLight.cginc"
                
            struct appdata
            {
            	float4 vertex : POSITION;
			};

            struct v2f
            {
            	float4 pos : SV_POSITION;
                SHADOW_COORDS(x) //x表示第几个纹理
            };

            v2f vert (appdata v)
            {
                v2f o;
                //...
                TRANSFER_SHADOW(o);
                return o;
            }

            fixed4 frag (v2f i) : SV_Target
            {
            	//...
            	//fixed atten = 1.0;
                //fixed shadow = SHADOW_ATTENUATION(i);
				//return fixed4(ambient + (diffuse + specular) * atten * shadow, 1.0);

				UNITY_LIGHT_ATTENUATION(atten, i, i.worldPos);
				return fixed4(ambient + (diffuse + specular) * atten, 1.0);
            }
            ENDCG
        }

        Pass
        {
            Tags {"LightMode"="ForwardAdd"}
            Blend One One

            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            #pragma multi_compile_fwdadd
            // #pragma multi_compile_fwdadd_fullshadows

            #include "UnityCG.cginc"
            #include "Lighting.cginc"
            #include "AutoLight.cginc"

            struct appdata
            {
            	float4 vertex : POSITION;
			};

            struct v2f
            {
            	float4 pos : SV_POSITION;
                SHADOW_COORDS(x) //x表示第几个纹理
            };

            v2f vert (appdata v)
            {
                v2f o;
                //...
                TRANSFER_SHADOW(o);
                return o;
            }

            fixed4 frag (v2f i) : SV_Target
            {
            	//...
				UNITY_LIGHT_ATTENUATION(atten, i, i.worldPos);
				return fixed4((diffuse + specular) * atten, 1.0);
            }
            ENDCG
        }

        // 自己实现阴影，额外添加一个Pass，这个Pass是为了更新光源的阴影映射纹理
        //Pass
        //{
        //    Tags {"LightMode"="ShadowCaster"}
        //}
    }
    Fallback "Specular"
}

在这里插入图片描述
在这里插入图片描述
需要注意的细节

  • 光源设置阴影类型，Hard Shadows或者Soft Shadows
  • 物体的Mesh Renderer上设置Cast Shadows和Receive Shadoes，Plane或一些半透明物体需要设置双面投射阴影，即Cast Shadows设置为Two Sided
  • 使用内置阴影需要在shader结尾加上 Fallback “Specular”，Specular的Fallback调用了VertexLit，VertexLit中有个Pass渲染光源的阴影映射纹理，或是摄像机的深度纹理。如果要自己实现阴影，需要额外写一个Pass，并把LightMode设置为ShadowCaster
  • Base Pass计算平行光和环境光，申明编译指令#pragma multi_compile_fwdbase，Additional Pass计算其他类型的光源，如果点光源或聚光灯也要计算阴影，需要申明编译指令#pragma multi_compile_fwdadd_fullshadows 代替 #pragma multi_compile_fwdadd
  • Additional Pass需要设置混合 Blend One One
  • 引用内置文件 #include “AutoLight.cginc”，计算阴影时所用的宏都是在这个文件中声明的
  • SHADOW_COORDS，TRANSFER_SHADOW和SHADOW_ATTENUATION这三个宏是计算阴影时的“三剑客”，SHADOW_COORDS就是声明一个用于对阴影纹理采样的坐标，TRANSFER_SHADOW将顶点从模型空间转换到光源空间后存储到_ShadowCoord中，SHADOW_ATTENUATION使用阴影坐标采样阴影贴图，也可以使用UNITY_LIGHT_ATTENUATION代替SHADOW_ATTENUATION，它用于计算光照衰减和阴影，接受3个参数，将光照衰减和阴影值相乘后的结果存储到第一个参数中，使用UNITY_LIGHT_ATTENUATION，使得Base Pass和Additional Pass的代码得以统一
  • 这些宏中会使用上下文变量来进行计算，所以变量名称需要和宏中使用的名称一致，a2v（或appdata）结构体中的顶点坐标变量名必须是vertex，顶点着色器的输入结构体a2v（或appdata）必须命名为v，v2f中的顶点位置变量必须命名为pos

完整的Shader

Shader "MyCustom/BuildinShadow"
{
    Properties
    {
        _MainTex            ("Texture",            2D)             = "white" {}
        _Diffuse            ("Diffuse",            Color)          = (0.5, 0.5, 0.5, 1)
        _Specular           ("Specular",           Color)          = (1, 1, 1, 1)
        _SpecularPower      ("SpecularPower",      Range(0, 150))  = 20
        _SpecularIntensity  ("SpecularIntensity",  Range(0, 10))   = 1.5
    }
    SubShader
    {
        CGINCLUDE
        float _specular(float3 worldViewDir, float3 worldLightDir, float3 worldNormal, float power, float intensity)
        {
            float3 halfVector = normalize(worldLightDir + worldViewDir);
            float hdotn = max(0, dot(halfVector, worldNormal));
            float specular = pow(hdotn, power) * intensity;
            return specular;
        }
        ENDCG

        Tags { "RenderType"="Opaque" }
        LOD 100

        Pass
        {
            Tags {"LightMode"="ForwardBase"}

            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            #pragma multi_compile_fwdbase

            #include "UnityCG.cginc"
            #include "Lighting.cginc"
            #include "AutoLight.cginc"
                
            struct appdata
            {
                float4 vertex : POSITION;
                float3 normal : NORMAL;
                float2 uv     : TEXCOORD0;
            };

            struct v2f
            {
                float4 pos          : SV_POSITION;
                float2 uv           : TEXCOORD0;
                float3 worldNormal  : TEXCOORD1;
                float3 worldPos     : TEXCOORD2;
                SHADOW_COORDS(3)
            };

            sampler2D _MainTex;
            float4 _MainTex_ST;

            float4 _Diffuse;
            float4 _Specular;
            float _SpecularPower;
            float _SpecularIntensity;

            v2f vert (appdata v)
            {
                v2f o;
                o.pos = UnityObjectToClipPos(v.vertex);
                o.uv = TRANSFORM_TEX(v.uv, _MainTex);
                o.worldNormal = UnityObjectToWorldNormal(v.normal);
                o.worldPos = mul(unity_ObjectToWorld, v.vertex).xyz;

                TRANSFER_SHADOW(o);
                return o;
            }

            fixed4 frag (v2f i) : SV_Target
            {
                float3 worldLightDir = UnityWorldSpaceLightDir(i.worldPos);
                float3 worldViewDir = normalize(UnityWorldSpaceViewDir(i.worldPos));

                fixed4 texColor = tex2D(_MainTex, i.uv);
                fixed3 albedo = texColor.rgb * _Diffuse.rgb;
                
                // 环境光
                float3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz * albedo;

                // 漫反射
                float3 diffuse = _LightColor0.rgb * albedo * max(0, dot(i.worldNormal, worldLightDir));

                // 高光
                float3 specular = _LightColor0.rgb * _Specular.rgb * _specular(worldViewDir, worldLightDir, i.worldNormal, _SpecularPower, _SpecularIntensity);
                
                // atten为阴影和衰减的乘积，UNITY_LIGHT_ATTENUATION针对不同类型的光源进行计算
                UNITY_LIGHT_ATTENUATION(atten, i, i.worldPos);

                float4 finalColor = 1;
                finalColor.rgb = ambient + (diffuse + specular) * atten;
                return finalColor;
            }
            ENDCG
        }

        Pass
        {
            Tags {"LightMode"="ForwardAdd"}
            Blend One One

            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            #pragma multi_compile_fwdadd
            // 其他光源使用阴影，使用下面的指令替换掉 multi_compile_fwdadd
            // #pragma multi_compile_fwdadd_fullshadows

            #include "UnityCG.cginc"
            #include "Lighting.cginc"
            #include "AutoLight.cginc"

            struct appdata
            {
                float4 vertex : POSITION;
                float3 normal : NORMAL;
                float2 uv     : TEXCOORD0;
            };

            struct v2f
            {
                float4 vertex       : SV_POSITION;
                float2 uv           : TEXCOORD0;
                float3 worldNormal  : TEXCOORD1;
                float3 worldPos     : TEXCOORD2;
                SHADOW_COORDS(3)
            };

            sampler2D _MainTex;
            float4 _MainTex_ST;

            float4 _Diffuse;
            float4 _Specular;
            float _SpecularPower;
            float _SpecularIntensity;

            v2f vert (appdata v)
            {
                v2f o;
                o.vertex = UnityObjectToClipPos(v.vertex);
                o.uv = TRANSFORM_TEX(v.uv, _MainTex);
                o.worldNormal = UnityObjectToWorldNormal(v.normal);
                o.worldPos = mul(unity_ObjectToWorld, v.vertex).xyz;
                TRANSFER_SHADOW(o);
                return o;
            }

            fixed4 frag (v2f i) : SV_Target
            {
                float3 worldLightDir = UnityWorldSpaceLightDir(i.worldPos);
                float3 worldViewDir = normalize(UnityWorldSpaceViewDir(i.worldPos));

                // 漫反射
                float3 diffuse = _LightColor0.rgb * _Diffuse.rgb * max(0, dot(i.worldNormal, worldLightDir));

                // 高光
                float3 specular = _LightColor0.rgb * _Specular.rgb * _specular(worldViewDir, worldLightDir, i.worldNormal, _SpecularPower, _SpecularIntensity);
                
                UNITY_LIGHT_ATTENUATION(atten, i, i.worldPos);

                float4 finalColor = 1;
                finalColor.rgb = (diffuse + specular) * atten;
                return finalColor;
            }
            ENDCG
        }
    }
    Fallback "Specular"
}

在这里插入图片描述
通过Frame Debug观察阴影的渲染过程，UpdateDepthTexture，即更新摄像机的深度纹理；RenderShadowmap，即渲染得到平行光的阴影映射纹理；CollectShadows，即根据深度纹理和阴影映射纹理得到屏幕空间的阴影图；最后绘制渲染结果

透明物体的阴影

在这里插入图片描述

需要注意的细节

  • Tags设置 “Queue”=“AlphaTest” ，“RenderType”=“TransparentCutout”
  • Cull Off 关闭剔除
  • FallBack “Transparent/Cutout/VertexLit” 它含有透明度测试功能的ShadowCaster Pass
  • 为了保证命名统一，必须使用_Cutoff来命名透明度阈值
  • Mesh Renderer组件中的Cast Shadows属性设置为Two Sided，强制Unity在计算阴影映射纹理时计算所有面的深度信息

完整的shader

Shader "MyCustom/AlphaTestShadow" 
{
	Properties 
	{
		_MainTex ("Main Tex",	   2D)			 = "white" {}
		_Color   ("Color Color", Color)			 = (1, 1, 1, 1)
		_Cutoff  ("Alpha Cutoff",  Range(0, 1))  = 0.5
	}
	
	SubShader 
	{
		Tags { "Queue"="AlphaTest" "IgnoreProjector"="True" "RenderType"="TransparentCutout" }
		
		Pass 
		{
			Tags { "LightMode"="ForwardBase" }
			Cull Off
			
			CGPROGRAM
			#pragma vertex vert
			#pragma fragment frag
			#pragma multi_compile_fwdbase
			
			#include "Lighting.cginc"
			#include "AutoLight.cginc"

			sampler2D _MainTex;
			float4 _MainTex_ST;
			fixed4 _Color;
			fixed _Cutoff;
			
			struct a2v
			{
				float4 vertex	: POSITION;
				float3 normal	: NORMAL;
				float4 uv		: TEXCOORD0;
			};
			
			struct v2f
			{
				float4 pos			: SV_POSITION;
				float3 worldNormal  : TEXCOORD0;
				float3 worldPos		: TEXCOORD1;
				float2 uv			: TEXCOORD2;
				SHADOW_COORDS(3)
			};
			
			v2f vert(a2v v)
			{
			 	v2f o;
			 	o.pos = UnityObjectToClipPos(v.vertex);
			 	o.worldNormal = UnityObjectToWorldNormal(v.normal);
			 	o.worldPos = mul(unity_ObjectToWorld, v.vertex).xyz;
			 	o.uv = TRANSFORM_TEX(v.uv, _MainTex);
				
			 	TRANSFER_SHADOW(o);
			 	return o;
			}
			
			fixed4 frag(v2f i) : SV_Target
			{
				fixed3 worldLightDir = normalize(UnityWorldSpaceLightDir(i.worldPos));
				
				fixed4 texColor = tex2D(_MainTex, i.uv);
				clip(texColor.a - _Cutoff);
				
				fixed3 albedo = texColor.rgb * _Color.rgb;
				// 环境光
				fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz * albedo;

				// 漫反射
				fixed3 diffuse = _LightColor0.rgb * albedo * max(0, dot(i.worldNormal, worldLightDir));
				
				UNITY_LIGHT_ATTENUATION(atten, i, i.worldPos);
				return fixed4(ambient + diffuse * atten, 1.0);
			}
			ENDCG
		}
	}
	FallBack "Transparent/Cutout/VertexLit"
}

参考

《Shader 入门精要》
查看Build-in Shaders 需要科学上网
在这里插入图片描述

北海6516
关注
专栏目录
基于Shadow Map的阴影实现
nxtgo
09-16 7251
0、简介 Shadow Mapping是一种基于图像空间的阴影实现方法，其优点是实现简单，适应于大型动态场景；缺点是由于shadow map的分辨率有限，使得阴影边缘容易出现锯齿(Aliasing)；关于SM的研究很活跃，主要围绕着阴影抗锯齿，出现了很多SM变种，如PSM，LPSM，VSM等等，在这里http://en.wikipedia.org/wiki/Shadow_mapping可以找到很
Unity shader阴影
a1601611709的博客
12-26 962
Unity shader阴影 参考书籍：《Unity Shader入门精要》 阴影是如何实现的 在实时渲染中，我们最常使用的是一种名为Shadow Map的技术。这种技术的原理是将摄像机放到与光源重合的位置上，那么场景中该光源的阴影区域就是那些摄像机看不到的地方。Unity使用的就是这种技术。 在前向渲染路径中，如果场景中最重要的平行光开启了阴影，unity就会为该光源计算它的阴影映射纹理（shadowMap）。这张阴影映射纹理本质上也是一张深度图，它记录了从该光源的位置出发、能看到的场景..
ASE_URP_仅渲染阴影.shader
07-28
URP渲染管线下仅渲染接受到的阴影的shader
Shader笔记：光照与阴影1
最新发布
qq_39377889的博客
08-27 1064
浅入深出，由ShadowCaster引入URP阴影的渲染机制，并以此为拓展，阐述了一些阴影渲染的画面问题，并对实际运用技术点的含义与原理进行了解析。
Shader实现的阴影效果(Shadow)
01-23
自己写的阴影效果，里面用了Shader,具体的话是运用了深度碰撞测试和投影机技术，目前最常用的阴影技术，简单易懂~
shader篇-阴影
新博客地址http://www.cnblogs.com/millionsmultiplication/
01-16 3534
shader篇-阴影 标签（空格分隔）： shader shader篇-阴影 简介 投射阴影实现 接受阴影 Unity统一管理光照衰减和阴影 透明度物体的阴影 简介 阴影的实现需要2个过程： 一、接受阴影的物体，需要在shader中采样阴影映射纹理，并把采样后结果与光照结果相乘获得阴影效果。 二、一个物体如果想投射阴影，就需要将该物体加入光照映射纹理的计算中，以便
shader入门13 阴影
残獄の世界に救いを
06-18 569
原理 阴影渲染的原理是将相机放在光源的位置,相机看不到的地方也就是光源无法照射的地方,即阴影. 我们有两个步骤需要实现,分别是 1.向物体投射阴影 2.接收其他物体投射的阴影 阴影投射 我们首先需要打开光源的阴影投射,和物体的阴影投射,组件中的设置会影响shader中是否计算阴影. 我们以普通的高光反射为基础,测试阴影投射 细心的人一定发现了我注释了Fallback,这是因为即便是我们没写阴影...
Shader学习的基础知识（十一）阴影
盖子的博客
03-10 939
我们通常用一种名为Shadow Map的技术实现阴影效果。这种技术的原理就是把摄像机放到灯光的位置，看不到的位置则为阴影。在前向渲染中，阴影映射纹理来实现阴影效果的。 阴影映射纹理是记录了由灯光到表面位置的深度信息，所以本质上也是一张深度图，怎么得到这张深度图呢？ 方法一：在正常执行了Base Pass和Additional Pass后更新纹理，但这样性能消耗很大，不推荐。 方法二：用额外一个Pa...
Unity Shader阴影贴图与阴影遮罩原理解析
通过本资源包中的文件和内容，学习者可以深入了解阴影生成的机制、shadowmask原理，并且通过实践编写自定义的shader来实现特定的阴影效果。以下是针对提供的文件信息的具体知识点阐述： 1. Unity Shader编程基础 ...
Unity Shader 阴影实现
qq_44800780的博客
11-15 2008
阴影是光线被阻挡的结果,在实时渲染中，我们最常使用的是一种名为Shadow Map阴影映射的技术，效果不错，而且相对容易实现。 阴影映射原理 我们以光的位置为视角进行渲染，我们能看到的东西都将被点亮，看不见的一定是在阴影之中了 那如何知道物体是看得见还是看不见呢？ 我们使用阴影映射纹理，它的本质是一张深度图，记录了从光源的位置出发、能看到的场景中距离它最近的表面位置. 在计算阴影纹理映射时，如何...
Unity Shader总结（九）——阴影
memory_MM_forever的博客
06-25 1756
屏幕空间的阴影投射 unity会调用lightmode为ShadowCaster的Pass来得到可投射阴影的光源的阴影投射纹理和摄像机的深度纹理，然后根据它们的纹理来得到屏幕空间的阴影图，如果摄像机的深度纹理记录的深度值大于转换到阴影投射纹理中的深度值，就证明该表面在阴影中。 如果想要物体接受投影，只需要在shader中对阴影图采样，首先把表面坐标从模型空间变换到屏幕空间中，然后使用这个坐标对阴影图进行采样。 不透明物体投射阴影 通用过Mesh Renderer组件中的Cast Shadows 和 Rece
Unity shader 自带阴影
若风
07-08 1449
一定要加这一行 #pragma multi_compile_fwdbase file:///D:/Program%20Files/Unity2018.3/Editor/Data/Documentation/en/Manual/SL-MultipleProgramVariants.html Shader "Unlit/PCSS" { Properties { _...
shader之旅-7-平面阴影（planar shadow）
weixin_34095889的博客
06-15 95
shader之旅-7-平面阴影（planar shadow） 根据《real-time shadow》这本书第二章中的推导，实现了最简单的阴影技术。planar shadow通过一个投影矩阵将被灯光照射的物体的顶点沿着光线方向投影到接受阴影的平面。关键的问题是这个投影矩阵怎么得到。阴影所在平面用下式表示：其中n是法线，d是常量，x是平面上...
Unity中Shader阴影的投射
楠溪泽岸的博客
10-21 838
Unity中Shader阴影的投射。
Unity中Shader阴影的接收
楠溪泽岸的博客
10-22 2025
Unity中Shader阴影的接收(基于上一篇文章)Unity中Shader阴影的投射。
【UnityShader入门精要学习笔记】第九章 更复杂的光照（3）——光照阴影
milu_ELK的博客
04-08 1516
在现实中的阴影是如何产生的？由于光是直射的，因此当一道光线遇到一个不透明的物体，那么这个物体就会投射阴影，阴影部分区域是光无法到达的区域。 在实时渲染中，最常使用的是一种叫做Shadow Map的技术，这种技术理解起来很简单——就是把摄像机位置放置与光源重合的位置上，那么摄像机看不到的地方即为阴影区域了。 在前向渲染路径中，如果场景中最重要的平行光开启了阴影，Unity就会为该光源计算它的**阴影映射纹理（Shadow Map）** 。这张阴影映射纹理本质上也是一张深度图。它记录了从该光源的位置触发、能
untiy 3d ShaderLab_第9章_2_球体阴影(二) 阴影的淡入/淡出
heyuchang666的专栏
10-26 805
在上一节的例子中，我们仅仅判断了是否能看到光源，其实不仅仅能判断是否可以看到光源，当我们看不到光源时，还可以计算出此时点距离光亮地带的远近程度，等价于到阴影中心的远近程度，这样就可计算一个带浓淡变化的阴影里，而这是在一般的阴影实现算法中比较难以做到的。
URP shader 产生阴影
11-25
根据提供的引用内容，我们可以得知URP shader产生阴影的方法如下： 1. 首先需要在shader中采样Shadermap贴图，可以使用以下代码实现： ```shader // 定义Shadermap贴图 sampler2D _ShadowMapTexture; // 采样Shadermap贴图 float4 shadowCoord = TransformWorldToShadowCoord(i.worldPos); float shadowMapDepth = tex2D(_ShadowMapTexture, shadowCoord.xy).r; ``` 2. 接着需要获取主光源并计算阴影衰减，可以使用以下代码实现： ```shader // 获取主光源 Light mainLight = GetMainLight(shadowCoord); // 计算阴影衰减 half shadow = mainLight.shadowAttenuation; ``` 3. 最后，根据阴影衰减的值来产生阴影，可以使用以下代码实现： ```shader // 根据阴影衰减的值产生阴影 half4 shadowColor = tex2D(_ShadowTex, i.uv); half4 litColor = tex2D(_MainTex, i.uv); half4 finalColor = lerp(litColor, shadowColor, shadow); ```
评论
添加红包

请填写红包祝福语或标题

个

红包个数最小为10个

元

红包金额最低5元

当前余额3.43元 前往充值 >
需支付：10.00元
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包
实付元
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明：

1.余额是钱包充值的虚拟货币，按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载，可以购买VIP、付费专栏及课程。

余额充值