Unity Shader - Providing vertex data to vertex programs 给顶点着色器提供顶点数据

最新推荐文章于 2024-05-02 18:31:14 发布
最新推荐文章于 2024-05-02 18:31:14 发布
阅读量421 收藏 1
点赞数
分类专栏： Unity Shader 译文 文章标签： Unity Providing vertex data to vs

目录：Unity Shader - 知识点目录（先占位，后续持续更新）
原文：Providing vertex data to vertex programs
版本：2019.1

Providing vertex data to vertex programs

给顶点着色器提供顶点数据

对于 Cg/HLSL 的顶点程序来说，网格的顶点数据需要传入到顶点着色器函数。每个输入的数据都需要指定 semantic （语义） ：如，POSITION 代表输入顶点的坐标，NORMAL 代表顶点法线。

通常来说，顶点的输入数据定义在一个结构体，而不是一个一个的在函数里头声明定义。一些常用的顶点结构都定义在 UnityCG.cginc include file，大多数情况下这些结构都够用。这些结构体是：

  • appdata_base：坐标，法线和一个纹理坐标。
  • appdata_tan：坐标，切线，法线和一个纹理坐标。
  • appdata_full：坐标，切线，法线，四个纹理坐标和一个颜色。

例如：下面的shader中，网格的颜色是基于法线来定，且使用 appdata_base 作为顶点程序的输入结构：

Shader "VertexInputSimple" {
    SubShader {
        Pass {
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            #include "UnityCG.cginc"
         
            struct v2f {
                float4 pos : SV_POSITION;
                fixed4 color : COLOR;
            };
            
            v2f vert (appdata_base v)
            {
                v2f o;
                o.pos = UnityObjectToClipPos(v.vertex);
                o.color.xyz = v.normal * 0.5 + 0.5;
                o.color.w = 1.0;
                return o;
            }

            fixed4 frag (v2f i) : SV_Target { return i.color; }
            ENDCG
        }
    } 
}

访问不同的顶点数据，你需要定义顶点数据结构体，或是给顶点着色器函数添加参数的方式。顶点数据都是以 Cg/HLSL semantics（语义）来识别的，必须是一下这些语义：

  • POSITION 是顶点的坐标，通常是 float3 或是 float4。
  • NORMAL 是顶点的法线，通常是 float3。
  • TEXCOORD0 是第一个UV坐标，通常是 float2，float3 或是 float4。
  • TEXCOORD1，TEXCOORD2，TEXCOORD3 分别是第二，第三和第四个UV坐标。
  • TANGENT 是切向量（用于法线映射），通常是 float4。
  • COLOR 是顶点的颜色，通常是 float4。

当网格数据分量数的比顶点着色器输入指定类型的数据分量数少时，那么其余的都用0填充，只有.w分量默认值为1。如，网格的纹理坐标通常是2D向量，有x和y分量。如果顶点着色器定义为一个 float4 类型，并使用 TEXCOORD0 语义，那么在顶点着色器接收该 float4 数据实际值就是：（x,y,0,1）。

Examples

例子

Visualizing UVs

可视化UV

接下来着色器的例子将使用顶点坐标和第一个纹理坐标作为顶点着色器输入数据结构（定义于 appdata 结构体）。这个 shader 用于调试网格的UV坐标是很有用的。

Shader "Debug/UV 1" {
SubShader {
    Pass {
        CGPROGRAM
        #pragma vertex vert
        #pragma fragment frag
        #include "UnityCG.cginc"

        // 顶点输入：坐标，UV
        struct appdata {
            float4 vertex : POSITION;
            float4 texcoord : TEXCOORD0;
        };

        struct v2f {
            float4 pos : SV_POSITION;
            float4 uv : TEXCOORD0;
        };
        
        v2f vert (appdata v) {
            v2f o;
            o.pos = UnityObjectToClipPos(v.vertex );
            o.uv = float4( v.texcoord.xy, 0, 0 );
            return o;
        }
        
        half4 frag( v2f i ) : SV_Target {
            half4 c = frac( i.uv );
            if (any(saturate(i.uv) - i.uv))
                c.b = 0.5;
            return c;
        }
        ENDCG
    }
}
}

这里的UV坐标被可视化为红和绿颜色，当UV坐标唱过0-1范围的都显示为蓝色：
Debug UV1 shader applied to a torus knot model
调试UV1着色器应用在圆环结（麻花结）的模型上

类似的，着色器可视化模型的第二个UV：

Shader "Debug/UV 2" {
SubShader {
    Pass {
        CGPROGRAM
        #pragma vertex vert
        #pragma fragment frag
        #include "UnityCG.cginc"

        // 顶点输入：坐标，第二个UV
        struct appdata {
            float4 vertex : POSITION;
            float4 texcoord1 : TEXCOORD1;
        };

        struct v2f {
            float4 pos : SV_POSITION;
            float4 uv : TEXCOORD0;
        };
        
        v2f vert (appdata v) {
            v2f o;
            o.pos = UnityObjectToClipPos(v.vertex );
            o.uv = float4( v.texcoord1.xy, 0, 0 );
            return o;
        }
        
        half4 frag( v2f i ) : SV_Target {
            half4 c = frac( i.uv );
            if (any(saturate(i.uv) - i.uv))
                c.b = 0.5;
            return c;
        }
        ENDCG
    }
}
}

Visualizing vertex colors

可视化顶点颜色

接下来的shader使用顶点的坐标和顶点颜色作为顶点输入的数据结构（定义在 appdata 结构体）。

Shader "Debug/Vertex color" {
SubShader {
    Pass {
        CGPROGRAM
        #pragma vertex vert
        #pragma fragment frag
        #include "UnityCG.cginc"

        // 顶点输入：坐标，颜色
        struct appdata {
            float4 vertex : POSITION;
            fixed4 color : COLOR;
        };

        struct v2f {
            float4 pos : SV_POSITION;
            fixed4 color : COLOR;
        };
        
        v2f vert (appdata v) {
            v2f o;
            o.pos = UnityObjectToClipPos(v.vertex );
            o.color = v.color;
            return o;
        }
        
        fixed4 frag (v2f i) : SV_Target { return i.color; }
        ENDCG
    }
}
}

Debug Colors shader applied to a torus knot model that has illumination baked into colors
调试颜色着色器应用于带有烘焙光照颜色的圆环结模型

Visualizing normals

可视化法线

下面的shader使用顶点坐标和法线作为顶点着色器的输入结构（定义在 appdata 结构体）。法线的 X,Y,Z分量可视化为RGB颜色。因为法线分量的数据范围是-1 ~ 1的，我们需要缩放和偏移它们，以便它们能用于显示颜色的数据范围： 0 ~ 1。

Shader "Debug/Normals" {
SubShader {
    Pass {
        CGPROGRAM
        #pragma vertex vert
        #pragma fragment frag
        #include "UnityCG.cginc"

        // 顶点输入：坐标，法线
        struct appdata {
            float4 vertex : POSITION;
            float3 normal : NORMAL;
        };

        struct v2f {
            float4 pos : SV_POSITION;
            fixed4 color : COLOR;
        };
        
        v2f vert (appdata v) {
            v2f o;
            o.pos = UnityObjectToClipPos(v.vertex );
            o.color.xyz = v.normal * 0.5 + 0.5;
            o.color.w = 1.0;
            return o;
        }
        
        fixed4 frag (v2f i) : SV_Target { return i.color; }
        ENDCG
    }
}
}

Debug Normals shader applied to a torus knot model. You can see that the model has hard shading edges.
调试法线着色器应用于圆环结模型。你可以看到模型的着色带有硬边缘。

Visualizing tangents and bitangent

可视化切线与副切线

切线与副切线向量用于法线映射。在Unity仅有切线向量存在顶点在，而副切线是从法线与切线推导出来的。

下面的shader使用顶点的坐标和切线作为顶点着色器的输入（定于在 appdata 结构体）。切线的x,y,z分量可视化为RGB颜色。因为法线的分量都是 -1 ~ 1的范围，我们缩放和偏移它们以便于输出到显示颜色的范围：0 ~ 1。

Shader "Debug/Tangents" {
SubShader {
    Pass {
        CGPROGRAM
        #pragma vertex vert
        #pragma fragment frag
        #include "UnityCG.cginc"

        // 顶点输入：坐标，切线
        struct appdata {
            float4 vertex : POSITION;
            float4 tangent : TANGENT;
        };

        struct v2f {
            float4 pos : SV_POSITION;
            fixed4 color : COLOR;
        };
        
        v2f vert (appdata v) {
            v2f o;
            o.pos = UnityObjectToClipPos(v.vertex );
            o.color = v.tangent * 0.5 + 0.5;
            return o;
        }
        
        fixed4 frag (v2f i) : SV_Target { return i.color; }
        ENDCG
    }
}
}

Debug Tangents shader applied to a torus knot model.
调试切线着色器应用于圆环结模型。

下面的shader可视化副切线。使用顶点的坐标，法线和切线作为顶点的输入。副切线（某些情况也叫副法线）是从法线和切线计算得来的。它需要被缩放和偏移到显示颜色的范围：0 ~ 1。

Shader "Debug/Bitangents" {
SubShader {
    Pass {
        Fog { Mode Off }
        CGPROGRAM
        #pragma vertex vert
        #pragma fragment frag
        #include "UnityCG.cginc"

        // 顶点输入：坐标，法线，切线
        struct appdata {
            float4 vertex : POSITION;
            float3 normal : NORMAL;
            float4 tangent : TANGENT;
        };

        struct v2f {
            float4 pos : SV_POSITION;
            float4 color : COLOR;
        };
        
        v2f vert (appdata v) {
            v2f o;
            o.pos = UnityObjectToClipPos(v.vertex );
            // 计算副切线
            float3 bitangent = cross( v.normal, v.tangent.xyz ) * v.tangent.w;
            o.color.xyz = bitangent * 0.5 + 0.5;
            o.color.w = 1.0;
            return o;
        }
        
        fixed4 frag (v2f i) : SV_Target { return i.color; }
        ENDCG
    }
}
}

Debug Bitangents shader applied to a torus knot model.
调试副切线着色器应用于圆环结模型。

Further Reading

延伸阅读

Jave.Lin
关注
  • 0
    点赞
  • 踩
  • 1
    收藏
    觉得还不错? 一键收藏
  • 0
    评论
专栏目录
Shader 基础使用(三) ----- vertex & fragment
BattleTiger的博客
08-10 2970
基本数据类型与surface一致,就不在此文章赘述了 顶点语义绑定 float4 POSITION 顶点坐标位置 float3 NORMAL 顶点法线向量坐标 float4 TEXCOORD0 第一个UV坐标 float4 TEXCOORD1..N 第二个到第N个UV坐标 float4 TENGENT 顶点切线向量坐标 float4 COLOR 顶点颜色值 常用函
unity shader学习笔记（2）:vertexshader(顶点颜色)
u010278564的专栏
10-18 3485
功能前提思考：大量物体使用同一个材质，实现不同的颜色。开发的功能是乐高模型的搭建模拟。优化材质数量 个人的做法是在不同模型初始化的时候赋予不同颜色，这些颜色存在顶点上面。而shader的话只是用于显示物体和一些光照效果的处理然后在混合顶点颜色。（有其他做法的可以多多交流，嘿嘿）。 直接上图 先发一个改变模型顶点颜色的代码 public MeshFilter MF1,MF2; ...
[基础] Unity Shader：顶点着色器（vert）函数
最新发布
z1234234234的博客
05-02 1044
顶点着色器（Vertex Shader）是图形渲染的第一个阶段，它的输入来自于CPU。顶点着色器的处理单位是顶点，CPU输入进来的每个顶点都会调用一次顶点着色器函数，也就是我们在Shader代码里所定义的vert函数。本篇我们将会通过顶点的颜色变换、顶点位移、顶点扭曲来介绍顶点着色器（vert）函数。
Unity Surface Shader 使用其他组件颜色
BDDNH的博客
05-22 614
自己新建的shader ，使用在linerender或者Image等组件上面的时候，这些组件的颜色修改不能影响到材质球。lineRender的颜色渐变是很实用的功能。 lineRender颜色能够改变材质颜色，是因为LineRender修改了模型点的颜色。然后Shader通过这个颜色去混合材质球颜色就能实现LineRender控制材质颜色了。 顶点片段着色器可以在顶点片段中获取顶点颜色，然后传入片段着色器。 这里主要说一下SurfaceShader，因为不太常用到。 自定义顶点函数 #pr..
Shader中的appdata类型
Sevol_Y
09-09 1503
appdata类型，是shader内置的结构类型，分为appdata_base、appdata_tan、appdata_full三个类型。 struct appdata_base { float4 vertex : POSITION;//顶点位置 float3 normal : NORMAL;//发现 float4 texcoord : TEXCOORD0;//纹理坐标 UNITY_VERTEX_INPUT_INSTANCE_ID }; struct appdata_t
Shader第三讲 Vertex&Fragment Shader
AK41君的专栏
03-10 831
转载自风宇冲Unity3D教程学院 链接：http://blog.sina.com.cn/s/blog_471132920101d5oz.html Vertex and Fragment Shader:最强大的Shader类型，也是本系列的重点，下文中简称V&F Shader，属于可编程渲染管线. 使用的是CG/HLSL语法。分为2个部分vertex顶点部分和Fragment像
unity曲面细分着色器详解
longger0000的博客
07-05 1600
前言：本文翻译自catlikecoding上一篇十分详细的英文blog并修改了几处小错误，逐行解释了如何在自己的shader中添加曲面细分支持，并给出了多种计算细分因子的方案以及它们的优缺点。
Unity Shader - Vertex and fragment shader examples 顶点和片段着色器的例子-附件资源
03-05
Unity Shader - Vertex and fragment shader examples 顶点和片段着色器的例子-附件资源
Unity-Shader-Basics-Tutorial：为Unity创建着色器的介绍
02-06
Unity Shader基础教程梁亚当（ ） 欢迎使用，本教程应该是对Unity着色器编写的简要介绍。 它假定您具有使用Unity的一些先前知识，但从未接触过着色器或材质。 我们将逐步构建着色器，并逐步显示所有功能。 如果您有...
Unity线框着色器 Wireframe shader - The Amazing Wireframe shader 2018
06-02
在Unity中，这通常通过修改着色器代码来实现，尤其是在表面着色器（Surface Shader）或顶点片段着色器（Vertex Fragment Shader）中。 Unity的着色器语言是基于Cg/HLSL的ShaderLab，开发者可以通过编写ShaderLab...
Unity Shader实现流光效果Shader-FlowEffect-master.zip
05-28
Surface Shader是一种高级的着色器模型，它允许开发者在一个统一的接口中定义表面的外观，而不必关心背后的光照计算细节。一个基本的Surface Shader结构包括`CGPROGRAM`和`ENDCG`之间的代码，以及表面函数`...
Unity 顶点着色器保姆级讲解
u010082265的博客
03-25 2677
本文详细介绍了顶点着色器的概念、优缺点以及在 Unity 中实现布林冯光照模型的示例代码。其中，顶点着色器是图形渲染管线中的一部分，用于对每个顶点进行操作和变换。它的优点包括高灵活性、高性能和支持硬件加速，但也存在一些缺点，如难以调试和复杂性较高等。 在 Unity 中，可以通过编写顶点着色器来实现各种复杂的图形效果，包括光照、变形、骨骼动画等。本文以兰伯特光照模型为例，给出了实现该模型的顶点着色器代码，并详细解释了其中的各个部分的含义和作用。
Shader-TexturePanner源码的简单梳理
weixin_43834106的博客
04-25 731
作为一个刚学习shader的菜鸟，当看到TexturePanner这样的组合式的shader，让人眼前一亮，忍不住有一种想探究它的好奇心，想了解一下内部是怎么实现的，顺便学学大佬的思路，所有今天就简单的梳理一下源码，先贴一下shader源码（删除了一部分无用的注释）： // Made with Amplify Shader Editor // Available at the Unity As...
Unity Shader 显示顶点颜色
提莫队长
07-06 1830
Unity Shader 插值显示顶点颜色，上来就是复制粘贴
Unity渲染模型顶点色shader教程
weixin_43071164的博客
06-08 3699
首先用Maya打开已经做好的模型，需要提前安装好mental ray，这里用一个带有贴图的正方体代替。 然后选择Rendering菜单组的Lighting/Shading菜单，选择Batch Bake方框。 打开渲染设置，取消最下方的Enable Default Light。 打开材质选项，把Ambient Color调至最高，模拟一个全局照明的效果。 烘培之前给物体做一个备份，复制一个新...
【Unity Shaders】Vertex Magic —— 访问顶点颜色
weixin_34067980的博客
07-27 492
本系列主要参考《Unity Shaders and Effects Cookbook》一书（感谢原书作者），同时会加上一点个人理解或拓展。这里是本书所有的插图。这里是本书所需的代码和资源（当然你也可以从官网下载）。========================================== 分割线==========================================写在...
Unity 切换 颜色空间Spine UI处理
yaoyutian的博客
12-30 2959
三维渲染一般使用Linear色彩空间合适，更准确，但对于UI，则似乎使用gamma，不管对于美工处理，还是人眼直观感受， 都比较好； Spine4.0之前只支持gamma，4.0后说支持linear，但似乎最终效果与线性不一致（1，2）； 1. 默认gamma导出的spine资源，如何在unitylinear下复现基本 一致的显示效果？ 修改spine shader，可近似，但还有差距，特别是不透明度，（默认的gamma转换linear函数自己微调）例如 Shader "Spine/Skeleton
Unity Polybrush与顶点色着色器
12-19 4672
　　今年年初，我们宣布了ProBuilder和Polybrush将正式成为Unity的一部分。我们已经详细介绍过使用ProBuilder快速关卡建模，而Polybrush可以帮助我们完成粗略的雕刻、纹理混合、对象散布和顶点色绘制等功能。 　　 　　通常为了处理顶点色，必须进行3D程序代码编写并估计最终结果。但有了Polybrush后，我们可以直接在编辑器中进行绘制，然后看到处理后的效果...
Unity3D shader（6）——vertex shader（顶点颜色变换）
niuge8905的博客
08-09 7608
Shader的顶点坐标其实和物体网格的局部坐标、世界坐标一致，只是这里需要有一个坐标转换。 首先说一下Unity3D shader的坐标转换。 这里首先需要了解Cg语言的标准函数库，链接地址：https://wenku.baidu.com/view/3a9db318fad6195f312ba675.html 有两个转换，一个转换是将物体顶点坐标转换到Unity程序里的相机里的坐标； 一个是
【Unity Shader学习笔记】（一）在表面着色器中控制顶点变换
06-09
好的，您的第一个问题是关于Unity Shader的学习笔记，具体是在表面着色器中控制顶点变换。那么我可以回答您的问题。 在Unity中，表面着色器是一种用于控制物体表面外观的程序。它们可以控制颜色、纹理和光照等方面...

“相关推荐”对你有帮助么？

  • 非常没帮助
  • 没帮助
  • 一般
  • 有帮助
  • 非常有帮助
提交
评论
添加红包

请填写红包祝福语或标题

个

红包个数最小为10个

元

红包金额最低5元

当前余额3.43元 前往充值 >
需支付：10.00元
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包
实付元
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明：

1.余额是钱包充值的虚拟货币，按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载，可以购买VIP、付费专栏及课程。

余额充值