#UVM# useage 解析 之 uvm_event 和 uvm_event_pool （一）小白易懂

在Systermverilog 中用于进程之间同步、通信的方式有 event, semaphore和mailbox。而在UVM中event则进一步进化成uvm_event类（为什么不延续使用event？弊端在哪里？），它不仅仅拥有完成不同组件进程之间同步的功能（如何实现？），还能像TLM通信一样传递数据（如何实现？），并且作用范围更广（TLM通信只能在uvm_component之间，而uvm_event不限于此，表现在哪里？）（开篇这里给出了几个疑问，今天这里的重点不会一一解答，想了解的朋友，请观看其它章节）。

一  常见的uvm_event的使用

首先，从常见的uvm_event达成同步的方式讲起。举例如下：

`timescale 1ns/1ps
import helloworld_test_pkg::*;
import uvm_pkg::*;
`include "uvm_macros.svh"
module tb_top();
reg clk,rst;

initial begin clk = 0; forever #5 clk = ~ clk;end
initial begin rst = 1'b0; #10 rst = 1; end

initial begin
run_test("helloworld_test") ;
end
  
initial begin
  // get a reference to the global singleton object by 
  // calling a static method
  uvm_event_pool ev_pool = uvm_event_pool::get_global_pool();// 还记得此处的调用方式吗？补功课哦 如果不清楚

  // either create a uvm_event or return a reference to it
  // (which depends on the order of execution of the two
  //  initial blocks - the first call creates the event,
  //  the second and subsequent calls return a reference to
  //  an existing event.)
  uvm_event ev = ev_pool.get("ev");
  
  // wait (an arbitrary) 10 and then trigger the event
  #10 ev.trigger();
  $display("%t: event ev triggered", $time);
end

initial begin
  // get a reference to the global singleton object by 
  // calling a static method
  uvm_event_pool ev_pool = uvm_event_pool::get_global_pool();

  // either create a uvm_event or return a reference to it
  uvm_event ev = ev_pool.get("ev");
  
  // wait for the trigger
  ev.wait_trigger();
  $display("%t: event ev trigger received", $time);
end

endmodule

这里，两个initial 块可以想象成两个不同UVM组件的不同进程，通过上面的注释已经基本可以理解uvm_event的达成UVM 进程之间同步的方法。

看似很简单，大致总结如下几步。

1.1 Get 一个全局的单例的uvm_event_pool类型对象的句柄

 // get a reference to the global singleton object by calling a static method
    uvm_event_pool ev_pool = uvm_event_pool::get_global_pool();

 uvm_event_pool的源代码：
https://verificationacademy.com/verification-methodology-reference/uvm/src/base/uvm_pool.svh

uvm_event_pool是一个参数为uvm_event类型的uvm_object_string_pool，而uvm_object_string_pool又是继承于uvm_pool。uvm_event_pool和uvm_pool没有太大差别，也不是很复杂，在这里不是重点。

  typedef uvm_object_string_pool #(T) this_type;
  static protected this_type m_global_pool;
  protected T pool[KEY];  // type KEY = string
.........
  static function this_type get_global_pool ();
       if (m_global_pool==null)
               m_global_pool = new("global_pool");
       return m_global_pool;
  endfunction

get_global_pool()的源代码如上，结合uvm_event_pool的成员pool和m_global_pool——其中pool是从uvm_pool中继承过来的，而KEY和T正是传递的类型参数，string和uvm_event——可以知道， 调用get_global_pool()会返回一个类型为uvm_event_pool的句柄，句柄指向的对象是全局并且单例的。也就是说两个initial块中两次调用get_global_pool都是返回同一个uvm_event_pool类型对象的句柄，只是先调用的那个get_global_pool函数会创建这个对象。
1.2  通过调用这个uvm_event_pool句柄的get()方法得到一个uvm_event对象的句柄

    uvm_event ev = ev_pool.get("ev");

 get ()函数如下：

virtual function T get (string key);
          if (!pool.exists(key))
               pool[key] = new (key);
          return pool[key];
  endfunction

根据源代码知道，在这里pool是一个关联数组，类型为uvm_event，索引类型为string（这也是为什么get()的参数为字符串）。两个initial块两次调用get()，是为了获得同一个pool[string]对象的句柄，先调用的那个get()会创建这个pool[string]，而后调用的那个只是获得这个pool[string]对象的句柄。这个过程和systemverilog中event的传递是一样的，是在两个进程中完成同步的基础。

1.3  通过uvm_event对象的方法trigget () 和wait_trigger ()达成同步

 前两步的目的本质上是为了让两个Initial块中两个uvm_event句柄指向同一个对象，这种作法相对于conifg_db或者层次化引用的方式显然方便得多，并且使用get_global()而非get()会更简单。接下来和systemverlog中event达成同步的操作一样了，在一个进程中触发->，另外一个进程中等待触发wait (event.triggered) or @event。
在uvm_event中，触发的方式是uvm_event.trigger ()；而等待出发的方式是wait_ptrigger () （电平触发）or wait_trigger () （上升沿触发） （与event的两种等待方式对应）。

二   uvm_event 相较于event的功能扩展

uvm_event的源代码如下，去掉了一些不常用的方法，这里只看关键的方法。

class uvm_event extends uvm_object；

其实uvm_event的基础，还是event，只不过event的触发和等待两个动作进行了很多扩展， 主要区别如下:

1）event被->触发之后，会触发使用@等待该事件的对象；uvm_event通过trigger()来触发，会触发使用wait_trigger()等待的对象。如果要再次等待事件触发，event只需要再次用->来触发，而uvm_event需要先通过reset()方法重置初始状态，再使用trigger()来触发。

2）event无法携带更多的信息，而uvm_event可以通过trigger(uvm_event data = null)的可选参数，将所要伴随触发的数据信息都写入到该触发事件中，而等待该事件的对象可以通过方法wait_trigger_data(output uvm_object data)来获取事件触发时写入的数据对象。这实际上是一个句柄的传递，句柄的类型是uvm_object，也就是说传递的对象句柄得是uvm_object类型的。那如何传递非uvm_object类型的对象呢，首先这个对象必须是uvm_object的子类或者子类的子类，然后才能将其句柄作为trigger()方法的参数，然后wait_trigger ()的参数必须是uvm_object类型的，可以用一个uvm_object类型的tmp作为参数传递句柄，然后使用$cast赋值给目标类型句柄。可以参考：http://www.sohu.com/a/140684109_778637

3）event触发时无法直接触发回调函数，而uvm_event可以通过add_callback(uvm_event_callback cb, bit append = 1)函数来添加回调函数。

4）event无法直接获取等待它的进程数目，而uvm_event不但可以通过get_num_waiters()来获取等待它的进程数目。

5）uvm_event 能够使用callback机制（这里就不讨论uvm_event_callback了，也不复杂）， uvm_event能够获取目前事件的等待获触发状态。两者最大的区别还是uvm_event能够传递数据，而event不行。

PS:  

 其实这两种做法的结果都是一样的，都是在uvm_event_pool::m_global_pool这个静态全局单例中的创建了一个uvm_event对象，并存放在关联数组uvm_event_pool::m_global_pool.pool[string]中，索引就是get or get_global ()的参数， 如果这个字符串索引已经存在，那么就返回这个pool[string]句柄。