Shader学习的基础知识（十九）广告牌

广告牌技术可以使用纹理看起来一起面对着自己。广告牌技术的本质就是构建旋转矩阵，而一个转换矩阵则需要三个基向量，即表面法线(normal)，右指方向切线(tangent)，上指方向副切线(Deputy tangent)，还需要一个锚点。

这里我用它做了一个打火机火焰的效果，素材只需要一张图片即可：


在对应的物体下创建一个Quad物体，然后挂上此Shader,即可得到效果，具体做法看代码吧，解释都在注释里了。

Shader "Custom/TestShader28" {
	Properties {
		_MainTex ("Main Tex", 2D) = "white" {}
		_Color ("Color Tint", Color) = (1, 1, 1, 1)
		_VerticalBillboarding ("Vertical Restraints", Range(0, 1)) = 1 
	}
	SubShader {
		//这里主要是关闭批处理
		Tags {"Queue"="Transparent" "IgnoreProjector"="True" "RenderType"="Transparent" "DisableBatching"="True"}
		
		Pass { 
			Tags { "LightMode"="ForwardBase" }
			
			ZWrite Off
			Blend SrcAlpha OneMinusSrcAlpha
			Cull Off
		
			CGPROGRAM
			
			#pragma vertex vert
			#pragma fragment frag
			
			#include "Lighting.cginc"
			
			sampler2D _MainTex;
			float4 _MainTex_ST;
			fixed4 _Color;
			fixed _VerticalBillboarding;
			
			struct a2v {
				float4 vertex : POSITION;
				float4 texcoord : TEXCOORD0;
			};
			
			struct v2f {
				float4 pos : SV_POSITION;
				float2 uv : TEXCOORD0;
			};
			
			v2f vert (a2v v) {
				v2f o;
				
				//原点(这个其实是一个逻辑的辅助作用，删了也不影响)
				float3 center = float3(0, 0, 0);
				//摄像机位置转到模型空间
				float3 viewer = mul(unity_WorldToObject,float4(_WorldSpaceCameraPos, 1));
				
				//在模型空间中，摄像机指向原点的向量
				float3 normalDir = viewer - center;
				//控制垂直约束度
				normalDir.y =normalDir.y * _VerticalBillboarding;
				//得出目标单位法线
				normalDir = normalize(normalDir);
				//防止法线方向和向上的方向平行 得到一个粗略的向上的方向
				//其实是找个向上的向量，好算出向右的向量
				float3 upDir = abs(normalDir.y) > 0.999 ? float3(0, 0, 1) : float3(0, 1, 0);
				//通过叉乘得到向右的向量
				float3 rightDir = normalize(cross(upDir, normalDir));
				//通过摄像机到原点 与 向右的向量叉乘得到真向上的向量
				upDir = normalize(cross(normalDir, rightDir));
				
				//模型空间中，顶点距离原点的位置
				float3 centerOffs = v.vertex.xyz - center;
				//模型空间中，三个分量分别乘以三个方向的单位向量，即把正面转过来面得摄像机
				float3 localPos = center + rightDir * centerOffs.x + upDir * centerOffs.y + normalDir * centerOffs.z;
              
				o.pos = UnityObjectToClipPos(float4(localPos, 1));
				o.uv = TRANSFORM_TEX(v.texcoord,_MainTex);

				return o;
			}
			
			fixed4 frag (v2f i) : SV_Target {
				fixed4 c = tex2D (_MainTex, i.uv);
				c.rgb *= _Color.rgb;
				
				return c;
			}
			
			ENDCG
		}
	} 
	FallBack "Transparent/VertexLit"
}