unity屏幕扭曲

unity屏幕扭曲效果

这个效果其实比较简单，但要根据具体情况来选择具体的实现方案；

1. 对于全屏扭曲，并且扭曲效果后没有其他物体的绘制（除了UI），这个时候可以选择使用全屏后处理效果；比如全屏雨幕效果；
2. 如果是半透明物体对背景的扭曲，可以使用内部的GrabPass或者CommandBuffer来实现；比如火焰效果、刀光效果、玻璃效果等；

扭曲效果注意事项

对于半透明物体对背景的扭曲情况下有一些注意事项：

1. 使用CommandBuffer效率是比GrabPass效率要高一些的，但需要自己写脚本控制，还要注意脚本的开启状态；而使用GrabPass就非常方便，只需要额外的一行Shader代码就好==（简直懒人必备）；
2. 采样背景时，屏幕坐标及扭曲后坐标的运算，屏幕坐标的运算可以看unity官方的代码：

GrabPass
{
    "_BackgroundTexture"
}

// Render the object with the texture generated above, and invert the colors
Pass
{
    CGPROGRAM
    #pragma vertex vert
    #pragma fragment frag
    #include "UnityCG.cginc"

    struct v2f
    {
        float4 grabPos : TEXCOORD0;
        float2 texcoord : TEXCOORD1;
        float4 pos : SV_POSITION;
    };

    v2f vert(appdata_base v) {
        v2f o;
        // use UnityObjectToClipPos from UnityCG.cginc to calculate 
        // the clip-space of the vertex
        o.pos = UnityObjectToClipPos(v.vertex);
        // use ComputeGrabScreenPos function from UnityCG.cginc
        // to get the correct texture coordinate
        o.grabPos = ComputeGrabScreenPos(o.pos);
        o.texcoord = v.texcoord;
        return o;
    }

    sampler2D _BackgroundTexture;

    half4 frag(v2f i) : SV_Target
    {
        half4 bgcolor = tex2Dproj(_BackgroundTexture, i.grabPos);
        return 1 - bgcolor;
    }
    ENDCG
}

这里有两个函数要注意，ComputeGrabScreenPos实际上得到的并不是(0-1)的纹理坐标，根据unity的源码(在UnityCG.cginc文件中)可以看到

inline float4 ComputeGrabScreenPos (float4 pos) {
    #if UNITY_UV_STARTS_AT_TOP
    float scale = -1.0;
    #else
    float scale = 1.0;
    #endif
    float4 o = pos * 0.5f;
    o.xy = float2(o.x, o.y*scale) + o.w;
#ifdef UNITY_SINGLE_PASS_STEREO
    o.xy = TransformStereoScreenSpaceTex(o.xy, pos.w);
#endif
    o.zw = pos.zw;
    return o;
}

ComputeGrabScreenPos得到是齐次空间下的纹理坐标xy，范围应该在(0,w)之间;
ComputeGrabScreenPos计算之前的齐次空间下纹理坐标xy，范围为(-w,w);
tex2Dproj采样函数会在采样时先对纹理坐标进行归一化，即xy的范围要除以w，然后得到位于(0，1)之间的采样坐标，之后进行采样。参考这里

得到纹理坐标后，我们只要对其进行扰动，就可以采样背景图得到扭曲的背景效果;
方法1为：

sampler2D _NoiseTex;

half4 frag(v2f i) : SV_Target
{
	half4 backUV = i.grabPos;
	backUV.xy += tex2D(_NoiseTex, i.texcoord);
    half4 bgcolor = tex2Dproj(_BackgroundTexture, backUV);
    return bgcolor;
}

该方法实际上是对归一化前的纹理坐标进行扰动，因而会受到w值的影响（熟悉坐标变换的知道，这实际上就是View空间下的深度），所以会离相机越近，扭曲效果越明显；

方法2为：

sampler2D _NoiseTex;

half4 frag(v2f i) : SV_Target
{
	half2 backUV = i.grabPos.xy/i.grabPos.w;
	backUV += tex2D(_NoiseTex, i.texcoord);
    half4 bgcolor = tex2D(_BackgroundTexture, backUV);
    return bgcolor;
}

该方法对归一化后的纹理左边进行扰动，强度只与_NoiseTex有关，与相机距离无关；