shader入门精要读书笔记30 边缘检测

一、边缘检测理论

边缘检测是一种描边效果实现的方法，原理是通过检测算子对图像进行卷积。

卷积核就是一个正方形的网格结构。在对某个像素进行卷积时，我们会把卷积核的中心放在该像素上，依次计算核中的每个元素值和每个像素的像素值的乘积，再把所有的相加，得到的结果就是该位置的新像素值。

这样的过程可以实现很多效果，例如图像模糊、边缘检测等。

常见的边缘检测算子(卷积核)：

以上别熬是的是两个方向的卷积核。

每个位置对应相乘累加后，再把Gx、Gy相加，得到G，G越大，说明越可能是边缘。

二、实现

摄像机脚本代码：

using UnityEngine;
using System.Collections;

public class EdgeDetection : PostEffectsBase {

	public Shader edgeDetectShader;
	private Material edgeDetectMaterial = null;
	public Material material {			//声明shader并根据shader创建材质
		get {
			edgeDetectMaterial = CheckShaderAndCreateMaterial(edgeDetectShader, edgeDetectMaterial);
			return edgeDetectMaterial;
		}  
	}

	[Range(0.0f, 1.0f)]
	public float edgesOnly = 0.0f;		//边缘线强度	为0时边缘会叠加在原渲染图像上，为1只显示边缘

	public Color edgeColor = Color.black;		//边缘线颜色
	
	public Color backgroundColor = Color.white;		//背景颜色

	void OnRenderImage (RenderTexture src, RenderTexture dest) {		//使用这个函数进行特效处理
		if (material != null) {		//这里会检查材质是否可用，
			material.SetFloat("_EdgeOnly", edgesOnly);      //可用的话设置材质相应参数
			material.SetColor("_EdgeColor", edgeColor);
			material.SetColor("_BackgroundColor", backgroundColor);

			Graphics.Blit(src, dest, material);     //使用Blit函数传递材质的Shader进行处理src，再传递出给dest
		} else {
			Graphics.Blit(src, dest);       //如果材质不可用，直接不进行处理。
		}
	}
}

Shader代码：

Shader "Unity Shaders Book/Chapter 12/Edge Detection" {
	Properties {
		_MainTex ("Base (RGB)", 2D) = "white" {}			//接收输入的渲染纹理
		_EdgeOnly ("Edge Only", Float) = 1.0
		_EdgeColor ("Edge Color", Color) = (0, 0, 0, 1)
		_BackgroundColor ("Background Color", Color) = (1, 1, 1, 1)
	}
	SubShader {
		Pass {  
			ZTest Always Cull Off ZWrite Off
			
			CGPROGRAM
			
			#include "UnityCG.cginc"
			
			#pragma vertex vert  
			#pragma fragment fragSobel
			
			sampler2D _MainTex;  
			uniform half4 _MainTex_TexelSize;			//×××_TexelSize，可以让Untiy为我们提供×××纹理对应的每个纹素的大小
			fixed _EdgeOnly;		//边缘线强度	为0时边缘会叠加在原渲染图像上，为1只显示边缘
			fixed4 _EdgeColor;		//边缘线颜色
			fixed4 _BackgroundColor;		//背景颜色
			
			struct v2f {
				float4 pos : SV_POSITION;
				half2 uv[9] : TEXCOORD0;
			};
			  
			v2f vert(appdata_img v) {
				v2f o;
				o.pos = UnityObjectToClipPos(v.vertex);
				
				half2 uv = v.texcoord;
				
				o.uv[0] = uv + _MainTex_TexelSize.xy * half2(-1, -1);			//用来取像素位置，采样原图像像素时使用
				o.uv[1] = uv + _MainTex_TexelSize.xy * half2(0, -1);
				o.uv[2] = uv + _MainTex_TexelSize.xy * half2(1, -1);
				o.uv[3] = uv + _MainTex_TexelSize.xy * half2(-1, 0);
				o.uv[4] = uv + _MainTex_TexelSize.xy * half2(0, 0);
				o.uv[5] = uv + _MainTex_TexelSize.xy * half2(1, 0);
				o.uv[6] = uv + _MainTex_TexelSize.xy * half2(-1, 1);
				o.uv[7] = uv + _MainTex_TexelSize.xy * half2(0, 1);
				o.uv[8] = uv + _MainTex_TexelSize.xy * half2(1, 1);
						 
				return o;
			}
			
			fixed luminance(fixed4 color) {
				return  0.2125 * color.r + 0.7154 * color.g + 0.0721 * color.b;			//这个函数用来计算亮度值
			}
			
			half Sobel(v2f i) {			
				const half Gx[9] = {-1,  0,  1,						//定义卷积核
									-2,  0,  2,
									-1,  0,  1};
				const half Gy[9] = {-1, -2, -1,
									0,  0,  0,
									1,  2,  1};		
				
				half texColor;
				half edgeX = 0;
				half edgeY = 0;
				for (int it = 0; it < 9; it++) {
					texColor = luminance(tex2D(_MainTex, i.uv[it]));		//先采样(采样时采的是相应位置的)后进行亮度值计算
					edgeX += texColor * Gx[it];		//使用edgeX累加每一个卷积核里面的数
					edgeY += texColor * Gy[it];		//同上
				}
				
				half edge = 1 - abs(edgeX) - abs(edgeY);		//使用1减去水平方向和竖直方向梯度值的绝对值，得到edge。edge越小说明这个位置越可能是一个边缘点
				//其实也就是edgeX和edgeY的绝对值的和，用1剪掉是为了得到反向的值

				return edge;
			}
			
			fixed4 fragSobel(v2f i) : SV_Target {
				half edge = Sobel(i);
				
				fixed4 withEdgeColor = lerp(_EdgeColor, tex2D(_MainTex, i.uv[4]), edge);		//使用edge在自己本来的颜色和边缘线之间插值，edge越小withEdgeColor颜色越靠近边缘线颜色
				fixed4 onlyEdgeColor = lerp(_EdgeColor, _BackgroundColor, edge);		//使用edge在边缘线颜色和背景颜色间插值，
				return lerp(withEdgeColor, onlyEdgeColor, _EdgeOnly);		//_EdgeOnly插值上面两个颜色。

				//实现当_EdgeOnly为0时 显示的是 图像颜色和边缘线的混合
				//    当_EdgeOnly为1时 显示的是 边缘线和背景颜色的混合(没有图像本身了)，

 			}
			
			ENDCG
		} 
	}
	FallBack Off
}

以上具体解释见代码注释。