【Godot4.2】颜色完全使用手册

已于 2024-03-17 18:27:46 修改
阅读量1.2k 收藏 24
点赞数 25
分类专栏： Godot4.0 文章标签： godot gdscript 颜色 HSV RGB
于 2024-03-17 17:14:24 首次发布
版权声明：本文为博主原创文章，遵循 CC 4.0 BY-SA 版权协议，转载请附上原文出处链接和本声明。
本文链接：https://blog.csdn.net/graypigen1990/article/details/136784938
版权

概述

本篇简单汇总Godot中的颜色的构造和使用，内容包括了：

  • RGB、RGBA，HSV以及HTML16进制颜色值、颜色常量等形式构造颜色
  • 颜色的运算以及取反、插值
  • 用类型化数组、紧缩数组或PNG图片形式存储多个颜色

构造颜色

因为颜色是一种视觉元素，所以用print打印颜色值到输出窗口是比较抽象的做法。

这里我采用了HFlowContainer+ColorRect的形式，并编写一个函数show_color来动态生成ColorRect添加到HFlowContainer，来显示我们构造的颜色。

其中：

  • HFlowContainer是水平流式布局容器，添加为其一级子节点的控件将按照类似HTML文档的流式布局形式，也就是逐行从右向左排列，占满一行自动换行。
  • ColorRect也是一个专用于显示单个颜色的矩形控件

测试场景：
image.png
颜色显示函数：

# 用ColorRect显示颜色
func show_color(color:Color):
	var rect = ColorRect.new()
	rect.color = color
	rect.custom_minimum_size = Vector2(100,100)
	print(color) # 打印颜色值
	add_child(rect)

使用Color类型的构造函数构造颜色

  • 在GDScript中，颜色有专门的数据类型Color。
  • Color和int、float以及String一样，属于GDScript内置的数据类型之一，专用于构造和存储颜色数据，并提供方法进行颜色的处理。
  • Color类型提供了多种构造函数，我们可以用构造函数形式，创建Color类型的变量。
# 使用构造函数构造颜色
var c1 = Color()                    # 默认黑色
# RGB或RGBA形式
var c2 = Color(1.0,0.0,0.0)         # Color(r,g,b)
var c3 = Color(0.0,1.0,0.0,1.0)     # Color(r,g,b,a)

用show_color函数显示的效果：
image.png
可以看到和Vector2或Vector3类似，空的构造函数都会返回所有分量都为0的值。而Color()也返回R、G、B分量都是0，但不透明度为1的颜色，也就是黑色。

也就是说：

  • Vector2()=Vector2(0,0)
  • Vector3()=Vector3(0,0,0)
  • Color()=Color(0,0,0)=Color(0,0,0,1)

另外你可以使用RGBA或RGB形式构造颜色：

  • 一个Color由R、G、B、A四个通道组成，分别代表红色Red、绿色Green、蓝色Blue和不透明度Alpha。
  • 每个通道值都采用0.0到1.0之间的小数，你也可以将其理解为百分比0%～100%。
  • 在构造Color类型的时候你可以使用RGB和RGBA两种基本形式，RGB形式可以看做是固定A为1.0的RGBA。

使用全局函数Color8

除了Color类型及其构造函数，GDScript还提供了一个全局函数Color8：

Color8(r8: int, g8: int, b8: int, a8: int = 255)

8的意思就是8位，2^8=256，也就是R、G、B、A通道值的范围是从0到 255，其中A的默认值为255，也就是完全不透明。

其实Color8返回的也是Color类型。所以两者本质上没有什么区别。实际使用中Color类型的小数形式或者说百分比形式更直观一点。Color8更偏向原始的计算机定义。

var c1 = Color8(255,0,0)      # 红色
var c2 = Color8(255,0,0,127)  # 红色，不透明度约0.5

image.png

使用16进制字符串或颜色名称形式

# 字符串：16进制或颜色名(不区分大小写)
var c6 = Color("#0000ff")           # #RRGGBB
var c7 = Color("#0000ffcc")         # #RRGGBBAA
var c8 = Color("#cc0")              # #RGB
var c9 = Color("#cc0c")             # #RGBA
var c10 = Color("cc0c")             # RGBA

# 颜色名字符串形式
var c11 = Color("red")              # 颜色名字符串
var c12 = Color("red",0.5)          # 颜色名字符串+ Alpha值

# from_string方法
var c20 = Color.from_string("blue",Color.BLUE) # (颜色名，默认值)
var c21 = Color.from_string("#ccc",Color.BLUE) # (颜色名，默认值)
16进制整数形式
# 16进制整数形式
var c24 = Color.hex(0xff0000ff)  # 0xRRGGBBAA,0x为前缀，表示为16进制
var c25 = Color.hex(0x00ff00ff)  # 0xRRGGBBAA,0x为前缀，表示为16进制
16进制html颜色字符串形式
# 16进制html颜色字符串形式
var c26 = Color.html("#ccc")        # #RGB
var c27 = Color.html("#ff0000")     # #RRGGBB
var c28 = Color.html("#ff0000ee")   # #RRGGBBAA
var c29 = Color.html("ff0000ee")    # RRGGBBAA

使用颜色常量

Color类型内部定义了很多颜色常量，你可以很方便的用颜色的常量名。
你可以在《包含GODOT所有名称颜色的JSON》中获得所有颜色常量的英文名和中文名及其颜色值的信息。

# 颜色常量
var c1 = Color.YELLOW                      # Color内置常量
var c2 = Color(Color.YELLOW_GREEN,1.0)     # Color内置常量

使用HSV形式构造

除了以上的RGB形式，16进制颜色值形式，颜色常量或颜色名形式，还可以使用(h,s,v)或(h,s,v,a)形式构造颜色。

var c1 = Color.from_hsv(1,1,1,1)
var c2 = Color.from_hsv(0,1,1,1)

show_color(c1)  # (1, 0, 0, 1)
show_color(c2)  # (1, 0, 0, 1)

关于HSV颜色模式的具体内容见下文《获取HSV分量》部分。

获取比当前颜色更暗或更亮的颜色

  • 使用Color的lightened()方法，可以创建比当前颜色更亮的颜色
  • 使用Color的darkened()方法，则可以创建比当前颜色更暗的颜色
var c1 = Color.RED  
	
# 显示颜色
show_color(c1.lightened(0.8))    
show_color(c1.lightened(0.6))
show_color(c1.lightened(0.4))
show_color(c1.lightened(0.2))
show_color(c1)                   # 原始颜色
show_color(c1.darkened(0.2))
show_color(c1.darkened(0.4))
show_color(c1.darkened(0.6))
show_color(c1.darkened(0.8))

image.png

获取颜色的分量

你可以通过以下形式获取一个Color的分量：

  • r,g,b,a获取其小数形式的分量
  • r8,g8,b8,a8获取其8位形式的分量
  • 下标[0],[1],[2],[3]形式获取r,g,b,a分量
  • h,s,v获取HSV模式的分量
var c1 = Color("red")        
	
# 显示颜色
show_color(c1)  # (1, 0, 0, 1)

# 小数形式
print(c1.r)  # 1
print(c1.g)  # 0
print(c1.b)  # 0
print(c1.a)  # 1

# 8位形式
print(c1.r8)  # 255
print(c1.g8)  # 0
print(c1.b8)  # 0
print(c1.a8)  # 255

# 下标形式
print(c1[0])  # 1
print(c1[1])  # 0
print(c1[2])  # 0
print(c1[3])  # 1

获取HSV分量

HSV颜色模型

HSV是另一种构造或表示颜色的模型，你可以称其为色相-饱和度-明度模型，即：
在这里插入图片描述
其数学形式的表示，一种是圆柱体，一种是圆锥体。

  • H：色相，Hue，是围绕中心轴的角度，取值为0~360度，GDScript中将其映射到0.0~1.0范围
  • S：饱和度，Saturation，是距中心轴的距离，取值为0~100，GDScript中将其映射到0.0~1.0范围
  • V：明度，Value，是中心轴的高度，取值为0~100，GDScript中将其映射到0.0~1.0范围

HSV模型又称HSB，其中B为Brightness。

Godot中的HSV

  • ColorPicker和ColorPickerButton使用的是下图左的取色形式

  • 检视器面板的颜色类属性（包括导出变量）采用的时下图右的取色形式
    在这里插入图片描述
    可以看到两者只是将H、S、V三个参数进行了不同的组合：

  • 前者将色相H单独拎出来，饱和度S和明度V进行组合

  • 后者将明度V单独出来，将色相和饱和度进行组合

在其他一些软件，还可以看到“色环”形式的HSV取色器设计：
在这里插入图片描述

  • 其中色相H采用360度的色环形式
  • 饱和度S和明度V组合成一个正三角形且三角形顶部的顶点指向色相，对应锥形模型的切面
  • 饱和度S和明度V也可以组合成正方形，对应圆柱体模型的一个切面
360度色相映射0到1的方法

度数/360即可。
黄色在RGB/CMY色环中为60度，60/360=1/6=0.16666666…

var c1 = Color.YELLOW

print(c1.h)  # 色相 0.16666667163372
print(c1.s)  # 饱和度 1
print(c1.v)  # 亮度 1

可以看到数值非常相近。

用HSV形式构造颜色

可以用Color类型的from_hsv()方法以(h,s,v,a)形式构造颜色。

var c1 = Color.from_hsv(1,1,1,1)
var c2 = Color.from_hsv(0,1,1,1)

show_color(c1)  # (1, 0, 0, 1)
show_color(c2)  # (1, 0, 0, 1)
  • 因为0°和360°都是红色，所以用0（0/360）或1（360/360）都是可以的。

image.png

生成简易HSV360色相

for i in range(360.0):
	show_color(Color.from_hsv(i/360.0,1,1,1))

image.png

颜色的比较

两个Color类型的颜色值，可以使用==或!=进行比较，判断是否相等。

var c1 = Color(1.0,0,0)
	
print(c1 == Color.RED)  # true
print(c1 != Color.RED)  # false

判断两个颜色是否近似相等

如果你按F1搜索is_equal_approx，可以看到很多内置类型都自带了一个is_equal_approx方法，这些类型一般都是由几个分量组成。

而在@GlobalScope中也存在一个is_equal_approx方法，用于比较两个浮点数是否相近。

其他内置类型is_equal_approx方法都是在其各个分量上调用@GlobalScope的is_equal_approx方法。
image.png
根据内置文档的说法is_equal_approx的精度与比较的数字本身的大小有关，数字越小，精度要求越高，数字越大，精度要求越低。
以下是我简单进行的几组测试：

print(is_equal_approx(0.9,1.0))     # flase
print(is_equal_approx(0.99,1.0))    # flase
print(is_equal_approx(0.999,1.0))   # flase
print(is_equal_approx(0.9999,1.0))  # flase
print(is_equal_approx(0.99999,1.0)) # true

print(is_equal_approx(9,10))           # flase
print(is_equal_approx(9.9,10))         # flase
print(is_equal_approx(9.99,10))        # flase
print(is_equal_approx(9.999,10))       # flase
print(is_equal_approx(9.9999,10))      # flase
print(is_equal_approx(9.99999,10))     # true

print(is_equal_approx(9999,10000))           # flase
print(is_equal_approx(9999.9,10000))         # flase
print(is_equal_approx(9999.99,10000))        # true
print(is_equal_approx(9999.999,10000))       # true

print(is_equal_approx(999999999,1000000000)) # true

因此在使用Color类型的is_equal_approx()，判定两个颜色是否近似时，其判定为true的条件是非常严格的，就是每个分量的差值都要＜0.00001才行。

var c1 = Color(0,1,0,1)
var c2 = Color(0,0.9,0,1)
var c3 = Color(0,0.99,0,1)
var c4 = Color(0,0.999,0,1)
var c5 = Color(0,0.9999,0,1)
var c6 = Color(0,0.99999,0,1)
var c7 = Color(0,0.999999,0,1)

show_color(c1)
show_color(c2)
show_color(c3)
show_color(c4)
show_color(c5)
show_color(c6)
show_color(c7)
print(c1.is_equal_approx(c2))   # false
print(c1.is_equal_approx(c3))   # false
print(c1.is_equal_approx(c4))   # false
print(c1.is_equal_approx(c5))   # false
print(c1.is_equal_approx(c6))   # false
print(c1.is_equal_approx(c7))   # true

这种近乎变态的近似判断几乎没有实用意义，因此不如自己编写一个函数来判断两个颜色的近似。

# 判断两个颜色是否相似，精度precision可以自定义，默认0.1
func is_similar_color(color1:Color,color2:Color,precision:float = 0.1) -> bool:
	var bol:bool
	var color_d = color1-color2  # 获得颜色的差值
	var color_d_arr = []         # 存储转化为绝对值和特定精度的分量
	# 将分量转换为特定精度的小数的绝对值
	for i in range(4):
		var d_val = snapped(absf(color_d[i]),precision) # 转换为与precision小数位数一致的浮点数
		color_d_arr.append(d_val)
	
	# 比较每个分量的绝对值是否都达到精度值的要求
	if color_d_arr[0] <= precision and \
		color_d_arr[1] <= precision and \
		color_d_arr[2] <= precision and \
		color_d_arr[3] <= precision:
		bol = true
	# 或者所有有分量的差值之和小于3倍精度
	elif color_d_arr[0] + color_d_arr[1]+ color_d_arr[2] + color_d_arr[3] <= precision * 3:
		bol = true
	else:
		bol = false
	return bol

var c1 = Color(0,1,0,1)
var c2 = Color(0,0.9,0,1)
var c3 = Color(0.1,0,0,1)
var c4 = Color(0.1,0.9,0,1)
var c5 = Color(0.2,0.9,0,1)
var c6 = Color(0.1,0.9,0.1,0.9)

show_color(c1)
show_color(c2)
show_color(c3)
show_color(c4)
show_color(c5)
show_color(c6)
print(is_similar_color(c1,c2))  # true
print(is_similar_color(c1,c3))  # false
print(is_similar_color(c1,c4))  # true
print(is_similar_color(c1,c5))  # true
print(is_similar_color(c1,c6))  # true

image.png

颜色的运算

颜色运算这部分，可以完全类比颜色是一个Vector4，虽然GDScript中没有这种数据类型，但运算形式和运算性质几乎和Vector2、Vector3如出一辙。

颜色相加

var c1 = Color.AQUAMARINE           
var c2 = Color.BLUE_VIOLET

# 显示颜色
show_color(c1)     # (0.498, 1, 0.8314, 1)
show_color(c2)     # (0.5412, 0.1686, 0.8863, 1)
show_color(c1+c2)  # (1.0392, 1.1686, 1.7176, 2)

image.png
可以看到一个Color值，类似与一个四分量向量，其加法就是各个分量值相加，这里两个颜色相加的值为(1.0392, 1.1686, 1.7176, 2)，超出了Color所定义的颜色值的上限(1.0,1.0,1.0,1.0)，也就是白色，所以最终它是以白色显示。

颜色相减

与颜色相加类似，两个颜色之间也可以进行相减运算。同样是RBGA四个通道的分量相减。

var c1 = Color.AQUAMARINE           
var c2 = Color.BLUE_VIOLET

# 显示颜色
show_color(c1)     # (0.498, 1, 0.8314, 1)
show_color(c2)     # (0.5412, 0.1686, 0.8863, 1)
show_color(c1-c2)  # (-0.0431, 0.8314, -0.0549, 0)

image.png
这里因为相减后Alpha通道值为0，所以颜色变为完全透明。

颜色相乘

var c1 = Color.AQUAMARINE           
var c2 = Color.BLUE_VIOLET

# 显示颜色
show_color(c1)     # (0.498, 1, 0.8314, 1)
show_color(c2)     # (0.5412, 0.1686, 0.8863, 1)
show_color(c1*c2)  # (0.2695, 0.1686, 0.7368, 1)

image.png
CanvasItem的modulate属性就是采用了颜色的乘法。其中比较特殊的就是：

  • 白色为(1.0,1.0,1.0,1.0)，任何数乘以1都保持不变，所以任何颜色乘以白色，还是这个颜色本身。
  • 黑色为(0.0,0.0,0.0,0.0)，任何数乘以0都会变成0，所以任何颜色乘以黑色，都会变成黑色。

image.png

颜色相除

var c1 = Color.AQUAMARINE           
var c2 = Color.BLUE_VIOLET

# 显示颜色
show_color(c1)     # (0.498, 1, 0.8314, 1)
show_color(c2)     # (0.5412, 0.1686, 0.8863, 1)
show_color(c1/c2)  # (0.9203, 5.9302, 0.9381, 1)

image.png

颜色乘以整数或浮点数

var c1 = Color(0.1,0.1,0.1)
	
show_color(c1)
show_color(c1 * 0.5)  # (0.05, 0.05, 0.05, 0.5)
show_color(c1 * 1.2)  # (0.12, 0.12, 0.12, 1.2)
show_color(c1 * 2)    # (0.2, 0.2, 0.2, 2)
show_color(c1 * 0)    # (0, 0, 0, 0)

image.png
除以一个整数或浮点数类似。

颜色的混合

var yellow = Color.YELLOW  
var green = Color.GREEN  

# 显示颜色
show_color(yellow)   # (1, 1, 0, 1)
show_color(green)    # (0, 1, 0, 1)
show_color(yellow.blend(green)) # (0, 1, 0, 1)

image.png

var yellow = Color(Color.YELLOW,0.5)
var green = Color.GREEN  

# 显示颜色
show_color(yellow)  # (1, 1, 0, 0.5)
show_color(green)    # (0, 1, 0, 1)
show_color(yellow.blend(green)) # (0, 1, 0, 1)

image.png
可以看到：如果混合的第2个颜色alpha是1，也就是不带透明度，会用后一个颜色覆盖之前的颜色。

var yellow = Color(Color.YELLOW,0.5)
var green = Color(Color.GREEN,0.5)

# 显示颜色
show_color(yellow)
show_color(green)
show_color(yellow.blend(green))

image.png
只有当第2个颜色alpha小于1，也就是带透明度，才可以看到混合的效果。

获取反色

var green = Color.GREEN  
	
# 显示颜色
show_color(green)             # (0, 1, 0, 1)
show_color(green.inverted())  # (1, 0, 1, 1)

image.png
inverted()返回反色 (1-r,1-g,1-b,a)。

获取颜色的灰度和亮度

godot4.2已经删除了Color的gray()方法，但我们根据其灰度值计算原理：(r + g + b) / 3。可以自己构造一个函数进行代替

# 返回颜色的灰度值
func get_gray(color:Color) -> float:
	return (color.r + color.g + color.b)/3.0

get_luminance()返回该颜色的亮度，位于[0.0, 1.0]的范围内。可以用来确定颜色是亮色还是暗色。一般认为亮度小于0.5的颜色是暗色。

var green = Color.GREEN  
	
# 显示颜色
show_color(green)              # (0, 1, 0, 1)
print(green.get_luminance())   # 0.71520000696182
print(get_gray(green))         # 0.33333333333333

颜色插值

var green = Color.GREEN  
var red = Color.RED

# 从0%到100%cha插值
for i in range(11):
    show_color(green.lerp(red,i * 0.1)) # 显示颜色

image.png
查看输出的数据，可以看到插值的整个过程：

(0, 1, 0, 1)
(0.1, 0.9, 0, 1)
(0.2, 0.8, 0, 1)
(0.3, 0.7, 0, 1)
(0.4, 0.6, 0, 1)
(0.5, 0.5, 0, 1)
(0.6, 0.4, 0, 1)
(0.7, 0.3, 0, 1)
(0.8, 0.2, 0, 1)
(0.9, 0.1, 0, 1)
(1, 0, 0, 1)

3.5的函数linear_interpolate4.x改名为lerp。

不同颜色表示形式之间的转化

关于RGB模式：8位,16位,32位和64位色

  • RGB色彩就是常说的光学三原色，R代表Red（红色），G代表Green（绿色），B代表Blue（蓝色）。自然界中肉眼所能看到的任何色彩都可以由这三种色彩混合叠加而成，因此也称为加色模式。
  • 现代的电子显示器，包括电视、电脑、手机和平板等大都是采用了RGB颜色标准，在显示器上，是通过电子枪打在屏幕的红、绿、蓝三色发光极上来产生色彩的，电脑一般都能显示32位颜色，约有一百万种以上的颜色。
  • 在led 领域 利用三合一点阵全彩技术， 即在一个发光单元里由RGB三色晶片组成全彩像素。 随着这一技术的不断成熟，led显示技术会给人们带来更加丰富真实的色彩感受。
  • 8位深（2的8次方）意味着有256种灰度或彩色组合，16位深（2的16次方）能表现65536种可能的颜色组合，24位深能够表现约1670万种不同的颜色。
  • 32位图像所含的信息多，所以表现的图像更加细腻逼真，而16位图像和8位图像由于所含的图像信息较少，所以表现的图像画质不如32位的细腻。

—— photoshop RGB模式8位,16位,32位有什么不同?_百度知道 (baidu.com)

RGBA转ABGR、ARGB等

Color类型提供了几个颜色表示形式转化的的函数，提供RGBA转ABGR、ARGB等格式。抱歉我对ABGR、ARGB格式的使用了解较少。这里贴出内置文档源码：

var color = Color(1, 0.5, 0.2)
print(color.to_abgr32()) # 输出 4281565439
print(color.to_abgr64()) # 输出 -225178692812801
print(color.to_argb32()) # 输出 4294934323
print(color.to_argb64()) # 输出 -2147470541
print(color.to_rgba32()) # 输出 4286526463
print(color.to_rgba64()) # 输出 -140736629309441

RGBA转HTML16进制颜色字符串

var color = Color(1, 1, 1, 0.5)
var s1 = color.to_html() # 返回 "7fffffff"
var s2 = color.to_html(false) # 返回 "ffffff"

判断某个变量是否为Color类型

var color = Color(1, 1, 1, 0.5)

print(color is Color)  # true
print(typeof(color) == TYPE_COLOR)  # true

批量存储颜色

在Godot4.X中你可以用类型化数组Array[Color]形式或紧缩数组PackedColorArray来专门用于存储多个颜色。

var colors:Array[Color]
	
for i in range(360.0):
    colors.append(Color.from_hsv(i/360.0,1,1,1))

或者：

var colors:PackedColorArray
	
for i in range(360.0):
    colors.append(Color.from_hsv(i/360.0,1,1,1))

声明存储多个颜色的导出变量

通过将导出变量类型设定为Array[Color]或PackedColorArray，就可以在检视器面板设定多个颜色。

extends HFlowContainer

@export var colors:PackedColorArray

image.png

声明存储多个颜色的自定义资源

可以自定义Resource，来存储多个颜色。

# 调色板 - 存储多个颜色
@tool
class_name ColorPalette extends Resource

@export var colors:PackedColorArray

你可以在检视器面板新建和编辑ColorPalette：
image.png
或者用代码方式创建、编辑并保存

var p1 = ColorPalette.new()
p1.colors.append(Color.RED)
p1.colors.append(Color.GREEN)
p1.colors.append(Color.YELLOW)
p1.colors.append(Color.BLUE)
ResourceSaver.save(p1,"res://colors_p1.tres")

用PNG图存储调色板

利用Image类型，我们可以直接将颜色值存储到一张png或jpg等形式的图片上。

var img = Image.create(5,1,false,Image.FORMAT_RGBA8)
img.set_pixel(0,0,Color.RED)
img.set_pixel(1,0,Color.GREEN)
img.set_pixel(2,0,Color.YELLOW)
img.set_pixel(3,0,Color.BLUE)
img.set_pixel(4,0,Color.GOLD)
img.save_png("colos1.png")

输出的图片如下：
在这里插入图片描述
我们可以重新加载这张图片，然后通过get_pixel来读取其中的颜色信息。

参考资料

巽星石
关注
  • 25
    点赞
  • 踩
  • 24
    收藏
    觉得还不错? 一键收藏
  • 打赏
    打赏
  • 0
    评论
专栏目录
Godot官方中文手册-20190117
01-17
godot官方中文手册 20190117下载 Godot是一个开源和免费的2d和3d的游戏引擎。 官网http://www.godotengine.org/ Godot自带编辑器,类似与unity的编辑器。使用自带的GDScript脚本。跨平台运行。
开源游戏引擎Godot官方中文手册2019
09-20
godot官方中文手册 20190117下载 Godot是一个开源和免费的2d和3d的游戏引擎。 官网http://www.godotengine.org/ Godot自带编辑器,类似与unity的编辑器。使用自带的GDScript脚本增加了c#/c++等语言支持，可跨平台运行。
视差背景，GODOT游戏引擎学习笔记（五）
最新发布
weixin_66990397的博客
05-25 1049
今天周六玩了一天，现在晚上来更新一下帖子。前面几节我们学习了创建一个人物精灵节点使其移动。这节我们来学习创建背景。会用到三个图片文件。
Godot引擎 4.0 文档 - 手册 - 2D
drgraph的博客
06-25 3719
¶这是对节点从本地绘制内容到绘制到屏幕上进行的 2D 变换的概述。本概述讨论了引擎的非常底层的细节。¶通常需要将自定义输入事件提供给场景树。有了以上知识，要正确地做到这一点，必须按照以下方式进行：GD脚本C＃varvar二维灯光和阴影¶¶默认情况下，Godot 中的 2D 场景是无阴影的，没有可见的灯光和阴影。虽然渲染速度很快，但未着色的场景可能看起来很平淡。Godot 提供了使用实时 2D 光照和阴影的能力，这可以极大地增强项目的深度感。没有 2D 灯光或阴影，场景没有阴影¶启用 2D 灯（无阴影）
Godot引擎 4.0 文档 - 手册 - 最佳实践
drgraph的博客
06-06 3123
¶由于 Godot 对项目结构或文件系统的使用没有限制，因此在学习引擎时组织文件似乎具有挑战性。本教程建议的工作流程应该是一个很好的起点。我们还将介绍如何使用 Godot 进行版本控制。¶Godot 的目标是对 VCS 友好，并生成大部分可读和可合并的文件。Godot 还支持在编辑器中使用版本控制系统。但是，编辑器中的 VCS 需要针对您正在使用的特定 VCS 的插件。可以在Project > Version Control下的编辑器中设置或关闭 VCS。​​。
Godot4自学手册目录
zhaoyang314的博客
03-22 1418
这是本人用Godot4.2开发2D游戏的自学笔记，我希望能够系统地学习和掌握游戏设计制作的相关技能，成为一名优秀的游戏开发者。记笔记的目的是防止自己忘记，另一方面是不断积累、不断创新，提高自己的水平。同时，还希望能与更多志同道合的朋友一起交流学习，共同探讨游戏的未来发展趋势，不断拓展自己的视野和思维。
ZoneLoadingSystem:Godot动态区域加载系统
04-01
这是Godot的动态区域加载系统，它负责为您管理区域管理，在玩家探索世界时加载和卸载区域，并使用后台线程来最大程度地减少性能故障。 这允许拥有巨大的无缝世界而无需加载屏幕。 该系统适用于手工制作的区域，例如...
Godot-v4.2-beta1-win64.exe.zip
11-08
在使用Godot 4.2 beta1时，开发者需要注意这是一个测试版本，可能存在bug和不稳定因素。因此，对于生产环境的项目，建议等待正式版本发布。同时，积极参与社区交流，报告问题和贡献代码，有助于加速Godot 4.2的完善...
Godot4.2.1 windows版本
02-21
在Windows上使用Godot 4.2.1，开发者可以利用其丰富的工具集创建2D和3D游戏。Godot的核心特点包括： 1. **多平台支持**：Godot支持Windows、Linux、macOS以及Android和iOS等移动平台，使得游戏能够跨平台发布。 2....
Godot在github的资源网址，最近版本4.1.2，只是下载速度有点慢
10-10
https://github.com/godotengine/godot/releases/tag/4.1.2-stable
【unity开发】Godot游戏引擎 v4.2.1
05-01
Godot是一个全新开发的开源跨平台游戏引擎，其功能集类似知名的跨平台游戏引擎Unity，可用于开发PC、主机、移动和Web游戏。开发者声称引 擎的2D和动画支持要强于Unity，表示在功能和特性上没有其它开源游戏引擎能相...
Godot开源游戏引擎24小时快速入门掌握2D和3D多平台游戏开发PDF版
09-19
Godot开源游戏引擎24小时快速入门，25章节，快速掌握2D和3D游戏开发，跨平台游戏开发引擎，PDF版比起epub更好阅读！简易英文，浅显易读，强烈推荐。（我的CSDN博客也有入门文章教程）
Godot简介
02-14
Godot简介
Godot游戏引擎 v4.2.1.zip
03-21
“说明.htm”文件可能包含了关于如何使用这个压缩包中的内容，包括如何导入和运行Godot项目，以及可能的注意事项和快速入门指南。 8. **godot-4.2.1-stable**： 这个文件可能是Godot 4.2.1稳定版本的可执行文件或...
【Godot4自学手册】第二十九节使用Shader来实现敌人受伤的闪白效果
03-26
在本节【Godot4自学手册】中，我们将深入探讨如何使用Shader技术来为敌人受伤时添加引人注目的视觉效果——闪白效果。Shader是计算机图形学中的一个重要概念，它控制了游戏或应用程序中物体的外观。在Godot 4.0中，...
【Godot4自学手册】第二十三节对话系统
03-12
在本节【Godot4自学手册】中，我们将深入探讨如何使用Godot 4.0游戏引擎配合Dialogic 2.0插件构建一个功能完善的对话系统，让你的角色能够与非玩家角色（NPC）进行互动。这个对话系统是游戏叙事和情节推进的重要工具...
【Godot4自学手册】第一节配置Godot运行环境
zhaoyang314的博客
01-20 2200
Godot是一款自由开源、由社区驱动的 2D 和 3D 游戏引擎！它是一款功能丰富的跨平台游戏引擎，可以通过统一的界面创建 2D 和 3D 游戏。它提供了一套全面的通用工具，因此用户可以专注于制作游戏，而无需重新发明轮子。游戏可以一键导出到多个平台，包括主流的桌面平台（Linux、macOS、Windows）、移动平台（Android、iOS）、基于 Web 的平台以及主机平台。
Godot4.1官方文档-中文翻译-使用TileSets
充满智慧的博客
10-15 1792
瓦片地图（tilemap）是一个用于创建游戏布局的瓦片格。使用TileMap节点设计关卡有几个好处。首先，它们允许你通过在网格上“绘制”瓦片来绘制布局，这比逐个放置单个Sprite2D节点要快得多。其次，它们允许更大的关卡，因为它们经过优化，可以绘制大量的瓦片。最后，它们允许你为瓦片添加碰撞、遮挡和导航形状等功能。要使用瓦片图，首先需要创建一个TileSet。TileSet是一组可以放置在TileMap节点中的瓦片。创建TileSet后，你将能够使用TileMap编辑器来放置它们。
Godot 代码修改Label文字颜色
qianhang120的博客
12-27 862
以font outline为例，直接将检查器中的此属性（图中红圈区域）拖入代码中，就会自动生成路径。"custom_colors/font_color"为Label自身的。如何确定属性索引路径？
godot class_name 使用
04-23
在Godot中，使用class_name来声明一个类的名称。这是一个额外的标记，它被用来创建类的元数据，从而提供给编辑器和其他工具使用。它可以与extends关键字一起使用，用于继承其他类的功能。例如，一个继承Node类的类可能会使用以下语法： class_name MyNode extends Node 这将为MyNode类声明一个名称，并将它继承自Node类。在编辑器中，MyNode将被作为一个Node类的子类来显示，并且在适当的位置出现在节点树中。此外，在相关工具中，如自动完成和类浏览器，也可以使用这个名称来实现特定的功能。
评论
添加红包

请填写红包祝福语或标题

个

红包个数最小为10个

元

红包金额最低5元

当前余额3.43元 前往充值 >
需支付：10.00元
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包

打赏作者

巽星石

你的鼓励将是我创作的最大动力

¥1 ¥2 ¥4 ¥6 ¥10 ¥20
扫码支付：¥1
获取中
扫码支付

您的余额不足，请更换扫码支付或充值

打赏作者

实付元
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明：

1.余额是钱包充值的虚拟货币，按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载，可以购买VIP、付费专栏及课程。

余额充值